22254893438bc632b65539d3c314e970bccf3f38
[mirror/qt/qt5.git] / init-repository
1 #!/usr/bin/env perl
2 #############################################################################
3 ##
4 ## Copyright (C) 2012 Digia Plc and/or its subsidiary(-ies).
5 ## Contact: http://www.qt-project.org/legal
6 ##
7 ## This file is part of the utilities of the Qt Toolkit.
8 ##
9 ## $QT_BEGIN_LICENSE:LGPL$
10 ## Commercial License Usage
11 ## Licensees holding valid commercial Qt licenses may use this file in
12 ## accordance with the commercial license agreement provided with the
13 ## Software or, alternatively, in accordance with the terms contained in
14 ## a written agreement between you and Digia.  For licensing terms and
15 ## conditions see http://qt.digia.com/licensing.  For further information
16 ## use the contact form at http://qt.digia.com/contact-us.
17 ##
18 ## GNU Lesser General Public License Usage
19 ## Alternatively, this file may be used under the terms of the GNU Lesser
20 ## General Public License version 2.1 as published by the Free Software
21 ## Foundation and appearing in the file LICENSE.LGPL included in the
22 ## packaging of this file.  Please review the following information to
23 ## ensure the GNU Lesser General Public License version 2.1 requirements
24 ## will be met: http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
25 ##
26 ## In addition, as a special exception, Digia gives you certain additional
27 ## rights.  These rights are described in the Digia Qt LGPL Exception
28 ## version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
29 ##
30 ## GNU General Public License Usage
31 ## Alternatively, this file may be used under the terms of the GNU
32 ## General Public License version 3.0 as published by the Free Software
33 ## Foundation and appearing in the file LICENSE.GPL included in the
34 ## packaging of this file.  Please review the following information to
35 ## ensure the GNU General Public License version 3.0 requirements will be
36 ## met: http://www.gnu.org/copyleft/gpl.html.
37 ##
38 ##
39 ## $QT_END_LICENSE$
40 ##
41 #############################################################################
42
43 use v5.8;
44 use strict;
45 use warnings;
46
47 package Qt::InitRepository;
48
49
50 =head1 NAME
51
52 init-repository - initialize the Qt5 repository and all submodules
53
54 =head1 SYNOPSIS
55
56   ./init-repository [options]
57
58 This script may be run after an initial `git clone' of Qt5 in order to check
59 out all submodules.
60
61
62 =head1 OPTIONS
63
64 B<Global options:>
65
66 =over
67
68 =item --force, -f
69
70 Force initialization (even if the submodules are already checked out).
71
72
73 =item --force-hooks
74
75 Force initialization of hooks (even if there are already hooks in checked out
76 submodules).
77
78
79 =item --quiet, -q
80
81 Be quiet.  Will exit cleanly if the repository is already initialized.
82
83 =back
84
85
86 B<Module options:>
87
88 =over
89
90 =item --no-webkit
91
92 Skip webkit and webkit examples submodules.
93 It may be desirable to skip these modules due to the large size of the webkit
94 git repository.
95
96 =item --module-subset=<module1>,<module2>...
97
98 Only initialize the specified subset of modules given as the argument. Specified
99 modules must already exist in .gitmodules.
100 The string "all" results in cloning all known modules. The default is the set of
101 maintained modules.
102
103 =item --no-update
104
105 Skip the `git submodule update' command.
106
107
108 =item --ignore-submodules
109
110 Set git config to ignore submodules by default when doing operations on the
111 qt5 repo, such as `pull', `fetch', `diff' etc.
112
113 After using this option, pass `--ignore-submodules=none' to git to override
114 it as needed.
115
116 =back
117
118
119 B<Repository options:>
120
121 =over
122
123 =item --berlin
124
125 Switch to internal URLs and make use of the Berlin git mirrors.
126 (Implies `--mirror').
127
128 =item --oslo
129
130 Switch to internal URLs and make use of the Oslo git mirrors.
131 (Implies `--mirror').
132
133
134 =item --http
135
136 Use the HTTP protocol for git operations.  This may be useful if the git
137 protocol is blocked by a firewall.  Note that this only works with the
138 external Gitorious server.
139
140 The `--http' option does not affect the gerrit remotes.
141
142
143 =item --codereview-username <Gerrit/JIRA username>
144
145 Specify the user name for the (potentially) writable `gerrit' remote
146 for each module, for use with the Gerrit code review tool.
147
148 If this option is omitted, the gerrit remote is created without a username
149 and port number, and thus relies on a correct SSH configuration.
150
151
152 =item --alternates <path to other Qt5 repo>
153
154 Adds alternates for each submodule to another full qt5 checkout. This makes
155 this qt5 checkout very small, as it will use the object store of the
156 alternates before unique objects are stored in its own object store.
157
158 This option has no effect when using `--no-update'.
159
160 B<NOTE:> This will make this repo dependent on the alternate, which is
161 potentially dangerous!  The dependency can be broken by also using
162 the `--copy-objects' option, or by running C<git repack -a> in each
163 submodule, where required.  Please read the note about the `--shared' option
164 in the documentation of `git clone' for more information.
165
166
167 =item --copy-objects
168
169 When `--alternates' is used, automatically do a C<git repack -a> in each
170 submodule after cloning, to ensure that the repositories are independent
171 from the source used as a reference for cloning.
172
173 Note that this negates the disk usage benefits gained from the use of
174 `--alternates'.
175
176
177 =item --mirror <url-base>
178
179 Uses <url-base> as the base URL for submodule git mirrors.
180
181 For example:
182
183   --mirror user@machine:/foo/bar
184
185 ...will use the following as a mirror for qtbase:
186
187   user@machine:/foo/bar/qt/qtbase.git
188
189 The mirror is permitted to contain a subset of the submodules; any
190 missing modules will fall back to the canonical URLs.
191
192 =back
193
194 =cut
195
196 use Carp         qw( confess             );
197 use English      qw( -no_match_vars      );
198 use Getopt::Long qw( GetOptionsFromArray );
199 use Pod::Usage   qw( pod2usage           );
200 use Cwd          qw( getcwd              );
201
202 my %PROTOCOLS = (
203     'http'      => 'http://git.gitorious.org/'     ,
204 );
205
206 my %GERRIT_REPOS = map { $_ => "qt/$_" } qw(
207     qt3d
208     qt5
209     qtactiveqt
210     qtandroidextras
211     qtbase
212     qtconnectivity
213     qtdeclarative
214     qtdoc
215     qtdocgallery
216     qtenginio
217     qtfeedback
218     qtgraphicaleffects
219     qtimageformats
220     qtjsondb
221     qtlocation
222     qtmacextras
223     qtmultimedia
224     qtpim
225     qtqa
226     qtquick1
227     qtquickcontrols
228     qtrepotools
229     qtscript
230     qtsensors
231     qtserialport
232     qtsvg
233     qtsystems
234     qttools
235     qttranslations
236     qtwayland
237     qtwebchannel
238     qtwebkit
239     qtwebkit-examples
240     qtwebsockets
241     qtwinextras
242     qtx11extras
243     qtxmlpatterns
244 );
245
246 my @DEFAULT_REPOS = qw(
247     qtactiveqt
248     qtandroidextras
249     qtbase
250     qtconnectivity
251     qtdeclarative
252     qtdoc
253     qtenginio
254     qtgraphicaleffects
255     qtimageformats
256     qtmacextras
257     qtmultimedia
258     qtqa
259     qtquick1
260     qtquickcontrols
261     qtlocation
262     qtrepotools
263     qtscript
264     qtsensors
265     qtserialport
266     qtsvg
267     qttools
268     qttranslations
269     qtwayland
270     qtwebchannel
271     qtwebsockets
272     qtwebkit
273     qtwebkit-examples
274     qtwinextras
275     qtx11extras
276     qtxmlpatterns
277 );
278
279 my $GERRIT_SSH_BASE
280     = 'ssh://@USER@codereview.qt-project.org@PORT@/';
281
282 my $BER_MIRROR_URL_BASE
283     = 'git://hegel/';
284
285 my $OSLO_MIRROR_URL_BASE
286     = 'git://qilin/';
287
288 sub new
289 {
290     my ($class, @arguments) = @_;
291
292     my $self = {};
293     bless $self, $class;
294     $self->parse_arguments(@arguments);
295
296     return $self;
297 }
298
299 # Like `system', but possibly log the command, and die on non-zero exit code
300 sub exe
301 {
302     my ($self, @cmd) = @_;
303
304     if (!$self->{quiet}) {
305         print "+ @cmd\n";
306     }
307
308     if (system(@cmd) != 0) {
309         confess "@cmd exited with status $CHILD_ERROR";
310     }
311
312     return;
313 }
314
315 sub parse_arguments
316 {
317     my ($self, @args) = @_;
318
319     %{$self} = (%{$self},
320         'alternates'          => "",
321         'codereview-username' => "",
322         'detach-alternates'   => 0 ,
323         'force'               => 0 ,
324         'force-hooks'         => 0 ,
325         'ignore-submodules'   => 0 ,
326         'mirror-url'          => "",
327         'protocol'            => "",
328         'update'              => 1 ,
329         'webkit'              => 1 ,
330         'module-subset'       => join(",", @DEFAULT_REPOS),
331     );
332
333     GetOptionsFromArray(\@args,
334         'alternates=s'      =>  \$self->{qw{ alternates        }},
335         'codereview-username=s' => \$self->{qw{ codereview-username }},
336         'copy-objects'      =>  \$self->{qw{ detach-alternates }},
337         'force|f'           =>  \$self->{qw{ force             }},
338         'force-hooks'       =>  \$self->{qw{ force-hooks       }},
339         'ignore-submodules' =>  \$self->{qw{ ignore-submodules }},
340         'mirror=s'          =>  \$self->{qw{ mirror-url        }},
341         'quiet'             =>  \$self->{qw{ quiet             }},
342         'update!'           =>  \$self->{qw{ update            }},
343         'webkit!'           =>  \$self->{qw{ webkit            }},
344         'module-subset=s'   =>  \$self->{qw{ module-subset     }},
345
346         'help|?'            =>  sub { pod2usage(1);               },
347         'http'              =>  sub { $self->{protocol} = 'http'; },
348
349         'berlin' => sub {
350             $self->{'mirror-url'}        = $BER_MIRROR_URL_BASE;
351         },
352         'oslo' => sub {
353             $self->{'mirror-url'}        = $OSLO_MIRROR_URL_BASE;
354         },
355     ) || pod2usage(2);
356
357     # Replace any double trailing slashes from end of mirror
358     $self->{'mirror-url'} =~ s{//+$}{/};
359
360     if ($self->{'module-subset'} eq "all") {
361         $self->{'module-subset'} = "";
362     } else {
363         $self->{'module-subset'} = {
364             map { $_ => 1 } split(qr{,}, $self->{'module-subset'})
365         };
366     }
367
368     return;
369 }
370
371 sub check_if_already_initialized
372 {
373     my ($self) = @_;
374
375     # We consider the repo as `initialized' if submodule.qtbase.url is set
376     if (qx(git config --get submodule.qtbase.url)) {
377         if ($self->{force}) {
378             my @configresult = qx(git config -l);
379             foreach (@configresult) {
380                 # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
381                 if (/(submodule\.[^.=]+)\.url=.*/) {
382                     $self->exe('git', 'config', '--remove-section', $1);
383                 }
384             }
385         }
386         else {
387             exit 0 if ($self->{quiet});
388             print "Will not reinitialize already initialized repository (use -f to force)!\n";
389             exit 1;
390         }
391     }
392
393     return;
394 }
395
396 sub git_submodule_init
397 {
398     my ($self) = @_;
399
400     my @init_args;
401     if ($self->{quiet}) {
402         push @init_args, '--quiet';
403     }
404     $self->exe('git', 'submodule', 'init', @init_args);
405
406     my $template = getcwd()."/.commit-template";
407     if (-e $template) {
408         $self->exe('git', 'config', 'commit.template', $template);
409     }
410
411     return;
412 }
413
414 sub git_disable_webkit_submodule
415 {
416     my ($self) = @_;
417
418     $self->exe('git', 'config', '--remove', 'submodule.qtwebkit');
419     $self->exe('git', 'config', '--remove', 'submodule.qtwebkit-examples');
420
421     return;
422 }
423
424 sub git_prune_submodules
425 {
426     my ($self) = @_;
427
428     my @configresult = qx(git config -l);
429     foreach my $line (@configresult) {
430         if ($line =~ /submodule\.([^.=]+)\.url=/) {
431             my $module_name = $1;
432             if (!$self->{'module-subset'}{$module_name}) {
433                 $self->exe('git', 'config', '--remove', "submodule.$module_name");
434             }
435         }
436     }
437 }
438
439 sub git_set_submodule_config
440 {
441     my ($self) = @_;
442
443     my @configresult          = qx(git config -l);
444     my $protocol              = $self->{protocol};
445     my $url_base_for_protocol = $PROTOCOLS{$protocol};
446
447     foreach my $line (@configresult) {
448         # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
449         next if ($line !~ /submodule\.([^.=]+)\.url=(.*)/);
450
451         my $key   = $1;
452         my $value = $2;
453
454         if ($protocol) {
455                 # rewrite URL to chosen protocol
456                 $value =~ s,^git://gitorious\.org/,$url_base_for_protocol,;
457         }
458
459         $self->exe('git', 'config', "submodule.$key.url", $value);
460
461         if ($self->{'ignore-submodules'}) {
462             $self->exe('git', 'config', "submodule.$key.ignore", 'all');
463         }
464     }
465
466     return;
467 }
468
469 sub git_clone_all_submodules
470 {
471     my ($self) = @_;
472
473     # manually clone each repo here, so we can easily use reference repos, mirrors etc
474     my @configresult = qx(git config -l);
475     foreach my $line (@configresult) {
476         if ($line =~ /submodule\.([^.=]+)\.url=(.*)/) {
477             $self->git_clone_one_submodule($1, $2);
478             if ($1 eq "qtwebengine") {
479                 $self->exe('git', 'submodule', 'update', $1);
480                 my $orig_cwd = getcwd();
481                 chdir($1) or confess "chdir $1: $OS_ERROR";
482                 $self->exe('git', 'submodule', 'init');
483                 $self->git_clone_all_submodules;
484                 chdir("$orig_cwd") or confess "chdir $orig_cwd: $OS_ERROR";
485             }
486         }
487     }
488
489     if ($self->{update}) {
490         $self->exe('git', 'submodule', 'update', '--recursive');
491     }
492
493     return;
494 }
495
496 sub git_add_remotes
497 {
498     my ($self, $repo_basename) = @_;
499
500     my $gerrit_repo_basename = $GERRIT_REPOS{$repo_basename};
501     if ($gerrit_repo_basename) {
502         my $gerrit_repo_url;
503
504         # If given a username, make a "verbose" remote.
505         # Otherwise, rely on proper SSH configuration.
506         if ($self->{'codereview-username'}) {
507             $gerrit_repo_url = $GERRIT_SSH_BASE;
508             $gerrit_repo_url =~ s,\@USER\@,$self->{'codereview-username'}\@,;
509             $gerrit_repo_url =~ s,\@PORT\@,:29418,;
510         }
511         else {
512             $gerrit_repo_url = $GERRIT_SSH_BASE;
513             $gerrit_repo_url =~ s,\@[^\@]+\@,,g;
514         }
515
516         $gerrit_repo_url .= $gerrit_repo_basename;
517         $self->exe('git', 'config', 'remote.gerrit.url', $gerrit_repo_url);
518         $self->exe('git', 'config', 'remote.gerrit.fetch', '+refs/heads/*:refs/remotes/gerrit/*', '/heads/');
519     }
520
521     return;
522 }
523
524 sub git_clone_one_submodule
525 {
526     my ($self, $submodule, $url) = @_;
527
528     my $alternates            = $self->{ 'alternates'        };
529     my $mirror_url            = $self->{ 'mirror-url'        };
530     my $protocol              = $self->{ 'protocol'          };
531
532     # `--reference FOO' args for the clone, if any.
533     my @reference_args;
534
535     if ($alternates) {
536         # alternates is a qt5 repo, so the submodule will be under that.
537         if (-d "$alternates/$submodule") {
538             @reference_args = ('--reference', "$alternates/$submodule");
539         }
540         else {
541             print " *** $alternates/$submodule not found, ignoring alternate for this submodule\n";
542         }
543     }
544
545     my $mirror;
546     if ($mirror_url and $url =~ /\/(qt\/[^.]+)\.git/) {
547         $mirror = $mirror_url.$1;
548         $mirror .= ".git" unless (-d $mirror); # Support local disk mirror
549     }
550
551     if ($mirror) {
552         # Only use the mirror if it can be reached.
553         eval { $self->exe('git', 'ls-remote', $mirror, 'test/if/mirror/exists') };
554         if ($@) {
555             warn "mirror [$mirror] is not accessible; $url will be used\n";
556             undef $mirror;
557         }
558     }
559
560     my $do_clone = (! -d "$submodule/.git");
561     if ($do_clone) {
562         $self->exe('git', 'clone', @reference_args, ($mirror ? $mirror : $url), $submodule);
563     }
564
565     my $orig_cwd = getcwd();
566     chdir($submodule) or confess "chdir $submodule: $OS_ERROR";
567
568     $self->exe('git', 'config', 'remote.origin.url', $url);
569     if ($mirror) {
570         $self->exe('git', 'config', 'remote.mirror.url', $mirror);
571         $self->exe('git', 'config', 'remote.mirror.fetch', '+refs/heads/*:refs/remotes/mirror/*');
572     }
573
574     if (!$do_clone) {
575         $self->exe('git', 'fetch', ($mirror ? $mirror : $url));
576     }
577
578     my $template = getcwd()."/../.commit-template";
579     if (-e $template) {
580         $self->exe('git', 'config', 'commit.template', $template);
581     }
582
583     $self->git_add_remotes($submodule);
584
585     if ($self->{'detach-alternates'}) {
586         $self->exe('git', 'repack', '-a');
587
588         my $alternates_path = '.git/objects/info/alternates';
589         if (-e $alternates_path) {
590             unlink($alternates_path) || confess "unlink $alternates_path: $OS_ERROR";
591         }
592     }
593
594     chdir($orig_cwd) or confess "cd $orig_cwd: $OS_ERROR";
595
596     return;
597 }
598
599 sub ensure_link
600 {
601     my ($self, $src, $tgt) = @_;
602     return if (!$self->{'force-hooks'} and -f $tgt);
603     unlink($tgt); # In case we have a dead symlink or pre-existing hook
604     print "Aliasing $src\n      as $tgt ...\n" if (!$self->{quiet});
605     return if eval { symlink($src, $tgt) };
606     # Windows doesn't do (proper) symlinks. As the post_commit script needs
607     # them to locate itself, we write a forwarding script instead.
608     open SCRIPT, ">".$tgt or die "Cannot create forwarding script $tgt: $!\n";
609     print SCRIPT "#!/bin/sh\nexec `dirname \$0`/$src \"\$\@\"\n";
610     close SCRIPT;
611 }
612
613 sub git_install_hooks
614 {
615     my ($self) = @_;
616
617     return if (!-d 'qtrepotools/git-hooks');
618
619     chomp(my @modules = `git submodule foreach :`);
620     push @modules, "";
621     for my $module (@modules) {
622         $module =~ s,^Entering \'([^\']+)\'$,$1/,;
623         my $rel = $module;
624         $rel =~ s,[^/]+,..,g;
625         $rel .= "../../qtrepotools/git-hooks/";
626         $self->ensure_link($rel.'gerrit_commit_msg_hook', $module.'.git/hooks/commit-msg');
627         $self->ensure_link($rel.'git_post_commit_hook', $module.'.git/hooks/post-commit');
628     }
629 }
630
631 sub run
632 {
633     my ($self) = @_;
634
635     $self->check_if_already_initialized;
636     $self->git_submodule_init;
637
638     if (!$self->{webkit}) {
639         $self->git_disable_webkit_submodule;
640     }
641
642     if ($self->{'module-subset'}) {
643         $self->git_prune_submodules;
644     }
645
646     $self->git_set_submodule_config;
647
648     $self->git_clone_all_submodules;
649
650     $self->git_add_remotes('qt5');
651
652     $self->git_install_hooks;
653
654     return;
655 }
656
657 #==============================================================================
658
659 Qt::InitRepository->new(@ARGV)->run if (!caller);
660 1;