09adc99469e9009498eb7ae72cbaabdc79f4bb79
[mirror/qt/qt5.git] / init-repository
1 #!/usr/bin/env perl
2 #############################################################################
3 ##
4 ## Copyright (C) 2012 Digia Plc and/or its subsidiary(-ies).
5 ## Contact: http://www.qt-project.org/legal
6 ##
7 ## This file is part of the utilities of the Qt Toolkit.
8 ##
9 ## $QT_BEGIN_LICENSE:LGPL$
10 ## Commercial License Usage
11 ## Licensees holding valid commercial Qt licenses may use this file in
12 ## accordance with the commercial license agreement provided with the
13 ## Software or, alternatively, in accordance with the terms contained in
14 ## a written agreement between you and Digia.  For licensing terms and
15 ## conditions see http://qt.digia.com/licensing.  For further information
16 ## use the contact form at http://qt.digia.com/contact-us.
17 ##
18 ## GNU Lesser General Public License Usage
19 ## Alternatively, this file may be used under the terms of the GNU Lesser
20 ## General Public License version 2.1 as published by the Free Software
21 ## Foundation and appearing in the file LICENSE.LGPL included in the
22 ## packaging of this file.  Please review the following information to
23 ## ensure the GNU Lesser General Public License version 2.1 requirements
24 ## will be met: http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
25 ##
26 ## In addition, as a special exception, Digia gives you certain additional
27 ## rights.  These rights are described in the Digia Qt LGPL Exception
28 ## version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
29 ##
30 ## GNU General Public License Usage
31 ## Alternatively, this file may be used under the terms of the GNU
32 ## General Public License version 3.0 as published by the Free Software
33 ## Foundation and appearing in the file LICENSE.GPL included in the
34 ## packaging of this file.  Please review the following information to
35 ## ensure the GNU General Public License version 3.0 requirements will be
36 ## met: http://www.gnu.org/copyleft/gpl.html.
37 ##
38 ##
39 ## $QT_END_LICENSE$
40 ##
41 #############################################################################
42
43 use v5.8;
44 use strict;
45 use warnings;
46
47 package Qt::InitRepository;
48
49
50 =head1 NAME
51
52 init-repository - initialize the Qt5 repository and all submodules
53
54 =head1 SYNOPSIS
55
56   ./init-repository [options]
57
58 This script may be run after an initial `git clone' of Qt5 in order to check
59 out all submodules.
60
61
62 =head1 OPTIONS
63
64 B<Global options:>
65
66 =over
67
68 =item --force, -f
69
70 Force initialization (even if the submodules are already checked out).
71
72
73 =item --quiet, -q
74
75 Be quiet.  Will exit cleanly if the repository is already initialized.
76
77 =back
78
79
80 B<Module options:>
81
82 =over
83
84 =item --no-webkit
85
86 Skip webkit and webkit examples submodules.
87 It may be desirable to skip these modules due to the large size of the webkit
88 git repository.
89
90 =item --module-subset=<module1>,<module2>...
91
92 Only initialize the specified subset of modules given as the argument. Specified
93 modules must already exist in .gitmodules.
94 The string "all" results in cloning all known modules. The default is the set of
95 maintained modules.
96
97 =item --no-update
98
99 Skip the `git submodule update' command.
100
101
102 =item --ignore-submodules
103
104 Set git config to ignore submodules by default when doing operations on the
105 qt5 repo, such as `pull', `fetch', `diff' etc.
106
107 This option is default for --nokia-developer.
108
109 After using this option, pass `--ignore-submodules=none' to git to override
110 it as needed.
111
112 =back
113
114
115 B<Repository options:>
116
117 =over
118
119 =item --nokia-developer
120
121 Switch to internal Nokia URLs.
122
123
124 =item --berlin
125
126 Switch to internal Nokia URLs and make use of the Berlin git mirrors.
127 (Implies `--mirror').
128
129
130 =item --ssh
131
132 Use the SSH protocol for git operations.  This may be useful if the git
133 protocol is blocked by a firewall. Note that this requires a user account
134 with an uploaded SSH key on all servers used.  (Implies `--nokia-developer').
135
136 The `--ssh' option does not affect the gerrit remotes.
137
138
139 =item --http
140
141 Use the HTTP protocol for git operations.  This may be useful if the git
142 protocol is blocked by a firewall.  Note that this only works with the
143 external Gitorious server.
144
145 The `--http' option does not affect the gerrit remotes.
146
147
148 =item --codereview-username <Gerrit/JIRA username>
149
150 Specify the user name for the (potentially) writable `gerrit' remote
151 for each module, for use with the Gerrit code review tool.
152
153 If this option is omitted, the gerrit remote is created without a username
154 and port number, and thus relies on a correct SSH configuration.
155
156
157 =item --alternates <path to other Qt5 repo>
158
159 Adds alternates for each submodule to another full qt5 checkout. This makes
160 this qt5 checkout very small, as it will use the object store of the
161 alternates before unique objects are stored in its own object store.
162
163 This option has no effect when using `--no-update'.
164
165 B<NOTE:> This will make this repo dependent on the alternate, which is
166 potentially dangerous!  The dependency can be broken by also using
167 the `--copy-objects' option, or by running C<git repack -a> in each
168 submodule, where required.  Please read the note about the `--shared' option
169 in the documentation of `git clone' for more information.
170
171
172 =item --copy-objects
173
174 When `--alternates' is used, automatically do a C<git repack -a> in each
175 submodule after cloning, to ensure that the repositories are independent
176 from the source used as a reference for cloning.
177
178 Note that this negates the disk usage benefits gained from the use of
179 `--alternates'.
180
181
182 =item --mirror <url-base>
183
184 Uses <url-base> as the base URL for submodule git mirrors.
185
186 For example:
187
188   --mirror user@machine:/foo/bar
189
190 ...will use the following as a mirror for qtbase:
191
192   user@machine:/foo/bar/qt/qtbase.git
193
194 The mirror is permitted to contain a subset of the submodules; any
195 missing modules will fall back to the canonical URLs.
196
197 =back
198
199 =cut
200
201 use Carp         qw( confess             );
202 use English      qw( -no_match_vars      );
203 use Getopt::Long qw( GetOptionsFromArray );
204 use Pod::Usage   qw( pod2usage           );
205 use Cwd          qw( getcwd              );
206
207 my %PROTOCOLS = (
208     'internal'  => 'git://scm.dev.nokia.troll.no/' ,
209     'ssh'       => 'git@scm.dev.nokia.troll.no:'   ,
210     'http'      => 'http://git.gitorious.org/'     ,
211 );
212
213 my %GERRIT_REPOS = map { $_ => "qt/$_" } qw(
214     qt3d
215     qt5
216     qlalr
217     qtactiveqt
218     qtbase
219     qtconnectivity
220     qtdeclarative
221     qtdoc
222     qtdocgallery
223     qtfeedback
224     qtgraphicaleffects
225     qtimageformats
226     qtjsondb
227     qtjsbackend
228     qtlocation
229     qtmultimedia
230     qtpim
231     qtqa
232     qtquick1
233     qtquickcontrols
234     qtrepotools
235     qtscript
236     qtsensors
237     qtserialport
238     qtsvg
239     qtsystems
240     qttools
241     qttranslations
242     qtwayland
243     qtwebkit
244     qtwebkit-examples
245     qtx11extras
246     qtxmlpatterns
247 );
248
249 my @DEFAULT_REPOS = qw(
250     qtactiveqt
251     qtbase
252     qtdeclarative
253     qtdoc
254     qtgraphicaleffects
255     qtimageformats
256     qtjsbackend
257     qtmultimedia
258     qtqa
259     qtquick1
260     qtquickcontrols
261     qtrepotools
262     qtscript
263     qtsensors
264     qtserialport
265     qtsvg
266     qttools
267     qttranslations
268     qtwebkit
269     qtwebkit-examples
270     qtx11extras
271     qtxmlpatterns
272 );
273
274 my $GERRIT_SSH_BASE
275     = 'ssh://@USER@codereview.qt-project.org@PORT@/';
276
277 my $BER_MIRROR_URL_BASE
278     = 'git://hegel/';
279
280 sub new
281 {
282     my ($class, @arguments) = @_;
283
284     my $self = {};
285     bless $self, $class;
286     $self->parse_arguments(@arguments);
287
288     return $self;
289 }
290
291 # Like `system', but possibly log the command, and die on non-zero exit code
292 sub exe
293 {
294     my ($self, @cmd) = @_;
295
296     if (!$self->{quiet}) {
297         print "+ @cmd\n";
298     }
299
300     if (system(@cmd) != 0) {
301         confess "@cmd exited with status $CHILD_ERROR";
302     }
303
304     return;
305 }
306
307 sub parse_arguments
308 {
309     my ($self, @args) = @_;
310
311     %{$self} = (%{$self},
312         'alternates'          => "",
313         'codereview-username' => "",
314         'detach-alternates'   => 0 ,
315         'force'               => 0 ,
316         'ignore-submodules'   => 0 ,
317         'mirror-url'          => "",
318         'nokia-developer'     => 0 ,
319         'protocol'            => "",
320         'update'              => 1 ,
321         'webkit'              => 1 ,
322         'module-subset'       => join(",", @DEFAULT_REPOS),
323     );
324
325     GetOptionsFromArray(\@args,
326         'alternates=s'      =>  \$self->{qw{ alternates        }},
327         'codereview-username=s' => \$self->{qw{ codereview-username }},
328         'copy-objects'      =>  \$self->{qw{ detach-alternates }},
329         'force'             =>  \$self->{qw{ force             }},
330         'ignore-submodules' =>  \$self->{qw{ ignore-submodules }},
331         'mirror=s'          =>  \$self->{qw{ mirror-url        }},
332         'nokia-developer'   =>  \$self->{qw{ nokia-developer   }},
333         'quiet'             =>  \$self->{qw{ quiet             }},
334         'update!'           =>  \$self->{qw{ update            }},
335         'webkit!'           =>  \$self->{qw{ webkit            }},
336         'module-subset=s'   =>  \$self->{qw{ module-subset     }},
337
338         'help|?'            =>  sub { pod2usage(1);               },
339         'http'              =>  sub { $self->{protocol} = 'http'; },
340         'ssh|ssh-protocol'  =>  sub { $self->{protocol} = 'ssh';  },
341
342         'berlin|berlin-nokia-developer' => sub {
343             $self->{'nokia-developer'}   = 1;
344             $self->{'protocol'}          = 'internal';
345             $self->{'mirror-url'}        = $BER_MIRROR_URL_BASE;
346         },
347
348         'nokia-developer' => sub {
349             $self->{'nokia-developer'}   = 1;
350             $self->{'protocol'}          = 'internal';
351             $self->{'ignore-submodules'} = 1;
352         },
353     ) || pod2usage(2);
354
355     if ($self->{'nokia-developer'} && $self->{'protocol'} eq 'http') {
356         print "*** Ignoring use of HTTP protocol, as it's only usable with external server\n";
357         $self->{'protocol'} = '';
358     }
359
360     # Replace any double trailing slashes from end of mirror
361     $self->{'mirror-url'} =~ s{//+$}{/};
362
363     if ($self->{'module-subset'} eq "all") {
364         $self->{'module-subset'} = "";
365     } else {
366         $self->{'module-subset'} = {
367             map { $_ => 1 } split(qr{,}, $self->{'module-subset'})
368         };
369     }
370
371     return;
372 }
373
374 sub check_if_already_initialized
375 {
376     my ($self) = @_;
377
378     # We consider the repo as `initialized' if submodule.qtbase.url is set
379     if (qx(git config --get submodule.qtbase.url)) {
380         if ($self->{force}) {
381             my @configresult = qx(git config -l);
382             foreach (@configresult) {
383                 # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
384                 if (/(submodule\.[^.=]+)\.url=.*/) {
385                     $self->exe('git', 'config', '--remove-section', $1);
386                 }
387             }
388         }
389         else {
390             exit 0 if ($self->{quiet});
391             print "Will not reinitialize already initialized repository (use -f to force)!\n";
392             exit 1;
393         }
394     }
395
396     return;
397 }
398
399 sub git_submodule_init
400 {
401     my ($self) = @_;
402
403     my @init_args;
404     if ($self->{quiet}) {
405         push @init_args, '--quiet';
406     }
407     $self->exe('git', 'submodule', 'init', @init_args);
408
409     my $template = getcwd()."/.commit-template";
410     if (-e $template) {
411         $self->exe('git', 'config', 'commit.template', $template);
412     }
413
414     return;
415 }
416
417 sub git_disable_webkit_submodule
418 {
419     my ($self) = @_;
420
421     $self->exe('git', 'config', '--remove', 'submodule.qtwebkit');
422     $self->exe('git', 'config', '--remove', 'submodule.qtwebkit-examples');
423
424     return;
425 }
426
427 sub git_prune_submodules
428 {
429     my ($self) = @_;
430
431     my @configresult = qx(git config -l);
432     foreach my $line (@configresult) {
433         if ($line =~ /submodule\.([^.=]+)\.url=/) {
434             my $module_name = $1;
435             if (!$self->{'module-subset'}{$module_name}) {
436                 $self->exe('git', 'config', '--remove', "submodule.$module_name");
437             }
438         }
439     }
440 }
441
442 sub git_set_submodule_config
443 {
444     my ($self) = @_;
445
446     my @configresult          = qx(git config -l);
447     my $protocol              = $self->{protocol};
448     my $url_base_for_protocol = $PROTOCOLS{$protocol};
449
450     foreach my $line (@configresult) {
451         # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
452         next if ($line !~ /submodule\.([^.=]+)\.url=(.*)/);
453
454         my $key   = $1;
455         my $value = $2;
456
457         if ($protocol) {
458                 # qt-labs projects are still hosted under qt internally.
459                 if ($protocol ne 'http') {
460                     $value =~ s,^git://gitorious\.org/qt-labs/,${url_base_for_protocol}qt/,;
461                 }
462
463                 # assume all other projects hosted under gitorious publicly.
464                 $value =~ s,^git://gitorious\.org/,$url_base_for_protocol,;
465         }
466
467         $self->exe('git', 'config', "submodule.$key.url", $value);
468
469         if ($self->{'ignore-submodules'}) {
470             $self->exe('git', 'config', "submodule.$key.ignore", 'all');
471         }
472     }
473
474     return;
475 }
476
477 sub git_clone_all_submodules
478 {
479     my ($self) = @_;
480
481     # manually clone each repo here, so we can easily use reference repos, mirrors etc
482     my @configresult = qx(git config -l);
483     foreach my $line (@configresult) {
484         if ($line =~ /submodule\.([^.=]+)\.url=(.*)/) {
485             $self->git_clone_one_submodule($1, $2);
486         }
487     }
488
489     if ($self->{update}) {
490         $self->exe('git', 'submodule', 'update', '--recursive');
491     }
492
493     return;
494 }
495
496 sub git_add_remotes
497 {
498     my ($self, $repo_basename) = @_;
499
500     my $gerrit_repo_basename = $GERRIT_REPOS{$repo_basename};
501     if ($gerrit_repo_basename) {
502         my $gerrit_repo_url;
503
504         # If given a username, make a "verbose" remote.
505         # Otherwise, rely on proper SSH configuration.
506         if ($self->{'codereview-username'}) {
507             $gerrit_repo_url = $GERRIT_SSH_BASE;
508             $gerrit_repo_url =~ s,\@USER\@,$self->{'codereview-username'}\@,;
509             $gerrit_repo_url =~ s,\@PORT\@,:29418,;
510         }
511         else {
512             $gerrit_repo_url = $GERRIT_SSH_BASE;
513             $gerrit_repo_url =~ s,\@[^\@]+\@,,g;
514         }
515
516         $gerrit_repo_url .= $gerrit_repo_basename;
517         $self->exe('git', 'config', 'remote.gerrit.url', $gerrit_repo_url);
518         $self->exe('git', 'config', 'remote.gerrit.fetch', '+refs/heads/*:refs/remotes/gerrit/*', '/heads/');
519     }
520
521     return;
522 }
523
524 sub git_clone_one_submodule
525 {
526     my ($self, $submodule, $url) = @_;
527
528     my $alternates            = $self->{ 'alternates'        };
529     my $mirror_url            = $self->{ 'mirror-url'        };
530     my $protocol              = $self->{ 'protocol'          };
531
532     # `--reference FOO' args for the clone, if any.
533     my @reference_args;
534
535     if ($alternates) {
536         # alternates is a qt5 repo, so the submodule will be under that.
537         if (-d "$alternates/$submodule") {
538             @reference_args = ('--reference', "$alternates/$submodule");
539         }
540         else {
541             print " *** $alternates/$submodule not found, ignoring alternate for this submodule\n";
542         }
543     }
544
545     my $mirror;
546     if ($mirror_url) {
547         $mirror = $mirror_url."qt/$submodule";
548         $mirror .= ".git" unless (-d $mirror); # Support local disk mirror
549     }
550
551     if ($mirror) {
552         # Only use the mirror if it can be reached.
553         eval { $self->exe('git', 'ls-remote', $mirror, 'test/if/mirror/exists') };
554         if ($@) {
555             warn "mirror [$mirror] is not accessible; $url will be used\n";
556             undef $mirror;
557         }
558     }
559
560     my $do_clone = (! -d "$submodule/.git");
561     if ($do_clone) {
562         $self->exe('git', 'clone', @reference_args, ($mirror ? $mirror : $url), $submodule);
563     }
564
565     chdir($submodule) or confess "chdir $submodule: $OS_ERROR";
566
567     $self->exe('git', 'config', 'remote.origin.url', $url);
568     if ($mirror) {
569         $self->exe('git', 'config', 'remote.mirror.url', $mirror);
570         $self->exe('git', 'config', 'remote.mirror.fetch', '+refs/heads/*:refs/remotes/mirror/*');
571     }
572
573     if (!$do_clone) {
574         $self->exe('git', 'fetch', ($mirror ? $mirror : $url));
575     }
576
577     my $template = getcwd()."/../.commit-template";
578     if (-e $template) {
579         $self->exe('git', 'config', 'commit.template', $template);
580     }
581
582     $self->git_add_remotes($submodule);
583
584     if ($self->{'detach-alternates'}) {
585         $self->exe('git', 'repack', '-a');
586
587         my $alternates_path = '.git/objects/info/alternates';
588         if (-e $alternates_path) {
589             unlink($alternates_path) || confess "unlink $alternates_path: $OS_ERROR";
590         }
591     }
592
593     chdir("..") or confess "cd ..: $OS_ERROR";
594
595     return;
596 }
597
598 sub run
599 {
600     my ($self) = @_;
601
602     $self->check_if_already_initialized;
603     $self->git_submodule_init;
604
605     if (!$self->{webkit}) {
606         $self->git_disable_webkit_submodule;
607     }
608
609     if ($self->{'module-subset'}) {
610         $self->git_prune_submodules;
611     }
612
613     $self->git_set_submodule_config;
614
615     $self->git_clone_all_submodules;
616
617     $self->git_add_remotes('qt5');
618
619     return;
620 }
621
622 #==============================================================================
623
624 Qt::InitRepository->new(@ARGV)->run if (!caller);
625 1;