init-repository

   1 #!/usr/bin/env perl
   2 #############################################################################
   3 ##
   4 ## Copyright (C) 2011 Nokia Corporation and/or its subsidiary(-ies).
   5 ## All rights reserved.
   6 ## Contact: Nokia Corporation (qt-info@nokia.com)
   7 ##
   8 ## This file is part of the utilities of the Qt Toolkit.
   9 ##
  10 ## $QT_BEGIN_LICENSE:LGPL$
  11 ## GNU Lesser General Public License Usage
  12 ## This file may be used under the terms of the GNU Lesser General Public
  13 ## License version 2.1 as published by the Free Software Foundation and
  14 ## appearing in the file LICENSE.LGPL included in the packaging of this
  15 ## file. Please review the following information to ensure the GNU Lesser
  16 ## General Public License version 2.1 requirements will be met:
  17 ## http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
  18 ##
  19 ## In addition, as a special exception, Nokia gives you certain additional
  20 ## rights. These rights are described in the Nokia Qt LGPL Exception
  21 ## version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
  22 ##
  23 ## GNU General Public License Usage
  24 ## Alternatively, this file may be used under the terms of the GNU General
  25 ## Public License version 3.0 as published by the Free Software Foundation
  26 ## and appearing in the file LICENSE.GPL included in the packaging of this
  27 ## file. Please review the following information to ensure the GNU General
  28 ## Public License version 3.0 requirements will be met:
  29 ## http://www.gnu.org/copyleft/gpl.html.
  30 ##
  31 ## Other Usage
  32 ## Alternatively, this file may be used in accordance with the terms and
  33 ## conditions contained in a signed written agreement between you and Nokia.
  34 ##
  35 ##
  36 ##
  37 ##
  38 ##
  39 ## $QT_END_LICENSE$
  40 ##
  41 #############################################################################
  42
  43 use v5.10;
  44 use strict;
  45 use warnings;
  46
  47 package Qt::InitRepository;
  48
  49
  50 =head1 NAME
  51
  52 init-repository - initialize the Qt5 repository and all submodules
  53
  54 =head1 SYNOPSIS
  55
  56   ./init-repository [options]
  57
  58 This script may be run after an initial `git clone' of Qt5 in order to check
  59 out all submodules.
  60
  61
  62 =head1 OPTIONS
  63
  64 B<Global options:>
  65
  66 =over
  67
  68 =item --force, -f
  69
  70 Force initialization (even if the submodules are already checked out).
  71
  72
  73 =item --quiet, -q
  74
  75 Be quiet.  Will exit cleanly if the repository is already initialized.
  76
  77 =back
  78
  79
  80 B<Module options:>
  81
  82 =over
  83
  84 =item --no-webkit
  85
  86 Skip webkit and webkit examples submodules.
  87 It may be desirable to skip these modules due to the large size of the webkit
  88 git repository.
  89
  90 =item --module-subset=<module1>,<module2>...
  91
  92 Only initialize the specified subset of modules given as the argument. Specified
  93 modules must already exist in .gitmodules.
  94
  95 =item --no-update
  96
  97 Skip the `git submodule update' command.
  98
  99
 100 =item --ignore-submodules
 101
 102 Set git config to ignore submodules by default when doing operations on the
 103 qt5 repo, such as `pull', `fetch', `diff' etc.
 104
 105 This option is default for --nokia-developer/--brisbane.
 106
 107 After using this option, pass `--ignore-submodules=none' to git to override
 108 it as needed.
 109
 110 =back
 111
 112
 113 B<Repository options:>
 114
 115 =over
 116
 117 =item --nokia-developer
 118
 119 Switch to internal Nokia URLs.
 120
 121
 122 =item --brisbane
 123
 124 Switch to internal Nokia URLs and make use of the Brisbane git mirrors.
 125 (Implies `--mirror' and `--mirror-webkit').
 126
 127 =item --berlin
 128
 129 Switch to internal Nokia URLs and make use of the Berlin git mirrors.
 130 (Implies `--mirror' and `--mirror-webkit').
 131
 132
 133 =item --ssh
 134
 135 Use the SSH protocol for git operations.  This may be useful if the git
 136 protocol is blocked by a firewall. Note that this requires a user account
 137 with an uploaded SSH key on all servers used.  (Implies `--nokia-developer').
 138
 139 The `--ssh' option does not affect the gerrit remotes.
 140
 141
 142 =item --http
 143
 144 Use the HTTP protocol for git operations.  This may be useful if the git
 145 protocol is blocked by a firewall.  Note that this only works with the
 146 external Gitorious server.
 147
 148 The `--http' option does not affect the gerrit remotes.
 149
 150
 151 =item --codereview-username <Gerrit/JIRA username>
 152
 153 Adds a (potentially) writable remote named `gerrit' for each module,
 154 for use with the Gerrit code review tool.
 155 This requires a username for SSH access to the codereview.qt-project.org
 156 server, which will be the same username you have for the bugtracker at
 157 bugreports.qt.nokia.com.
 158
 159 If this option is omitted, the gerrit remote is created with read-only
 160 access (using HTTP protocol).
 161
 162
 163 =item --alternates <path to other Qt5 repo>
 164
 165 Adds alternates for each submodule to another full qt5 checkout. This makes
 166 this qt5 checkout very small, as it will use the object store of the
 167 alternates before unique objects are stored in its own object store.
 168
 169 This option has no effect when using `--no-update'.
 170
 171 B<NOTE:> This will make this repo dependent on the alternate, which is
 172 potentially dangerous!  The dependency can be broken by also using
 173 the `--copy-objects' option, or by running C<git repack -a> in each
 174 submodule, where required.  Please read the note about the `--shared' option
 175 in the documentation of `git clone' for more information.
 176
 177
 178 =item --copy-objects
 179
 180 When `--alternates' is used, automatically do a C<git repack -a> in each
 181 submodule after cloning, to ensure that the repositories are independent
 182 from the source used as a reference for cloning.
 183
 184 Note that this negates the disk usage benefits gained from the use of
 185 `--alternates'.
 186
 187
 188 =item --mirror <url-base>
 189
 190 Uses <url-base> as the base URL for submodule git mirrors.
 191
 192 For example:
 193
 194   --mirror user@machine:/foo/bar
 195
 196 ...will use the following as a mirror for qtbase:
 197
 198   user@machine:/foo/bar/qtbase.git
 199
 200
 201 =item --mirror-webkit <url>
 202
 203 Uses <url> as the URL for the webkit git mirror.
 204
 205 =back
 206
 207 =cut
 208
 209 use Carp         qw( confess             );
 210 use English      qw( -no_match_vars      );
 211 use Getopt::Long qw( GetOptionsFromArray );
 212 use Pod::Usage   qw( pod2usage           );
 213 use Cwd          qw( getcwd              );
 214
 215 my %PROTOCOLS = (
 216     'internal'  => 'git://scm.dev.nokia.troll.no/' ,
 217     'ssh'       => 'git@scm.dev.nokia.troll.no:'   ,
 218     'http'      => 'http://git.gitorious.org/'     ,
 219 );
 220
 221 my %GERRIT_REPOS = map { $_ => "qt/$_" } qw(
 222     qt5
 223     qlalr
 224     qtactiveqt
 225     qtbase
 226     qtconnectivity
 227     qtdeclarative
 228     qtdoc
 229     qtdocgallery
 230     qtfeedback
 231     qtlocation
 232     qtmultimedia
 233     qtmultimediakit
 234     qtphonon
 235     qtpim
 236     qtqa
 237     qtrepotools
 238     qtscript
 239     qtsensors
 240     qtsvg
 241     qtsystems
 242     qttools
 243     qttranslations
 244     qtwayland
 245     qtwebkit-examples-and-demos
 246     qtxmlpatterns
 247 );
 248 $GERRIT_REPOS{qtquick3d} = "qt/quick3d";
 249
 250 # Protocol-specific repo overrides, if they differ from the values set in the git submodule config
 251 # (e.g. because public vs private names differ for whatever reason)
 252 my %PROTOCOL_REPOS = (
 253     qtquick3d   =>  {
 254         internal    =>  "qt/quick3d",   # instead of qt-quick3d/qt-quick3d on gitorious
 255         ssh         =>  "qt/quick3d",
 256     },
 257 );
 258
 259 my $GERRIT_SSH_BASE
 260     = 'ssh://codereview.qt-project.org:29418/';
 261
 262 my $GERRIT_HTTP_BASE
 263     = 'http://codereview.qt-project.org/p/';
 264
 265 my $BNE_MIRROR_URL_BASE
 266     = 'git://bq-git.apac.nokia.com/qtsoftware/';
 267
 268 my $BNE_MIRROR_WEBKIT_URL
 269     = 'git://bq-git.apac.nokia.com/qtsoftware/research/gitorious-org-webkit-qtwebkit-mirror.git';
 270
 271 my $BNE_MIRROR_V8_URL
 272     = 'git://bq-git.apac.nokia.com/github/v8.git';
 273
 274 my $BER_MIRROR_URL_BASE
 275     = 'git://ber-git.europe.nokia.com/';
 276
 277 my $BER_MIRROR_WEBKIT_URL
 278     = 'git://ber-git.europe.nokia.com/qtwebkit/qtwebkit.git';
 279
 280
 281 sub new
 282 {
 283     my ($class, @arguments) = @_;
 284
 285     my $self = {};
 286     bless $self, $class;
 287     $self->parse_arguments(@arguments);
 288
 289     return $self;
 290 }
 291
 292 # Like `system', but possibly log the command, and die on non-zero exit code
 293 sub exe
 294 {
 295     my ($self, @cmd) = @_;
 296
 297     if (!$self->{quiet}) {
 298         print "+ @cmd\n";
 299     }
 300
 301     if (system(@cmd) != 0) {
 302         confess "@cmd exited with status $CHILD_ERROR";
 303     }
 304
 305     return;
 306 }
 307
 308 sub parse_arguments
 309 {
 310     my ($self, @args) = @_;
 311
 312     %{$self} = (%{$self},
 313         'alternates'          => "",
 314         'codereview-username' => "",
 315         'detach-alternates'   => 0 ,
 316         'force'               => 0 ,
 317         'ignore-submodules'   => 0 ,
 318         'mirror-url'          => "",
 319         'mirror-webkit-url'   => "",
 320         'mirror-v8-url'       => "",
 321         'nokia-developer'     => 0 ,
 322         'protocol'            => "",
 323         'update'              => 1 ,
 324         'webkit'              => 1 ,
 325         'module-subset'       => "",
 326     );
 327
 328     GetOptionsFromArray(\@args,
 329         'alternates=s'      =>  \$self->{qw{ alternates        }},
 330         'codereview-username=s' => \$self->{qw{ codereview-username }},
 331         'copy-objects'      =>  \$self->{qw{ detach-alternates }},
 332         'force'             =>  \$self->{qw{ force             }},
 333         'ignore-submodules' =>  \$self->{qw{ ignore-submodules }},
 334         'mirror-webkit=s'   =>  \$self->{qw{ mirror-webkit-url }},
 335         'mirror=s'          =>  \$self->{qw{ mirror-url        }},
 336         'nokia-developer'   =>  \$self->{qw{ nokia-developer   }},
 337         'quiet'             =>  \$self->{qw{ quiet             }},
 338         'update!'           =>  \$self->{qw{ update            }},
 339         'webkit!'           =>  \$self->{qw{ webkit            }},
 340         'module-subset=s'   =>  \$self->{qw{ module-subset     }},
 341
 342         'help|?'            =>  sub { pod2usage(1);               },
 343         'http'              =>  sub { $self->{protocol} = 'http'; },
 344         'ssh|ssh-protocol'  =>  sub { $self->{protocol} = 'ssh';  },
 345
 346         'brisbane|brisbane-nokia-developer' => sub {
 347             $self->{'nokia-developer'}   = 1;
 348             $self->{'protocol'}          = 'internal';
 349             $self->{'mirror-url'}        = $BNE_MIRROR_URL_BASE;
 350             $self->{'mirror-v8-url'}     = $BNE_MIRROR_V8_URL;
 351             $self->{'mirror-webkit-url'} = $BNE_MIRROR_WEBKIT_URL;
 352             $self->{'ignore-submodules'} = 1;
 353         },
 354
 355         'berlin|berlin-nokia-developer' => sub {
 356             $self->{'nokia-developer'}   = 1;
 357             $self->{'protocol'}          = 'internal';
 358             $self->{'mirror-url'}        = $BER_MIRROR_URL_BASE;
 359             $self->{'mirror-webkit-url'} = $BER_MIRROR_WEBKIT_URL;
 360         },
 361
 362         'nokia-developer' => sub {
 363             $self->{'nokia-developer'}   = 1;
 364             $self->{'protocol'}          = 'internal';
 365             $self->{'ignore-submodules'} = 1;
 366         },
 367     ) || pod2usage(2);
 368
 369     if ($self->{'nokia-developer'} && $self->{'protocol'} eq 'http') {
 370         print "*** Ignoring use of HTTP protocol, as it's only usable with external server\n";
 371         $self->{'protocol'} = '';
 372     }
 373
 374     # Replace any double trailing slashes from end of mirror
 375     $self->{'mirror-url'} =~ s{//+$}{/};
 376
 377     if ($self->{'module-subset'}) {
 378         $self->{'module-subset'} = {
 379             map { $_ => 1 } split(qr{,}, $self->{'module-subset'})
 380         };
 381     }
 382
 383     return;
 384 }
 385
 386 sub check_if_already_initialized
 387 {
 388     my ($self) = @_;
 389
 390     # We consider the repo as `initialized' if submodule.qtbase.url is set
 391     if (qx(git config --get submodule.qtbase.url)) {
 392         if ($self->{force}) {
 393             my @configresult = qx(git config -l);
 394             foreach (@configresult) {
 395                 # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
 396                 if (/(submodule\.[^.=]+)\.url=.*/) {
 397                     $self->exe('git', 'config', '--remove-section', $1);
 398                 }
 399             }
 400         }
 401         else {
 402             exit 0 if ($self->{quiet});
 403             print "Will not reinitialize already initialized repository (use -f to force)!\n";
 404             exit 1;
 405         }
 406     }
 407
 408     return;
 409 }
 410
 411 sub git_submodule_init
 412 {
 413     my ($self) = @_;
 414
 415     my @init_args;
 416     if ($self->{quiet}) {
 417         push @init_args, '--quiet';
 418     }
 419     $self->exe('git', 'submodule', 'init', @init_args);
 420
 421     my $template = getcwd()."/.commit-template";
 422     if (-e $template) {
 423         $self->exe('git', 'config', 'commit.template', $template);
 424     }
 425
 426     return;
 427 }
 428
 429 sub git_disable_webkit_submodule
 430 {
 431     my ($self) = @_;
 432
 433     $self->exe('git', 'config', '--remove', 'submodule.qtwebkit');
 434     $self->exe('git', 'config', '--remove', 'submodule.qtwebkit-examples-and-demos');
 435
 436     return;
 437 }
 438
 439 sub git_prune_submodules
 440 {
 441     my ($self) = @_;
 442
 443     my @configresult = qx(git config -l);
 444     foreach my $line (@configresult) {
 445         if ($line =~ /submodule\.([^.=]+)\.url=/) {
 446             my $module_name = $1;
 447             if (!$self->{'module-subset'}{$module_name}) {
 448                 $self->exe('git', 'config', '--remove', "submodule.$module_name");
 449             }
 450         }
 451     }
 452 }
 453
 454 sub git_set_submodule_config
 455 {
 456     my ($self) = @_;
 457
 458     my @configresult          = qx(git config -l);
 459     my $protocol              = $self->{protocol};
 460     my $url_base_for_protocol = $PROTOCOLS{$protocol};
 461
 462     foreach my $line (@configresult) {
 463         # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
 464         next if ($line !~ /submodule\.([^.=]+)\.url=(.*)/);
 465
 466         my $key   = $1;
 467         my $value = $2;
 468
 469         if ($protocol) {
 470             # WebKit is special, and has only external link.
 471             if ($key ne 'qtwebkit') {
 472                 # qt-labs projects are still hosted under qt internally.
 473                 if ($protocol ne 'http') {
 474                     $value =~ s,^git://gitorious\.org/qt-labs/,${url_base_for_protocol}qt/,;
 475                 }
 476
 477                 if ($PROTOCOL_REPOS{$key}->{$protocol}) {
 478                     # If this repo has an explicitly set basename for this protocol, use it...
 479                     # e.g.   'git@example.com:'     . 'qt/quick3d'
 480                     $value = $url_base_for_protocol . $PROTOCOL_REPOS{$key}->{$protocol};
 481                 }
 482                 else {
 483                     # ...otherwise, assume the selected protocol uses same naming structure
 484                     # as gitorious.org
 485                     # e.g. git://gitorious.org/qt/qt5 => git@example.com:qt/qt5
 486                     $value =~ s,^git://gitorious\.org/,$url_base_for_protocol,;
 487                 }
 488             }
 489         }
 490
 491         $self->exe('git', 'config', "submodule.$key.url", $value);
 492
 493         if ($self->{'ignore-submodules'}) {
 494             $self->exe('git', 'config', "submodule.$key.ignore", 'all');
 495         }
 496     }
 497
 498     return;
 499 }
 500
 501 sub git_clone_all_submodules
 502 {
 503     my ($self) = @_;
 504
 505     # manually clone each repo here, so we can easily use reference repos, mirrors etc
 506     my @configresult = qx(git config -l);
 507     foreach my $line (@configresult) {
 508         if ($line =~ /submodule\.([^.=]+)\.url=(.*)/) {
 509             $self->git_clone_one_submodule($1, $2);
 510         }
 511     }
 512
 513     $self->exe('git', 'submodule', 'update');
 514
 515     return;
 516 }
 517
 518 sub git_add_remotes
 519 {
 520     my ($self, $repo_basename) = @_;
 521
 522     my $protocol              = $self->{protocol};
 523     my $url_base_for_protocol = $PROTOCOLS{$protocol};
 524
 525     my %current_remotes;
 526     for my $line (qx(git remote show)) {
 527         chomp $line;
 528         $current_remotes{$line} = 1;
 529     }
 530
 531     my $gerrit_repo_basename = $GERRIT_REPOS{$repo_basename};
 532     if ($gerrit_repo_basename && !$current_remotes{'gerrit'}) {
 533         my $gerrit_repo_url;
 534
 535         # If given a username, we use writable remote (ssh).
 536         # Otherwise, we use read-only (http).
 537         if ($self->{'codereview-username'}) {
 538             $gerrit_repo_url = $GERRIT_SSH_BASE;
 539             $gerrit_repo_url =~ s[^ssh://][ssh://$self->{'codereview-username'}@];
 540         }
 541         else {
 542             $gerrit_repo_url = $GERRIT_HTTP_BASE;
 543         }
 544
 545         $gerrit_repo_url .= $gerrit_repo_basename;
 546         $self->exe('git', 'remote', 'add', 'gerrit', $gerrit_repo_url);
 547
 548         $current_remotes{'gerrit'} = 1;
 549     }
 550
 551     # if repo still has no gerrit repo defined, alias it to origin
 552     if (!$current_remotes{'gerrit'}) {
 553         my @configresult = qx(git remote -v);
 554         foreach (@configresult) {
 555             if (/^origin\s+(\S+) \(fetch\)/) {
 556                 $self->exe('git', 'remote', 'add', 'gerrit', $1);
 557             }
 558         }
 559     }
 560
 561     return;
 562 }
 563
 564 sub git_clone_one_submodule
 565 {
 566     my ($self, $submodule, $url) = @_;
 567
 568     my $alternates            = $self->{ 'alternates'        };
 569     my $mirror_url            = $self->{ 'mirror-url'        };
 570     my $mirror_webkit_url     = $self->{ 'mirror-webkit-url' };
 571     my $mirror_v8_url         = $self->{ 'mirror-v8-url'     };
 572     my $protocol              = $self->{ 'protocol'          };
 573     my $nokia_developer       = $self->{ 'nokia-developer'   };
 574
 575     # `--reference FOO' args for the clone, if any.
 576     my @reference_args;
 577
 578     if ($alternates) {
 579         # alternates is a qt5 repo, so the submodule will be under that.
 580         if (-d "$alternates/$submodule") {
 581             @reference_args = ('--reference', "$alternates/$submodule");
 582         }
 583         else {
 584             print " *** $alternates/$submodule not found, ignoring alternate for this submodule\n";
 585         }
 586     }
 587
 588     my $mirror;
 589     if ($mirror_url && ($submodule ne 'qtwebkit')) {
 590         $mirror = $mirror_url.( $PROTOCOL_REPOS{$submodule}->{internal} // "qt/$submodule" );
 591         $mirror .= ".git" unless (-d $mirror); # Support local disk mirror
 592     }
 593     elsif ($mirror_webkit_url && ($submodule eq 'qtwebkit')) {
 594         $mirror = $mirror_webkit_url;
 595     }
 596
 597     my $do_clone = (! -d "$submodule/.git");
 598     if ($do_clone) {
 599         $self->exe('git', 'clone', @reference_args, ($mirror ? $mirror : $url), $submodule);
 600     }
 601
 602     chdir($submodule) or confess "chdir $submodule: $OS_ERROR";
 603
 604     if (!$do_clone) {
 605         $self->exe('git', 'fetch', ($mirror ? $mirror : $url));
 606     }
 607
 608     my $template = getcwd()."/../.commit-template";
 609     if (-e $template) {
 610         $self->exe('git', 'config', 'commit.template', $template);
 611     }
 612
 613     if ($mirror) {
 614         $self->exe('git', 'config', 'remote.origin.url', $url);
 615
 616         # In `force' mode, remove the mirror if it already exists,
 617         # since we may be reinitializing the module.
 618         if ($self->{force}) {
 619             eval { $self->exe('git', 'remote', 'rm', 'mirror'); }; # failure is OK
 620         }
 621
 622         $self->exe('git', 'remote', 'add', 'mirror', $mirror);
 623     }
 624
 625     $self->git_add_remotes($submodule) if $nokia_developer;
 626
 627     if ($self->{'detach-alternates'}) {
 628         $self->exe('git', 'repack', '-a');
 629
 630         my $alternates_path = '.git/objects/info/alternates';
 631         unlink($alternates_path) || confess "unlink $alternates_path: $OS_ERROR";
 632     }
 633
 634     if ($submodule eq "qtbase" || $submodule eq "qtdeclarative") { #Extra steps needed to setup base and declarative
 635         $self->exe('git', 'submodule', 'init');
 636         if ($mirror_v8_url || $protocol eq 'http') {
 637             my @configresult = qx(git config -l);
 638             my $v8url;
 639             foreach my $line (@configresult) {
 640                 # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
 641                 next if ($line !~ /submodule.src\/3rdparty\/v8.url=(.*)/);
 642                 $v8url = $1;
 643             }
 644
 645             if ($v8url) {
 646                 if ($protocol eq 'http') {
 647                     # rewrite the git:// url to https://
 648                     if ($v8url =~ s{^git://github}{https://github}) {
 649                         $self->exe('git', 'config', 'submodule.src/3rdparty/v8.url', $v8url);
 650                     }
 651                     else {
 652                         warn 'You requested git over http, but I could not figure out how to '
 653                             ."rewrite v8's giturl of $v8url";
 654                     }
 655                 }
 656
 657                 if ($mirror_v8_url && $do_clone) {
 658                     chdir('src/3rdparty/') or confess "chdir $submodule/src/3rdparty: $OS_ERROR";
 659                     $self->exe('git', 'clone', $mirror_v8_url, 'v8');
 660                     chdir('v8') or confess "chdir $submodule/src/3rdparty/v8: $OS_ERROR";
 661                     $self->exe('git', 'config', 'remote.origin.url', $v8url);
 662                     chdir('../../..') or confess "cd ../../..: $OS_ERROR";
 663                 }
 664             }
 665         }
 666         $self->exe('git', 'submodule', 'update');
 667     }
 668
 669     chdir("..") or confess "cd ..: $OS_ERROR";
 670
 671     return;
 672 }
 673
 674 sub run
 675 {
 676     my ($self) = @_;
 677
 678     my $nokia_developer       = $self->{ 'nokia-developer'   };
 679
 680     $self->check_if_already_initialized;
 681     $self->git_submodule_init;
 682
 683     if (!$self->{webkit}) {
 684         $self->git_disable_webkit_submodule;
 685     }
 686
 687     if ($self->{'module-subset'}) {
 688         $self->git_prune_submodules;
 689     }
 690
 691     $self->git_set_submodule_config;
 692
 693     if ($self->{update}) {
 694         $self->git_clone_all_submodules;
 695     }
 696
 697     $self->git_add_remotes('qt5') if $nokia_developer;
 698
 699     return;
 700 }
 701
 702 #==============================================================================
 703
 704 Qt::InitRepository->new(@ARGV)->run if (!caller);
 705 1;