Add --berlin to set up WebKit mirror accordingly.
[mirror/qt/qt5.git] / init-repository
1 #!/usr/bin/env perl
2 #############################################################################
3 ##
4 ## Copyright (C) 2011 Nokia Corporation and/or its subsidiary(-ies).
5 ## All rights reserved.
6 ## Contact: Nokia Corporation (qt-info@nokia.com)
7 ##
8 ## This file is part of the utilities of the Qt Toolkit.
9 ##
10 ## $QT_BEGIN_LICENSE:LGPL$
11 ## No Commercial Usage
12 ## This file contains pre-release code and may not be distributed.
13 ## You may use this file in accordance with the terms and conditions
14 ## contained in the Technology Preview License Agreement accompanying
15 ## this package.
16 ##
17 ## GNU Lesser General Public License Usage
18 ## Alternatively, this file may be used under the terms of the GNU Lesser
19 ## General Public License version 2.1 as published by the Free Software
20 ## Foundation and appearing in the file LICENSE.LGPL included in the
21 ## packaging of this file.  Please review the following information to
22 ## ensure the GNU Lesser General Public License version 2.1 requirements
23 ## will be met: http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
24 ##
25 ## In addition, as a special exception, Nokia gives you certain additional
26 ## rights.  These rights are described in the Nokia Qt LGPL Exception
27 ## version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
28 ##
29 ## If you have questions regarding the use of this file, please contact
30 ## Nokia at qt-info@nokia.com.
31 ##
32 ##
33 ##
34 ##
35 ##
36 ##
37 ##
38 ##
39 ## $QT_END_LICENSE$
40 ##
41 #############################################################################
42
43 use v5.10;
44 use strict;
45 use warnings;
46
47 package Qt::InitRepository;
48
49
50 =head1 NAME
51
52 init-repository - initialize the Qt5 repository and all submodules
53
54 =head1 SYNOPSIS
55
56   ./init-repository [options]
57
58 This script may be run after an initial `git clone' of Qt5 in order to check
59 out all submodules.
60
61
62 =head1 OPTIONS
63
64 B<Global options:>
65
66 =over
67
68 =item --force, -f
69
70 Force initialization (even if the submodules are already checked out).
71
72
73 =item --quiet, -q
74
75 Be quiet.  Will exit cleanly if the repository is already initialized.
76
77 =back
78
79
80 B<Module options:>
81
82 =over
83
84 =item --no-webkit
85
86 Skip webkit and webkit examples submodules.
87 It may be desirable to skip these modules due to the large size of the webkit
88 git repository.
89
90
91 =item --no-update
92
93 Skip the `git submodule update' command.
94
95
96 =item --ignore-submodules
97
98 Set git config to ignore submodules by default when doing operations on the
99 qt5 repo, such as `pull', `fetch', `diff' etc.
100
101 This option is default for --nokia-developer/--brisbane.
102
103 After using this option, pass `--ignore-submodules=none' to git to override
104 it as needed.
105
106 =back
107
108
109 B<Repository options:>
110
111 =over
112
113 =item --nokia-developer
114
115 Switch to internal Nokia URLs.
116
117
118 =item --brisbane
119
120 Switch to internal Nokia URLs and make use of the Brisbane git mirrors.
121 (Implies `--mirror' and `--mirror-webkit').
122
123 =item --berlin
124
125 Switch to internal Nokia URLs and make use of the Berlin git mirrors.
126 (Implies `--mirror' and `--mirror-webkit').
127
128
129 =item --ssh
130
131 Use the SSH protocol for git operations.  This may be useful if the git
132 protocol is blocked by a firewall. Note that this requires a user account
133 with an uploaded SSH key on all servers used.  (Implies `--nokia-developer').
134
135
136 =item --http
137
138 Use the HTTP protocol for git operations.  This may be useful if the git
139 protocol is blocked by a firewall.  Note that this only works with the
140 external Gitorious server.
141
142
143 =item --codereview-username <Gerrit/JIRA username>
144
145 Adds a gerrit alias to repos under Gerrit codereview management.
146 This requires a username for SSH access to the codereview.qt.nokia.com
147 server, which will be the same username you have for the bugtracker at
148 bugreports.qt.nokia.com.
149
150
151 =item --alternates <path to other Qt5 repo>
152
153 Adds alternates for each submodule to another full qt5 checkout. This makes
154 this qt5 checkout very small, as it will use the object store of the
155 alternates before unique objects are stored in its own object store.
156
157 This option has no effect when using `--no-update'.
158
159 B<NOTE:> This will make this repo dependent on the alternate, which is
160 potentially dangerous!  The dependency can be broken by also using
161 the `--copy-objects' option, or by running C<git repack -a> in each
162 submodule, where required.  Please read the note about the `--shared' option
163 in the documentation of `git clone' for more information.
164
165
166 =item --copy-objects
167
168 When `--alternates' is used, automatically do a C<git repack -a> in each
169 submodule after cloning, to ensure that the repositories are independent
170 from the source used as a reference for cloning.
171
172 Note that this negates the disk usage benefits gained from the use of
173 `--alternates'.
174
175
176 =item --mirror <url-base>
177
178 Uses <url-base> as the base URL for submodule git mirrors.
179
180 For example:
181
182   --mirror user@machine:/foo/bar
183
184 ...will use the following as a mirror for qtbase:
185
186   user@machine:/foo/bar/qtbase.git
187
188
189 =item --mirror-webkit <url>
190
191 Uses <url> as the URL for the webkit git mirror.
192
193 =back
194
195 =cut
196
197 use Carp         qw( confess             );
198 use English      qw( -no_match_vars      );
199 use Getopt::Long qw( GetOptionsFromArray );
200 use Pod::Usage   qw( pod2usage           );
201 use Cwd          qw( getcwd              );
202
203 my %PROTOCOLS = (
204     'internal'  => 'git://scm.dev.nokia.troll.no/' ,
205     'ssh'       => 'git@scm.dev.nokia.troll.no:'   ,
206     'http'      => 'http://git.gitorious.org/'     ,
207 );
208
209 my %STAGING_REPOS = map { $_ => "git://gitorious.org/qt/$_-staging.git" } qw(
210     qt5
211     qt3support
212     qtactiveqt
213     qtbase
214     qtdeclarative
215     qtdoc
216     qtmultimedia
217     qtphonon
218     qtqa
219     qtscript
220     qtsvg
221     qttools
222     qttranslations
223     qtwebkit-examples-and-demos
224     qtxmlpatterns
225     qtlocation
226     qtsensors
227 );
228
229 my %GERRIT_REPOS = map { $_ => "codereview.qt.nokia.com:qt/$_.git" } qw(
230     qtbase
231 );
232
233 my $BNE_MIRROR_URL_BASE
234     = 'git://bq-git.apac.nokia.com/qtsoftware/qt/';
235
236 my $BNE_MIRROR_WEBKIT_URL
237     = 'git://bq-git.apac.nokia.com/qtsoftware/research/gitorious-org-webkit-qtwebkit-mirror.git';
238
239 my $BER_MIRROR_URL_BASE
240     = 'git://ber-git.europe.nokia.com/qt/';
241
242 my $BER_MIRROR_WEBKIT_URL
243     = 'git://ber-git.europe.nokia.com/qtwebkit/qtwebkit.git';
244
245
246 sub new
247 {
248     my ($class, @arguments) = @_;
249
250     my $self = {};
251     bless $self, $class;
252     $self->parse_arguments(@arguments);
253
254     return $self;
255 }
256
257 # Like `system', but possibly log the command, and die on non-zero exit code
258 sub exe
259 {
260     my ($self, @cmd) = @_;
261
262     if (!$self->{quiet}) {
263         print "+ @cmd\n";
264     }
265
266     if (system(@cmd) != 0) {
267         confess "@cmd exited with status $CHILD_ERROR";
268     }
269
270     return;
271 }
272
273 sub parse_arguments
274 {
275     my ($self, @args) = @_;
276
277     %{$self} = (%{$self},
278         'alternates'          => "",
279         'codereview-username' => "",
280         'detach-alternates'   => 0 ,
281         'force'               => 0 ,
282         'ignore-submodules'   => 0 ,
283         'mirror-url'          => "",
284         'mirror-webkit-url'   => "",
285         'nokia-developer'     => 0 ,
286         'protocol'            => "",
287         'update'              => 1 ,
288         'webkit'              => 1 ,
289     );
290
291     GetOptionsFromArray(\@args,
292         'alternates=s'      =>  \$self->{qw{ alternates        }},
293         'codereview-username=s' => \$self->{qw{ codereview-username }},
294         'copy-objects'      =>  \$self->{qw{ detach-alternates }},
295         'force'             =>  \$self->{qw{ force             }},
296         'ignore-submodules' =>  \$self->{qw{ ignore-submodules }},
297         'mirror-webkit=s'   =>  \$self->{qw{ mirror-webkit-url }},
298         'mirror=s'          =>  \$self->{qw{ mirror-url        }},
299         'nokia-developer'   =>  \$self->{qw{ nokia-developer   }},
300         'quiet'             =>  \$self->{qw{ quiet             }},
301         'update!'           =>  \$self->{qw{ update            }},
302         'webkit!'           =>  \$self->{qw{ webkit            }},
303
304         'help|?'            =>  sub { pod2usage(1);               },
305         'http'              =>  sub { $self->{protocol} = 'http'; },
306         'ssh|ssh-protocol'  =>  sub { $self->{protocol} = 'ssh';  },
307
308         'brisbane|brisbane-nokia-developer' => sub {
309             $self->{'nokia-developer'}   = 1;
310             $self->{'protocol'}          = 'internal';
311             $self->{'mirror-url'}        = $BNE_MIRROR_URL_BASE;
312             $self->{'mirror-webkit-url'} = $BNE_MIRROR_WEBKIT_URL;
313             $self->{'ignore-submodules'} = 1;
314         },
315
316         'berlin|berlin-nokia-developer' => sub {
317             $self->{'nokia-developer'}   = 1;
318             $self->{'protocol'}          = 'internal';
319             $self->{'mirror-url'}        = $BER_MIRROR_URL_BASE;
320             $self->{'mirror-webkit-url'} = $BER_MIRROR_WEBKIT_URL;
321         },
322
323         'nokia-developer' => sub {
324             $self->{'nokia-developer'}   = 1;
325             $self->{'protocol'}          = 'internal';
326             $self->{'ignore-submodules'} = 1;
327         },
328     ) || pod2usage(2);
329
330     if ($self->{'nokia-developer'} && $self->{'protocol'} eq 'http') {
331         print "*** Ignoring use of HTTP protocol, as it's only usable with external server\n";
332         $self->{'protocol'} = '';
333     }
334
335     # Replace any double trailing slashes from end of mirror
336     $self->{'mirror-url'} =~ s{//+$}{/};
337
338     return;
339 }
340
341 sub check_if_already_initialized
342 {
343     my ($self) = @_;
344
345     # We consider the repo as `initialized' if submodule.qtbase.url is set
346     if (qx(git config --get submodule.qtbase.url)) {
347         if ($self->{force}) {
348             my @configresult = qx(git config -l);
349             foreach (@configresult) {
350                 # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
351                 if (/(submodule\.[^.=]+)\.url=.*/) {
352                     $self->exe('git', 'config', '--remove-section', $1);
353                 }
354             }
355         }
356         else {
357             exit 0 if ($self->{quiet});
358             print "Will not reinitialize already initialized repository (use -f to force)!\n";
359             exit 1;
360         }
361     }
362
363     return;
364 }
365
366 sub git_submodule_init
367 {
368     my ($self) = @_;
369
370     my @init_args;
371     if ($self->{quiet}) {
372         push @init_args, '--quiet';
373     }
374     $self->exe('git', 'submodule', 'init', @init_args);
375
376     my $template = getcwd()."/.commit-template";
377     if (-e $template) {
378         $self->exe('git', 'config', 'commit.template', $template);
379     }
380
381     return;
382 }
383
384 sub git_disable_webkit_submodule
385 {
386     my ($self) = @_;
387
388     $self->exe('git', 'config', '--remove', 'submodule.qtwebkit');
389     $self->exe('git', 'config', '--remove', 'submodule.qtwebkit-examples-and-demos');
390
391     return;
392 }
393
394 sub git_set_submodule_config
395 {
396     my ($self) = @_;
397
398     my @configresult          = qx(git config -l);
399     my $protocol              = $self->{protocol};
400     my $url_base_for_protocol = $PROTOCOLS{$protocol};
401
402     foreach my $line (@configresult) {
403         # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
404         next if ($line !~ /(submodule\.[^.=]+\.url)=(.*)/);
405
406         my $key   = $1;
407         my $value = $2;
408
409         if ($protocol) {
410             # WebKit is special, and has only external link.
411             if ($key ne 'submodule.qtwebkit.url') {
412                 # qt-labs projects are still hosted under qt internally.
413                 if ($protocol ne 'http') {
414                     $value =~ s,^git://gitorious\.org/qt-labs/,${url_base_for_protocol}qt/,;
415                 }
416                 $value =~ s,^git://gitorious\.org/,$url_base_for_protocol,;
417             }
418         }
419
420         $self->exe('git', 'config', $key, $value);
421
422         if ($self->{'ignore-submodules'}) {
423             $key =~ s,\.url,.ignore,;
424             $self->exe('git', 'config', $key, 'all');
425         }
426     }
427
428     return;
429 }
430
431 sub git_clone_all_submodules
432 {
433     my ($self) = @_;
434
435     # manually clone each repo here, so we can easily use reference repos, mirrors and
436     # add all staging repos
437     my @configresult = qx(git config -l);
438     foreach my $line (@configresult) {
439         if ($line =~ /submodule\.([^.=]+)\.url=(.*)/) {
440             $self->git_clone_one_submodule($1, $2);
441         }
442     }
443
444     $self->exe('git', 'submodule', 'update');
445
446     return;
447 }
448
449 sub git_add_remotes
450 {
451     my ($self, $repo_basename) = @_;
452
453     my $protocol              = $self->{protocol};
454     my $url_base_for_protocol = $PROTOCOLS{$protocol};
455
456     my %current_remotes;
457     for my $line (qx(git remote show)) {
458         chomp $line;
459         $current_remotes{$line} = 1;
460     }
461
462     my @gerrit = grep { /^$repo_basename$/; } keys %GERRIT_REPOS;
463     if (!$current_remotes{'gerrit'} && $self->{'codereview-username'}) {
464         foreach my $gerrit_repo (@gerrit) {
465             my $gerrit_repo_url = $GERRIT_REPOS{$gerrit_repo};
466             $self->exe('git', 'remote', 'add', 'gerrit', $self->{'codereview-username'}."@".$gerrit_repo_url);
467         }
468     }
469
470     my @staging = grep { /^$repo_basename$/; } keys %STAGING_REPOS;
471     if (!$current_remotes{'staging'}) {
472         foreach my $staging_repo (@staging) {
473             my $staging_repo_url = $STAGING_REPOS{$staging_repo};
474             if ($protocol) {
475                 if ($protocol ne 'http') {
476                     $staging_repo_url =~ s,^git://gitorious\.org/qt-labs/,${url_base_for_protocol}qt/,;
477                 }
478                 $staging_repo_url =~ s,^git://gitorious\.org/,$url_base_for_protocol,;
479             }
480             $self->exe('git', 'remote', 'add', 'staging', $staging_repo_url);
481         }
482     }
483
484     # if repo has no staging repo defined, alias it to gerrit or origin
485     if (!$current_remotes{'staging'} && !@staging) {
486         my @configresult = qx(git remote -v);
487         my $staging_set = 0;
488         foreach (@configresult) {
489             if (/^gerrit\s+(\S+) \(fetch\)/) {
490                 $self->exe('git', 'remote', 'add', 'staging', $1);
491                 $staging_set = 1;
492             }
493         }
494         unless($staging_set) {
495             foreach (@configresult) {
496                 if (/^origin\s+(\S+) \(fetch\)/) {
497                     $self->exe('git', 'remote', 'add', 'staging', $1);
498                 }
499             }
500         }
501     }
502     #if repo has no gerrit repo defined, alias it to whatever staging now points to (could be origin)
503     if (!$current_remotes{'gerrit'} && !@gerrit) {
504         my @configresult = qx(git remote -v);
505         foreach (@configresult) {
506             if (/^staging\s+(\S+) \(fetch\)/) {
507                 $self->exe('git', 'remote', 'add', 'gerrit', $1);
508             }
509         }
510     }
511
512     return;
513 }
514
515 sub git_clone_one_submodule
516 {
517     my ($self, $submodule, $url) = @_;
518
519     my $alternates            = $self->{ 'alternates'        };
520     my $mirror_url            = $self->{ 'mirror-url'        };
521     my $mirror_webkit_url     = $self->{ 'mirror-webkit-url' };
522
523     # `--reference FOO' args for the clone, if any.
524     my @reference_args;
525
526     if ($alternates) {
527         # alternates is a qt5 repo, so the submodule will be under that.
528         if (-d "$alternates/$submodule") {
529             @reference_args = ('--reference', "$alternates/$submodule");
530         }
531         else {
532             print " *** $alternates/$submodule not found, ignoring alternate for this submodule\n";
533         }
534     }
535
536     my $mirror;
537     if ($mirror_url && ($submodule ne 'qtwebkit')) {
538         $mirror = $mirror_url.$submodule;
539         $mirror .= ".git" unless (-d $mirror); # Support local disk mirror
540     }
541     elsif ($mirror_webkit_url && ($submodule eq 'qtwebkit')) {
542         $mirror = $mirror_webkit_url;
543     }
544
545     my $do_clone = (! -d "$submodule/.git");
546     if ($do_clone) {
547         $self->exe('git', 'clone', @reference_args, ($mirror ? $mirror : $url), $submodule);
548     }
549
550     chdir($submodule) or confess "chdir $submodule: $OS_ERROR";
551
552     if (!$do_clone) {
553         $self->exe('git', 'fetch', ($mirror ? $mirror : $url));
554     }
555
556     my $template = getcwd()."/../.commit-template";
557     if (-e $template) {
558         $self->exe('git', 'config', 'commit.template', $template);
559     }
560
561     if ($mirror) {
562         $self->exe('git', 'config', 'remote.origin.url', $url);
563
564         # In `force' mode, remove the mirror if it already exists,
565         # since we may be reinitializing the module.
566         if ($self->{force}) {
567             eval { $self->exe('git', 'remote', 'rm', 'mirror'); }; # failure is OK
568         }
569
570         $self->exe('git', 'remote', 'add', 'mirror', $mirror);
571     }
572
573     $self->git_add_remotes($submodule);
574
575     if ($self->{'detach-alternates'}) {
576         $self->exe('git', 'repack', '-a');
577
578         my $alternates_path = '.git/objects/info/alternates';
579         unlink($alternates_path) || confess "unlink $alternates_path: $OS_ERROR";
580     }
581
582     chdir("..") or confess "cd ..: $OS_ERROR";
583
584     return;
585 }
586
587 sub run
588 {
589     my ($self) = @_;
590
591     $self->check_if_already_initialized;
592     $self->git_submodule_init;
593
594     if (!$self->{webkit}) {
595         $self->git_disable_webkit_submodule;
596     }
597
598     $self->git_set_submodule_config;
599
600     if ($self->{update}) {
601         $self->git_clone_all_submodules;
602     }
603
604     $self->git_add_remotes('qt5');
605
606     return;
607 }
608
609 #==============================================================================
610
611 Qt::InitRepository->new(@ARGV)->run if (!caller);
612 1;