Added qtfeedback module.
[mirror/qt/qt5.git] / init-repository
1 #!/usr/bin/env perl
2 #############################################################################
3 ##
4 ## Copyright (C) 2011 Nokia Corporation and/or its subsidiary(-ies).
5 ## All rights reserved.
6 ## Contact: Nokia Corporation (qt-info@nokia.com)
7 ##
8 ## This file is part of the utilities of the Qt Toolkit.
9 ##
10 ## $QT_BEGIN_LICENSE:LGPL$
11 ## No Commercial Usage
12 ## This file contains pre-release code and may not be distributed.
13 ## You may use this file in accordance with the terms and conditions
14 ## contained in the Technology Preview License Agreement accompanying
15 ## this package.
16 ##
17 ## GNU Lesser General Public License Usage
18 ## Alternatively, this file may be used under the terms of the GNU Lesser
19 ## General Public License version 2.1 as published by the Free Software
20 ## Foundation and appearing in the file LICENSE.LGPL included in the
21 ## packaging of this file.  Please review the following information to
22 ## ensure the GNU Lesser General Public License version 2.1 requirements
23 ## will be met: http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
24 ##
25 ## In addition, as a special exception, Nokia gives you certain additional
26 ## rights.  These rights are described in the Nokia Qt LGPL Exception
27 ## version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
28 ##
29 ## If you have questions regarding the use of this file, please contact
30 ## Nokia at qt-info@nokia.com.
31 ##
32 ##
33 ##
34 ##
35 ##
36 ##
37 ##
38 ##
39 ## $QT_END_LICENSE$
40 ##
41 #############################################################################
42
43 use v5.10;
44 use strict;
45 use warnings;
46
47 package Qt::InitRepository;
48
49
50 =head1 NAME
51
52 init-repository - initialize the Qt5 repository and all submodules
53
54 =head1 SYNOPSIS
55
56   ./init-repository [options]
57
58 This script may be run after an initial `git clone' of Qt5 in order to check
59 out all submodules.
60
61
62 =head1 OPTIONS
63
64 B<Global options:>
65
66 =over
67
68 =item --force, -f
69
70 Force initialization (even if the submodules are already checked out).
71
72
73 =item --quiet, -q
74
75 Be quiet.  Will exit cleanly if the repository is already initialized.
76
77 =back
78
79
80 B<Module options:>
81
82 =over
83
84 =item --no-webkit
85
86 Skip webkit and webkit examples submodules.
87 It may be desirable to skip these modules due to the large size of the webkit
88 git repository.
89
90
91 =item --no-update
92
93 Skip the `git submodule update' command.
94
95
96 =item --ignore-submodules
97
98 Set git config to ignore submodules by default when doing operations on the
99 qt5 repo, such as `pull', `fetch', `diff' etc.
100
101 This option is default for --nokia-developer/--brisbane.
102
103 After using this option, pass `--ignore-submodules=none' to git to override
104 it as needed.
105
106 =back
107
108
109 B<Repository options:>
110
111 =over
112
113 =item --nokia-developer
114
115 Switch to internal Nokia URLs.
116
117
118 =item --brisbane
119
120 Switch to internal Nokia URLs and make use of the Brisbane git mirrors.
121 (Implies `--mirror' and `--mirror-webkit').
122
123 =item --berlin
124
125 Switch to internal Nokia URLs and make use of the Berlin git mirrors.
126 (Implies `--mirror' and `--mirror-webkit').
127
128
129 =item --ssh
130
131 Use the SSH protocol for git operations.  This may be useful if the git
132 protocol is blocked by a firewall. Note that this requires a user account
133 with an uploaded SSH key on all servers used.  (Implies `--nokia-developer').
134
135
136 =item --http
137
138 Use the HTTP protocol for git operations.  This may be useful if the git
139 protocol is blocked by a firewall.  Note that this only works with the
140 external Gitorious server.
141
142
143 =item --codereview-username <Gerrit/JIRA username>
144
145 Adds a gerrit alias to repos under Gerrit codereview management.
146 This requires a username for SSH access to the codereview.qt.nokia.com
147 server, which will be the same username you have for the bugtracker at
148 bugreports.qt.nokia.com.
149
150
151 =item --alternates <path to other Qt5 repo>
152
153 Adds alternates for each submodule to another full qt5 checkout. This makes
154 this qt5 checkout very small, as it will use the object store of the
155 alternates before unique objects are stored in its own object store.
156
157 This option has no effect when using `--no-update'.
158
159 B<NOTE:> This will make this repo dependent on the alternate, which is
160 potentially dangerous!  The dependency can be broken by also using
161 the `--copy-objects' option, or by running C<git repack -a> in each
162 submodule, where required.  Please read the note about the `--shared' option
163 in the documentation of `git clone' for more information.
164
165
166 =item --copy-objects
167
168 When `--alternates' is used, automatically do a C<git repack -a> in each
169 submodule after cloning, to ensure that the repositories are independent
170 from the source used as a reference for cloning.
171
172 Note that this negates the disk usage benefits gained from the use of
173 `--alternates'.
174
175
176 =item --mirror <url-base>
177
178 Uses <url-base> as the base URL for submodule git mirrors.
179
180 For example:
181
182   --mirror user@machine:/foo/bar
183
184 ...will use the following as a mirror for qtbase:
185
186   user@machine:/foo/bar/qtbase.git
187
188
189 =item --mirror-webkit <url>
190
191 Uses <url> as the URL for the webkit git mirror.
192
193 =back
194
195 =cut
196
197 use Carp         qw( confess             );
198 use English      qw( -no_match_vars      );
199 use Getopt::Long qw( GetOptionsFromArray );
200 use Pod::Usage   qw( pod2usage           );
201 use Cwd          qw( getcwd              );
202
203 my %PROTOCOLS = (
204     'internal'  => 'git://scm.dev.nokia.troll.no/' ,
205     'ssh'       => 'git@scm.dev.nokia.troll.no:'   ,
206     'http'      => 'http://git.gitorious.org/'     ,
207 );
208
209 my %STAGING_REPOS = map { $_ => "git://gitorious.org/qt/$_-staging.git" } qw(
210     qt5
211     qt3support
212     qtactiveqt
213     qtbase
214     qtdeclarative
215     qtdoc
216     qtmultimedia
217     qtphonon
218     qtqa
219     qtscript
220     qtsvg
221     qttools
222     qttranslations
223     qtwebkit-examples-and-demos
224     qtxmlpatterns
225     qtlocation
226     qtsensors
227     qtsystems
228     qtfeedback
229 );
230
231 my %GERRIT_REPOS = map { $_ => "codereview.qt.nokia.com:qt/$_.git" } qw(
232     qtbase
233     qtdeclarative
234     qtdoc
235     qtmultimediakit
236 );
237
238 my $BNE_MIRROR_URL_BASE
239     = 'git://bq-git.apac.nokia.com/qtsoftware/qt/';
240
241 my $BNE_MIRROR_WEBKIT_URL
242     = 'git://bq-git.apac.nokia.com/qtsoftware/research/gitorious-org-webkit-qtwebkit-mirror.git';
243
244 my $BER_MIRROR_URL_BASE
245     = 'git://ber-git.europe.nokia.com/qt/';
246
247 my $BER_MIRROR_WEBKIT_URL
248     = 'git://ber-git.europe.nokia.com/qtwebkit/qtwebkit.git';
249
250
251 sub new
252 {
253     my ($class, @arguments) = @_;
254
255     my $self = {};
256     bless $self, $class;
257     $self->parse_arguments(@arguments);
258
259     return $self;
260 }
261
262 # Like `system', but possibly log the command, and die on non-zero exit code
263 sub exe
264 {
265     my ($self, @cmd) = @_;
266
267     if (!$self->{quiet}) {
268         print "+ @cmd\n";
269     }
270
271     if (system(@cmd) != 0) {
272         confess "@cmd exited with status $CHILD_ERROR";
273     }
274
275     return;
276 }
277
278 sub parse_arguments
279 {
280     my ($self, @args) = @_;
281
282     %{$self} = (%{$self},
283         'alternates'          => "",
284         'codereview-username' => "",
285         'detach-alternates'   => 0 ,
286         'force'               => 0 ,
287         'ignore-submodules'   => 0 ,
288         'mirror-url'          => "",
289         'mirror-webkit-url'   => "",
290         'nokia-developer'     => 0 ,
291         'protocol'            => "",
292         'update'              => 1 ,
293         'webkit'              => 1 ,
294     );
295
296     GetOptionsFromArray(\@args,
297         'alternates=s'      =>  \$self->{qw{ alternates        }},
298         'codereview-username=s' => \$self->{qw{ codereview-username }},
299         'copy-objects'      =>  \$self->{qw{ detach-alternates }},
300         'force'             =>  \$self->{qw{ force             }},
301         'ignore-submodules' =>  \$self->{qw{ ignore-submodules }},
302         'mirror-webkit=s'   =>  \$self->{qw{ mirror-webkit-url }},
303         'mirror=s'          =>  \$self->{qw{ mirror-url        }},
304         'nokia-developer'   =>  \$self->{qw{ nokia-developer   }},
305         'quiet'             =>  \$self->{qw{ quiet             }},
306         'update!'           =>  \$self->{qw{ update            }},
307         'webkit!'           =>  \$self->{qw{ webkit            }},
308
309         'help|?'            =>  sub { pod2usage(1);               },
310         'http'              =>  sub { $self->{protocol} = 'http'; },
311         'ssh|ssh-protocol'  =>  sub { $self->{protocol} = 'ssh';  },
312
313         'brisbane|brisbane-nokia-developer' => sub {
314             $self->{'nokia-developer'}   = 1;
315             $self->{'protocol'}          = 'internal';
316             $self->{'mirror-url'}        = $BNE_MIRROR_URL_BASE;
317             $self->{'mirror-webkit-url'} = $BNE_MIRROR_WEBKIT_URL;
318             $self->{'ignore-submodules'} = 1;
319         },
320
321         'berlin|berlin-nokia-developer' => sub {
322             $self->{'nokia-developer'}   = 1;
323             $self->{'protocol'}          = 'internal';
324             $self->{'mirror-url'}        = $BER_MIRROR_URL_BASE;
325             $self->{'mirror-webkit-url'} = $BER_MIRROR_WEBKIT_URL;
326         },
327
328         'nokia-developer' => sub {
329             $self->{'nokia-developer'}   = 1;
330             $self->{'protocol'}          = 'internal';
331             $self->{'ignore-submodules'} = 1;
332         },
333     ) || pod2usage(2);
334
335     if ($self->{'nokia-developer'} && $self->{'protocol'} eq 'http') {
336         print "*** Ignoring use of HTTP protocol, as it's only usable with external server\n";
337         $self->{'protocol'} = '';
338     }
339
340     # Replace any double trailing slashes from end of mirror
341     $self->{'mirror-url'} =~ s{//+$}{/};
342
343     return;
344 }
345
346 sub check_if_already_initialized
347 {
348     my ($self) = @_;
349
350     # We consider the repo as `initialized' if submodule.qtbase.url is set
351     if (qx(git config --get submodule.qtbase.url)) {
352         if ($self->{force}) {
353             my @configresult = qx(git config -l);
354             foreach (@configresult) {
355                 # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
356                 if (/(submodule\.[^.=]+)\.url=.*/) {
357                     $self->exe('git', 'config', '--remove-section', $1);
358                 }
359             }
360         }
361         else {
362             exit 0 if ($self->{quiet});
363             print "Will not reinitialize already initialized repository (use -f to force)!\n";
364             exit 1;
365         }
366     }
367
368     return;
369 }
370
371 sub git_submodule_init
372 {
373     my ($self) = @_;
374
375     my @init_args;
376     if ($self->{quiet}) {
377         push @init_args, '--quiet';
378     }
379     $self->exe('git', 'submodule', 'init', @init_args);
380
381     my $template = getcwd()."/.commit-template";
382     if (-e $template) {
383         $self->exe('git', 'config', 'commit.template', $template);
384     }
385
386     return;
387 }
388
389 sub git_disable_webkit_submodule
390 {
391     my ($self) = @_;
392
393     $self->exe('git', 'config', '--remove', 'submodule.qtwebkit');
394     $self->exe('git', 'config', '--remove', 'submodule.qtwebkit-examples-and-demos');
395
396     return;
397 }
398
399 sub git_set_submodule_config
400 {
401     my ($self) = @_;
402
403     my @configresult          = qx(git config -l);
404     my $protocol              = $self->{protocol};
405     my $url_base_for_protocol = $PROTOCOLS{$protocol};
406
407     foreach my $line (@configresult) {
408         # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
409         next if ($line !~ /(submodule\.[^.=]+\.url)=(.*)/);
410
411         my $key   = $1;
412         my $value = $2;
413
414         if ($protocol) {
415             # WebKit is special, and has only external link.
416             if ($key ne 'submodule.qtwebkit.url') {
417                 # qt-labs projects are still hosted under qt internally.
418                 if ($protocol ne 'http') {
419                     $value =~ s,^git://gitorious\.org/qt-labs/,${url_base_for_protocol}qt/,;
420                 }
421                 $value =~ s,^git://gitorious\.org/,$url_base_for_protocol,;
422             }
423         }
424
425         $self->exe('git', 'config', $key, $value);
426
427         if ($self->{'ignore-submodules'}) {
428             $key =~ s,\.url,.ignore,;
429             $self->exe('git', 'config', $key, 'all');
430         }
431     }
432
433     return;
434 }
435
436 sub git_clone_all_submodules
437 {
438     my ($self) = @_;
439
440     # manually clone each repo here, so we can easily use reference repos, mirrors and
441     # add all staging repos
442     my @configresult = qx(git config -l);
443     foreach my $line (@configresult) {
444         if ($line =~ /submodule\.([^.=]+)\.url=(.*)/) {
445             $self->git_clone_one_submodule($1, $2);
446         }
447     }
448
449     $self->exe('git', 'submodule', 'update');
450
451     return;
452 }
453
454 sub git_add_remotes
455 {
456     my ($self, $repo_basename) = @_;
457
458     my $protocol              = $self->{protocol};
459     my $url_base_for_protocol = $PROTOCOLS{$protocol};
460
461     my %current_remotes;
462     for my $line (qx(git remote show)) {
463         chomp $line;
464         $current_remotes{$line} = 1;
465     }
466
467     my @gerrit = grep { /^$repo_basename$/; } keys %GERRIT_REPOS;
468     if (!$current_remotes{'gerrit'} && $self->{'codereview-username'}) {
469         foreach my $gerrit_repo (@gerrit) {
470             my $gerrit_repo_url = $GERRIT_REPOS{$gerrit_repo};
471             $self->exe('git', 'remote', 'add', 'gerrit', $self->{'codereview-username'}."@".$gerrit_repo_url);
472         }
473     }
474
475     my @staging = grep { /^$repo_basename$/; } keys %STAGING_REPOS;
476     if (!$current_remotes{'staging'}) {
477         foreach my $staging_repo (@staging) {
478             my $staging_repo_url = $STAGING_REPOS{$staging_repo};
479             if ($protocol) {
480                 if ($protocol ne 'http') {
481                     $staging_repo_url =~ s,^git://gitorious\.org/qt-labs/,${url_base_for_protocol}qt/,;
482                 }
483                 $staging_repo_url =~ s,^git://gitorious\.org/,$url_base_for_protocol,;
484             }
485             $self->exe('git', 'remote', 'add', 'staging', $staging_repo_url);
486         }
487     }
488
489     # if repo has no staging repo defined, alias it to gerrit or origin
490     if (!$current_remotes{'staging'} && !@staging) {
491         my @configresult = qx(git remote -v);
492         my $staging_set = 0;
493         foreach (@configresult) {
494             if (/^gerrit\s+(\S+) \(fetch\)/) {
495                 $self->exe('git', 'remote', 'add', 'staging', $1);
496                 $staging_set = 1;
497             }
498         }
499         unless($staging_set) {
500             foreach (@configresult) {
501                 if (/^origin\s+(\S+) \(fetch\)/) {
502                     $self->exe('git', 'remote', 'add', 'staging', $1);
503                 }
504             }
505         }
506     }
507     #if repo has no gerrit repo defined, alias it to whatever staging now points to (could be origin)
508     if (!$current_remotes{'gerrit'} && !@gerrit) {
509         my @configresult = qx(git remote -v);
510         foreach (@configresult) {
511             if (/^staging\s+(\S+) \(fetch\)/) {
512                 $self->exe('git', 'remote', 'add', 'gerrit', $1);
513             }
514         }
515     }
516
517     return;
518 }
519
520 sub git_clone_one_submodule
521 {
522     my ($self, $submodule, $url) = @_;
523
524     my $alternates            = $self->{ 'alternates'        };
525     my $mirror_url            = $self->{ 'mirror-url'        };
526     my $mirror_webkit_url     = $self->{ 'mirror-webkit-url' };
527
528     # `--reference FOO' args for the clone, if any.
529     my @reference_args;
530
531     if ($alternates) {
532         # alternates is a qt5 repo, so the submodule will be under that.
533         if (-d "$alternates/$submodule") {
534             @reference_args = ('--reference', "$alternates/$submodule");
535         }
536         else {
537             print " *** $alternates/$submodule not found, ignoring alternate for this submodule\n";
538         }
539     }
540
541     my $mirror;
542     if ($mirror_url && ($submodule ne 'qtwebkit')) {
543         $mirror = $mirror_url.$submodule;
544         $mirror .= ".git" unless (-d $mirror); # Support local disk mirror
545     }
546     elsif ($mirror_webkit_url && ($submodule eq 'qtwebkit')) {
547         $mirror = $mirror_webkit_url;
548     }
549
550     my $do_clone = (! -d "$submodule/.git");
551     if ($do_clone) {
552         $self->exe('git', 'clone', @reference_args, ($mirror ? $mirror : $url), $submodule);
553     }
554
555     chdir($submodule) or confess "chdir $submodule: $OS_ERROR";
556
557     if (!$do_clone) {
558         $self->exe('git', 'fetch', ($mirror ? $mirror : $url));
559     }
560
561     my $template = getcwd()."/../.commit-template";
562     if (-e $template) {
563         $self->exe('git', 'config', 'commit.template', $template);
564     }
565
566     if ($mirror) {
567         $self->exe('git', 'config', 'remote.origin.url', $url);
568
569         # In `force' mode, remove the mirror if it already exists,
570         # since we may be reinitializing the module.
571         if ($self->{force}) {
572             eval { $self->exe('git', 'remote', 'rm', 'mirror'); }; # failure is OK
573         }
574
575         $self->exe('git', 'remote', 'add', 'mirror', $mirror);
576     }
577
578     $self->git_add_remotes($submodule);
579
580     if ($self->{'detach-alternates'}) {
581         $self->exe('git', 'repack', '-a');
582
583         my $alternates_path = '.git/objects/info/alternates';
584         unlink($alternates_path) || confess "unlink $alternates_path: $OS_ERROR";
585     }
586
587     if ($submodule eq "qtdeclarative") { #Extra step needed to setup declarative 
588         $self->exe('git', 'submodule', 'init'); 
589         $self->exe('git', 'submodule', 'update'); 
590     } 
591
592     chdir("..") or confess "cd ..: $OS_ERROR";
593
594     return;
595 }
596
597 sub run
598 {
599     my ($self) = @_;
600
601     $self->check_if_already_initialized;
602     $self->git_submodule_init;
603
604     if (!$self->{webkit}) {
605         $self->git_disable_webkit_submodule;
606     }
607
608     $self->git_set_submodule_config;
609
610     if ($self->{update}) {
611         $self->git_clone_all_submodules;
612     }
613
614     $self->git_add_remotes('qt5');
615
616     return;
617 }
618
619 #==============================================================================
620
621 Qt::InitRepository->new(@ARGV)->run if (!caller);
622 1;