init-repository: fixed incorrect example for --mirror option
[mirror/qt/qt5.git] / init-repository
1 #!/usr/bin/env perl
2 #############################################################################
3 ##
4 ## Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
5 ## Contact: http://www.qt-project.org/
6 ##
7 ## This file is part of the utilities of the Qt Toolkit.
8 ##
9 ## $QT_BEGIN_LICENSE:LGPL$
10 ## GNU Lesser General Public License Usage
11 ## This file may be used under the terms of the GNU Lesser General Public
12 ## License version 2.1 as published by the Free Software Foundation and
13 ## appearing in the file LICENSE.LGPL included in the packaging of this
14 ## file. Please review the following information to ensure the GNU Lesser
15 ## General Public License version 2.1 requirements will be met:
16 ## http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
17 ##
18 ## In addition, as a special exception, Nokia gives you certain additional
19 ## rights. These rights are described in the Nokia Qt LGPL Exception
20 ## version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
21 ##
22 ## GNU General Public License Usage
23 ## Alternatively, this file may be used under the terms of the GNU General
24 ## Public License version 3.0 as published by the Free Software Foundation
25 ## and appearing in the file LICENSE.GPL included in the packaging of this
26 ## file. Please review the following information to ensure the GNU General
27 ## Public License version 3.0 requirements will be met:
28 ## http://www.gnu.org/copyleft/gpl.html.
29 ##
30 ## Other Usage
31 ## Alternatively, this file may be used in accordance with the terms and
32 ## conditions contained in a signed written agreement between you and Nokia.
33 ##
34 ##
35 ##
36 ##
37 ##
38 ##
39 ## $QT_END_LICENSE$
40 ##
41 #############################################################################
42
43 use v5.8;
44 use strict;
45 use warnings;
46
47 package Qt::InitRepository;
48
49
50 =head1 NAME
51
52 init-repository - initialize the Qt5 repository and all submodules
53
54 =head1 SYNOPSIS
55
56   ./init-repository [options]
57
58 This script may be run after an initial `git clone' of Qt5 in order to check
59 out all submodules.
60
61
62 =head1 OPTIONS
63
64 B<Global options:>
65
66 =over
67
68 =item --force, -f
69
70 Force initialization (even if the submodules are already checked out).
71
72
73 =item --quiet, -q
74
75 Be quiet.  Will exit cleanly if the repository is already initialized.
76
77 =back
78
79
80 B<Module options:>
81
82 =over
83
84 =item --no-webkit
85
86 Skip webkit and webkit examples submodules.
87 It may be desirable to skip these modules due to the large size of the webkit
88 git repository.
89
90 =item --module-subset=<module1>,<module2>...
91
92 Only initialize the specified subset of modules given as the argument. Specified
93 modules must already exist in .gitmodules.
94
95 =item --no-update
96
97 Skip the `git submodule update' command.
98
99
100 =item --ignore-submodules
101
102 Set git config to ignore submodules by default when doing operations on the
103 qt5 repo, such as `pull', `fetch', `diff' etc.
104
105 This option is default for --nokia-developer/--brisbane.
106
107 After using this option, pass `--ignore-submodules=none' to git to override
108 it as needed.
109
110 =back
111
112
113 B<Repository options:>
114
115 =over
116
117 =item --nokia-developer
118
119 Switch to internal Nokia URLs.
120
121
122 =item --brisbane
123
124 Switch to internal Nokia URLs and make use of the Brisbane git mirrors.
125 (Implies `--mirror' and `--mirror-webkit').
126
127 =item --berlin
128
129 Switch to internal Nokia URLs and make use of the Berlin git mirrors.
130 (Implies `--mirror' and `--mirror-webkit').
131
132
133 =item --ssh
134
135 Use the SSH protocol for git operations.  This may be useful if the git
136 protocol is blocked by a firewall. Note that this requires a user account
137 with an uploaded SSH key on all servers used.  (Implies `--nokia-developer').
138
139 The `--ssh' option does not affect the gerrit remotes.
140
141
142 =item --http
143
144 Use the HTTP protocol for git operations.  This may be useful if the git
145 protocol is blocked by a firewall.  Note that this only works with the
146 external Gitorious server.
147
148 The `--http' option does not affect the gerrit remotes.
149
150
151 =item --codereview-username <Gerrit/JIRA username>
152
153 Specify the user name for the (potentially) writable `gerrit' remote
154 for each module, for use with the Gerrit code review tool.
155
156 If this option is omitted, the gerrit remote is created without a username
157 and port number, and thus relies on a correct SSH configuration.
158
159
160 =item --alternates <path to other Qt5 repo>
161
162 Adds alternates for each submodule to another full qt5 checkout. This makes
163 this qt5 checkout very small, as it will use the object store of the
164 alternates before unique objects are stored in its own object store.
165
166 This option has no effect when using `--no-update'.
167
168 B<NOTE:> This will make this repo dependent on the alternate, which is
169 potentially dangerous!  The dependency can be broken by also using
170 the `--copy-objects' option, or by running C<git repack -a> in each
171 submodule, where required.  Please read the note about the `--shared' option
172 in the documentation of `git clone' for more information.
173
174
175 =item --copy-objects
176
177 When `--alternates' is used, automatically do a C<git repack -a> in each
178 submodule after cloning, to ensure that the repositories are independent
179 from the source used as a reference for cloning.
180
181 Note that this negates the disk usage benefits gained from the use of
182 `--alternates'.
183
184
185 =item --mirror <url-base>
186
187 Uses <url-base> as the base URL for submodule git mirrors.
188
189 For example:
190
191   --mirror user@machine:/foo/bar
192
193 ...will use the following as a mirror for qtbase:
194
195   user@machine:/foo/bar/qt/qtbase.git
196
197 The mirror is permitted to contain a subset of the submodules; any
198 missing modules will fall back to the canonical URLs.
199
200 =item --mirror-webkit <url>
201
202 Uses <url> as the URL for the webkit git mirror.
203
204 =back
205
206 =cut
207
208 use Carp         qw( confess             );
209 use English      qw( -no_match_vars      );
210 use Getopt::Long qw( GetOptionsFromArray );
211 use Pod::Usage   qw( pod2usage           );
212 use Cwd          qw( getcwd              );
213
214 my %PROTOCOLS = (
215     'internal'  => 'git://scm.dev.nokia.troll.no/' ,
216     'ssh'       => 'git@scm.dev.nokia.troll.no:'   ,
217     'http'      => 'http://git.gitorious.org/'     ,
218 );
219
220 my %GERRIT_REPOS = map { $_ => "qt/$_" } qw(
221     qt3d
222     qt5
223     qlalr
224     qtactiveqt
225     qtbase
226     qtconnectivity
227     qtdeclarative
228     qtdoc
229     qtdocgallery
230     qtfeedback
231     qtgraphicaleffects
232     qtimageformats
233     qtjsondb
234     qtjsbackend
235     qtlocation
236     qtmultimedia
237     qtphonon
238     qtpim
239     qtqa
240     qtquick1
241     qtrepotools
242     qtscript
243     qtsensors
244     qtsvg
245     qtsystems
246     qttools
247     qttranslations
248     qtwayland
249     qtwebkit-examples-and-demos
250     qtxmlpatterns
251 );
252
253 my $GERRIT_SSH_BASE
254     = 'ssh://@USER@codereview.qt-project.org@PORT@/';
255
256 my $BNE_MIRROR_URL_BASE
257     = 'git://bq-git.apac.nokia.com/qtsoftware/';
258
259 my $BNE_MIRROR_WEBKIT_URL
260     = 'git://bq-git.apac.nokia.com/qtsoftware/research/gitorious-org-webkit-qtwebkit-mirror.git';
261
262 my $BER_MIRROR_URL_BASE
263     = 'git://ber-git.europe.nokia.com/';
264
265 my $BER_MIRROR_WEBKIT_URL
266     = 'git://ber-git.europe.nokia.com/qtwebkit/qtwebkit.git';
267
268
269 sub new
270 {
271     my ($class, @arguments) = @_;
272
273     my $self = {};
274     bless $self, $class;
275     $self->parse_arguments(@arguments);
276
277     return $self;
278 }
279
280 # Like `system', but possibly log the command, and die on non-zero exit code
281 sub exe
282 {
283     my ($self, @cmd) = @_;
284
285     if (!$self->{quiet}) {
286         print "+ @cmd\n";
287     }
288
289     if (system(@cmd) != 0) {
290         confess "@cmd exited with status $CHILD_ERROR";
291     }
292
293     return;
294 }
295
296 sub parse_arguments
297 {
298     my ($self, @args) = @_;
299
300     %{$self} = (%{$self},
301         'alternates'          => "",
302         'codereview-username' => "",
303         'detach-alternates'   => 0 ,
304         'force'               => 0 ,
305         'ignore-submodules'   => 0 ,
306         'mirror-url'          => "",
307         'mirror-webkit-url'   => "",
308         'nokia-developer'     => 0 ,
309         'protocol'            => "",
310         'update'              => 1 ,
311         'webkit'              => 1 ,
312         'module-subset'       => "",
313     );
314
315     GetOptionsFromArray(\@args,
316         'alternates=s'      =>  \$self->{qw{ alternates        }},
317         'codereview-username=s' => \$self->{qw{ codereview-username }},
318         'copy-objects'      =>  \$self->{qw{ detach-alternates }},
319         'force'             =>  \$self->{qw{ force             }},
320         'ignore-submodules' =>  \$self->{qw{ ignore-submodules }},
321         'mirror-webkit=s'   =>  \$self->{qw{ mirror-webkit-url }},
322         'mirror=s'          =>  \$self->{qw{ mirror-url        }},
323         'nokia-developer'   =>  \$self->{qw{ nokia-developer   }},
324         'quiet'             =>  \$self->{qw{ quiet             }},
325         'update!'           =>  \$self->{qw{ update            }},
326         'webkit!'           =>  \$self->{qw{ webkit            }},
327         'module-subset=s'   =>  \$self->{qw{ module-subset     }},
328
329         'help|?'            =>  sub { pod2usage(1);               },
330         'http'              =>  sub { $self->{protocol} = 'http'; },
331         'ssh|ssh-protocol'  =>  sub { $self->{protocol} = 'ssh';  },
332
333         'brisbane|brisbane-nokia-developer' => sub {
334             $self->{'nokia-developer'}   = 1;
335             $self->{'protocol'}          = 'internal';
336             $self->{'mirror-url'}        = $BNE_MIRROR_URL_BASE;
337             $self->{'mirror-webkit-url'} = $BNE_MIRROR_WEBKIT_URL;
338             $self->{'ignore-submodules'} = 1;
339         },
340
341         'berlin|berlin-nokia-developer' => sub {
342             $self->{'nokia-developer'}   = 1;
343             $self->{'protocol'}          = 'internal';
344             $self->{'mirror-url'}        = $BER_MIRROR_URL_BASE;
345             $self->{'mirror-webkit-url'} = $BER_MIRROR_WEBKIT_URL;
346         },
347
348         'nokia-developer' => sub {
349             $self->{'nokia-developer'}   = 1;
350             $self->{'protocol'}          = 'internal';
351             $self->{'ignore-submodules'} = 1;
352         },
353     ) || pod2usage(2);
354
355     if ($self->{'nokia-developer'} && $self->{'protocol'} eq 'http') {
356         print "*** Ignoring use of HTTP protocol, as it's only usable with external server\n";
357         $self->{'protocol'} = '';
358     }
359
360     # Replace any double trailing slashes from end of mirror
361     $self->{'mirror-url'} =~ s{//+$}{/};
362
363     if ($self->{'module-subset'}) {
364         $self->{'module-subset'} = {
365             map { $_ => 1 } split(qr{,}, $self->{'module-subset'})
366         };
367     }
368
369     return;
370 }
371
372 sub check_if_already_initialized
373 {
374     my ($self) = @_;
375
376     # We consider the repo as `initialized' if submodule.qtbase.url is set
377     if (qx(git config --get submodule.qtbase.url)) {
378         if ($self->{force}) {
379             my @configresult = qx(git config -l);
380             foreach (@configresult) {
381                 # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
382                 if (/(submodule\.[^.=]+)\.url=.*/) {
383                     $self->exe('git', 'config', '--remove-section', $1);
384                 }
385             }
386         }
387         else {
388             exit 0 if ($self->{quiet});
389             print "Will not reinitialize already initialized repository (use -f to force)!\n";
390             exit 1;
391         }
392     }
393
394     return;
395 }
396
397 sub git_submodule_init
398 {
399     my ($self) = @_;
400
401     my @init_args;
402     if ($self->{quiet}) {
403         push @init_args, '--quiet';
404     }
405     $self->exe('git', 'submodule', 'init', @init_args);
406
407     my $template = getcwd()."/.commit-template";
408     if (-e $template) {
409         $self->exe('git', 'config', 'commit.template', $template);
410     }
411
412     return;
413 }
414
415 sub git_disable_webkit_submodule
416 {
417     my ($self) = @_;
418
419     $self->exe('git', 'config', '--remove', 'submodule.qtwebkit');
420     $self->exe('git', 'config', '--remove', 'submodule.qtwebkit-examples-and-demos');
421
422     return;
423 }
424
425 sub git_prune_submodules
426 {
427     my ($self) = @_;
428
429     my @configresult = qx(git config -l);
430     foreach my $line (@configresult) {
431         if ($line =~ /submodule\.([^.=]+)\.url=/) {
432             my $module_name = $1;
433             if (!$self->{'module-subset'}{$module_name}) {
434                 $self->exe('git', 'config', '--remove', "submodule.$module_name");
435             }
436         }
437     }
438 }
439
440 sub git_set_submodule_config
441 {
442     my ($self) = @_;
443
444     my @configresult          = qx(git config -l);
445     my $protocol              = $self->{protocol};
446     my $url_base_for_protocol = $PROTOCOLS{$protocol};
447
448     foreach my $line (@configresult) {
449         # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
450         next if ($line !~ /submodule\.([^.=]+)\.url=(.*)/);
451
452         my $key   = $1;
453         my $value = $2;
454
455         if ($protocol) {
456             # WebKit is special, and has only external link.
457             if ($key ne 'qtwebkit') {
458                 # qt-labs projects are still hosted under qt internally.
459                 if ($protocol ne 'http') {
460                     $value =~ s,^git://gitorious\.org/qt-labs/,${url_base_for_protocol}qt/,;
461                 }
462
463                 # assume all other projects hosted under gitorious publicly.
464                 $value =~ s,^git://gitorious\.org/,$url_base_for_protocol,;
465             }
466         }
467
468         $self->exe('git', 'config', "submodule.$key.url", $value);
469
470         if ($self->{'ignore-submodules'}) {
471             $self->exe('git', 'config', "submodule.$key.ignore", 'all');
472         }
473     }
474
475     return;
476 }
477
478 sub git_clone_all_submodules
479 {
480     my ($self) = @_;
481
482     # manually clone each repo here, so we can easily use reference repos, mirrors etc
483     my @configresult = qx(git config -l);
484     foreach my $line (@configresult) {
485         if ($line =~ /submodule\.([^.=]+)\.url=(.*)/) {
486             $self->git_clone_one_submodule($1, $2);
487         }
488     }
489
490     if ($self->{update}) {
491         $self->exe('git', 'submodule', 'update', '--recursive');
492     }
493
494     return;
495 }
496
497 sub git_add_remotes
498 {
499     my ($self, $repo_basename) = @_;
500
501     my $gerrit_repo_basename = $GERRIT_REPOS{$repo_basename};
502     if ($gerrit_repo_basename) {
503         my $gerrit_repo_url;
504
505         # If given a username, make a "verbose" remote.
506         # Otherwise, rely on proper SSH configuration.
507         if ($self->{'codereview-username'}) {
508             $gerrit_repo_url = $GERRIT_SSH_BASE;
509             $gerrit_repo_url =~ s,\@USER\@,$self->{'codereview-username'}\@,;
510             $gerrit_repo_url =~ s,\@PORT\@,:29418,;
511         }
512         else {
513             $gerrit_repo_url = $GERRIT_SSH_BASE;
514             $gerrit_repo_url =~ s,\@[^\@]+\@,,g;
515         }
516
517         $gerrit_repo_url .= $gerrit_repo_basename;
518         $self->exe('git', 'config', 'remote.gerrit.url', $gerrit_repo_url);
519         $self->exe('git', 'config', 'remote.gerrit.fetch', '+refs/heads/*:refs/remotes/gerrit/*', '/heads/');
520     }
521
522     return;
523 }
524
525 sub git_clone_one_submodule
526 {
527     my ($self, $submodule, $url) = @_;
528
529     my $alternates            = $self->{ 'alternates'        };
530     my $mirror_url            = $self->{ 'mirror-url'        };
531     my $mirror_webkit_url     = $self->{ 'mirror-webkit-url' };
532     my $protocol              = $self->{ 'protocol'          };
533
534     # `--reference FOO' args for the clone, if any.
535     my @reference_args;
536
537     if ($alternates) {
538         # alternates is a qt5 repo, so the submodule will be under that.
539         if (-d "$alternates/$submodule") {
540             @reference_args = ('--reference', "$alternates/$submodule");
541         }
542         else {
543             print " *** $alternates/$submodule not found, ignoring alternate for this submodule\n";
544         }
545     }
546
547     my $mirror;
548     if ($mirror_url && ($submodule ne 'qtwebkit')) {
549         $mirror = $mirror_url."qt/$submodule";
550         $mirror .= ".git" unless (-d $mirror); # Support local disk mirror
551     }
552     elsif ($mirror_webkit_url && ($submodule eq 'qtwebkit')) {
553         $mirror = $mirror_webkit_url;
554     }
555
556     if ($mirror) {
557         # Only use the mirror if it can be reached.
558         eval { $self->exe('git', 'ls-remote', $mirror, 'test/if/mirror/exists') };
559         if ($@) {
560             warn "mirror [$mirror] is not accessible; $url will be used\n";
561             undef $mirror;
562         }
563     }
564
565     my $do_clone = (! -d "$submodule/.git");
566     if ($do_clone) {
567         $self->exe('git', 'clone', @reference_args, ($mirror ? $mirror : $url), $submodule);
568     }
569
570     chdir($submodule) or confess "chdir $submodule: $OS_ERROR";
571
572     $self->exe('git', 'config', 'remote.origin.url', $url);
573     if ($mirror) {
574         $self->exe('git', 'config', 'remote.mirror.url', $mirror);
575         $self->exe('git', 'config', 'remote.mirror.fetch', '+refs/heads/*:refs/remotes/mirror/*');
576     }
577
578     if (!$do_clone) {
579         $self->exe('git', 'fetch', ($mirror ? $mirror : $url));
580     }
581
582     my $template = getcwd()."/../.commit-template";
583     if (-e $template) {
584         $self->exe('git', 'config', 'commit.template', $template);
585     }
586
587     $self->git_add_remotes($submodule);
588
589     if ($self->{'detach-alternates'}) {
590         $self->exe('git', 'repack', '-a');
591
592         my $alternates_path = '.git/objects/info/alternates';
593         if (-e $alternates_path) {
594             unlink($alternates_path) || confess "unlink $alternates_path: $OS_ERROR";
595         }
596     }
597
598     chdir("..") or confess "cd ..: $OS_ERROR";
599
600     return;
601 }
602
603 sub run
604 {
605     my ($self) = @_;
606
607     $self->check_if_already_initialized;
608     $self->git_submodule_init;
609
610     if (!$self->{webkit}) {
611         $self->git_disable_webkit_submodule;
612     }
613
614     if ($self->{'module-subset'}) {
615         $self->git_prune_submodules;
616     }
617
618     $self->git_set_submodule_config;
619
620     $self->git_clone_all_submodules;
621
622     $self->git_add_remotes('qt5');
623
624     return;
625 }
626
627 #==============================================================================
628
629 Qt::InitRepository->new(@ARGV)->run if (!caller);
630 1;