4078a24151bed889ec1891ef007d78bfc678023f
[mirror/qt/qt5.git] / init-repository
1 #!/usr/bin/env perl
2 #############################################################################
3 ##
4 ## Copyright (C) 2011 Nokia Corporation and/or its subsidiary(-ies).
5 ## All rights reserved.
6 ## Contact: Nokia Corporation (qt-info@nokia.com)
7 ##
8 ## This file is part of the utilities of the Qt Toolkit.
9 ##
10 ## $QT_BEGIN_LICENSE:LGPL$
11 ## No Commercial Usage
12 ## This file contains pre-release code and may not be distributed.
13 ## You may use this file in accordance with the terms and conditions
14 ## contained in the Technology Preview License Agreement accompanying
15 ## this package.
16 ##
17 ## GNU Lesser General Public License Usage
18 ## Alternatively, this file may be used under the terms of the GNU Lesser
19 ## General Public License version 2.1 as published by the Free Software
20 ## Foundation and appearing in the file LICENSE.LGPL included in the
21 ## packaging of this file.  Please review the following information to
22 ## ensure the GNU Lesser General Public License version 2.1 requirements
23 ## will be met: http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
24 ##
25 ## In addition, as a special exception, Nokia gives you certain additional
26 ## rights.  These rights are described in the Nokia Qt LGPL Exception
27 ## version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
28 ##
29 ## If you have questions regarding the use of this file, please contact
30 ## Nokia at qt-info@nokia.com.
31 ##
32 ##
33 ##
34 ##
35 ##
36 ##
37 ##
38 ##
39 ## $QT_END_LICENSE$
40 ##
41 #############################################################################
42
43 use v5.10;
44 use strict;
45 use warnings;
46
47 package Qt::InitRepository;
48
49
50 =head1 NAME
51
52 init-repository - initialize the Qt5 repository and all submodules
53
54 =head1 SYNOPSIS
55
56   ./init-repository [options]
57
58 This script may be run after an initial `git clone' of Qt5 in order to check
59 out all submodules.
60
61
62 =head1 OPTIONS
63
64 B<Global options:>
65
66 =over
67
68 =item --force, -f
69
70 Force initialization (even if the submodules are already checked out).
71
72
73 =item --quiet, -q
74
75 Be quiet.  Will exit cleanly if the repository is already initialized.
76
77 =back
78
79
80 B<Module options:>
81
82 =over
83
84 =item --no-webkit
85
86 Skip webkit and webkit examples submodules.
87 It may be desirable to skip these modules due to the large size of the webkit
88 git repository.
89
90
91 =item --no-update
92
93 Skip the `git submodule update' command.
94
95
96 =item --ignore-submodules
97
98 Set git config to ignore submodules by default when doing operations on the
99 qt5 repo, such as `pull', `fetch', `diff' etc.
100
101 This option is default for --nokia-developer/--brisbane.
102
103 After using this option, pass `--ignore-submodules=none' to git to override
104 it as needed.
105
106 =back
107
108
109 B<Repository options:>
110
111 =over
112
113 =item --nokia-developer
114
115 Switch to internal Nokia URLs.
116
117
118 =item --brisbane
119
120 Switch to internal Nokia URLs and make use of the Brisbane git mirrors.
121 (Implies `--mirror' and `--mirror-webkit').
122
123 =item --berlin
124
125 Switch to internal Nokia URLs and make use of the Berlin git mirrors.
126 (Implies `--mirror' and `--mirror-webkit').
127
128
129 =item --ssh
130
131 Use the SSH protocol for git operations.  This may be useful if the git
132 protocol is blocked by a firewall. Note that this requires a user account
133 with an uploaded SSH key on all servers used.  (Implies `--nokia-developer').
134
135
136 =item --http
137
138 Use the HTTP protocol for git operations.  This may be useful if the git
139 protocol is blocked by a firewall.  Note that this only works with the
140 external Gitorious server.
141
142
143 =item --codereview-username <Gerrit/JIRA username>
144
145 Adds a gerrit alias to repos under Gerrit codereview management.
146 This requires a username for SSH access to the codereview.qt.nokia.com
147 server, which will be the same username you have for the bugtracker at
148 bugreports.qt.nokia.com.
149
150
151 =item --alternates <path to other Qt5 repo>
152
153 Adds alternates for each submodule to another full qt5 checkout. This makes
154 this qt5 checkout very small, as it will use the object store of the
155 alternates before unique objects are stored in its own object store.
156
157 This option has no effect when using `--no-update'.
158
159 B<NOTE:> This will make this repo dependent on the alternate, which is
160 potentially dangerous!  The dependency can be broken by also using
161 the `--copy-objects' option, or by running C<git repack -a> in each
162 submodule, where required.  Please read the note about the `--shared' option
163 in the documentation of `git clone' for more information.
164
165
166 =item --copy-objects
167
168 When `--alternates' is used, automatically do a C<git repack -a> in each
169 submodule after cloning, to ensure that the repositories are independent
170 from the source used as a reference for cloning.
171
172 Note that this negates the disk usage benefits gained from the use of
173 `--alternates'.
174
175
176 =item --mirror <url-base>
177
178 Uses <url-base> as the base URL for submodule git mirrors.
179
180 For example:
181
182   --mirror user@machine:/foo/bar
183
184 ...will use the following as a mirror for qtbase:
185
186   user@machine:/foo/bar/qtbase.git
187
188
189 =item --mirror-webkit <url>
190
191 Uses <url> as the URL for the webkit git mirror.
192
193 =back
194
195 =cut
196
197 use Carp         qw( confess             );
198 use English      qw( -no_match_vars      );
199 use Getopt::Long qw( GetOptionsFromArray );
200 use Pod::Usage   qw( pod2usage           );
201 use Cwd          qw( getcwd              );
202
203 my %PROTOCOLS = (
204     'internal'  => 'git://scm.dev.nokia.troll.no/' ,
205     'ssh'       => 'git@scm.dev.nokia.troll.no:'   ,
206     'http'      => 'http://git.gitorious.org/'     ,
207 );
208
209 my %STAGING_REPOS = map { $_ => "git://gitorious.org/qt/$_-staging.git" } qw(
210     qt5
211     qt3support
212     qtactiveqt
213     qtbase
214     qtdeclarative
215     qtdoc
216     qtmultimedia
217     qtphonon
218     qtqa
219     qtscript
220     qtsvg
221     qttools
222     qttranslations
223     qtwebkit-examples-and-demos
224     qtxmlpatterns
225     qtlocation
226     qtsensors
227     qtsystems
228 );
229
230 my %GERRIT_REPOS = map { $_ => "codereview.qt.nokia.com:qt/$_.git" } qw(
231     qtbase
232 );
233
234 my $BNE_MIRROR_URL_BASE
235     = 'git://bq-git.apac.nokia.com/qtsoftware/qt/';
236
237 my $BNE_MIRROR_WEBKIT_URL
238     = 'git://bq-git.apac.nokia.com/qtsoftware/research/gitorious-org-webkit-qtwebkit-mirror.git';
239
240 my $BER_MIRROR_URL_BASE
241     = 'git://ber-git.europe.nokia.com/qt/';
242
243 my $BER_MIRROR_WEBKIT_URL
244     = 'git://ber-git.europe.nokia.com/qtwebkit/qtwebkit.git';
245
246
247 sub new
248 {
249     my ($class, @arguments) = @_;
250
251     my $self = {};
252     bless $self, $class;
253     $self->parse_arguments(@arguments);
254
255     return $self;
256 }
257
258 # Like `system', but possibly log the command, and die on non-zero exit code
259 sub exe
260 {
261     my ($self, @cmd) = @_;
262
263     if (!$self->{quiet}) {
264         print "+ @cmd\n";
265     }
266
267     if (system(@cmd) != 0) {
268         confess "@cmd exited with status $CHILD_ERROR";
269     }
270
271     return;
272 }
273
274 sub parse_arguments
275 {
276     my ($self, @args) = @_;
277
278     %{$self} = (%{$self},
279         'alternates'          => "",
280         'codereview-username' => "",
281         'detach-alternates'   => 0 ,
282         'force'               => 0 ,
283         'ignore-submodules'   => 0 ,
284         'mirror-url'          => "",
285         'mirror-webkit-url'   => "",
286         'nokia-developer'     => 0 ,
287         'protocol'            => "",
288         'update'              => 1 ,
289         'webkit'              => 1 ,
290     );
291
292     GetOptionsFromArray(\@args,
293         'alternates=s'      =>  \$self->{qw{ alternates        }},
294         'codereview-username=s' => \$self->{qw{ codereview-username }},
295         'copy-objects'      =>  \$self->{qw{ detach-alternates }},
296         'force'             =>  \$self->{qw{ force             }},
297         'ignore-submodules' =>  \$self->{qw{ ignore-submodules }},
298         'mirror-webkit=s'   =>  \$self->{qw{ mirror-webkit-url }},
299         'mirror=s'          =>  \$self->{qw{ mirror-url        }},
300         'nokia-developer'   =>  \$self->{qw{ nokia-developer   }},
301         'quiet'             =>  \$self->{qw{ quiet             }},
302         'update!'           =>  \$self->{qw{ update            }},
303         'webkit!'           =>  \$self->{qw{ webkit            }},
304
305         'help|?'            =>  sub { pod2usage(1);               },
306         'http'              =>  sub { $self->{protocol} = 'http'; },
307         'ssh|ssh-protocol'  =>  sub { $self->{protocol} = 'ssh';  },
308
309         'brisbane|brisbane-nokia-developer' => sub {
310             $self->{'nokia-developer'}   = 1;
311             $self->{'protocol'}          = 'internal';
312             $self->{'mirror-url'}        = $BNE_MIRROR_URL_BASE;
313             $self->{'mirror-webkit-url'} = $BNE_MIRROR_WEBKIT_URL;
314             $self->{'ignore-submodules'} = 1;
315         },
316
317         'berlin|berlin-nokia-developer' => sub {
318             $self->{'nokia-developer'}   = 1;
319             $self->{'protocol'}          = 'internal';
320             $self->{'mirror-url'}        = $BER_MIRROR_URL_BASE;
321             $self->{'mirror-webkit-url'} = $BER_MIRROR_WEBKIT_URL;
322         },
323
324         'nokia-developer' => sub {
325             $self->{'nokia-developer'}   = 1;
326             $self->{'protocol'}          = 'internal';
327             $self->{'ignore-submodules'} = 1;
328         },
329     ) || pod2usage(2);
330
331     if ($self->{'nokia-developer'} && $self->{'protocol'} eq 'http') {
332         print "*** Ignoring use of HTTP protocol, as it's only usable with external server\n";
333         $self->{'protocol'} = '';
334     }
335
336     # Replace any double trailing slashes from end of mirror
337     $self->{'mirror-url'} =~ s{//+$}{/};
338
339     return;
340 }
341
342 sub check_if_already_initialized
343 {
344     my ($self) = @_;
345
346     # We consider the repo as `initialized' if submodule.qtbase.url is set
347     if (qx(git config --get submodule.qtbase.url)) {
348         if ($self->{force}) {
349             my @configresult = qx(git config -l);
350             foreach (@configresult) {
351                 # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
352                 if (/(submodule\.[^.=]+)\.url=.*/) {
353                     $self->exe('git', 'config', '--remove-section', $1);
354                 }
355             }
356         }
357         else {
358             exit 0 if ($self->{quiet});
359             print "Will not reinitialize already initialized repository (use -f to force)!\n";
360             exit 1;
361         }
362     }
363
364     return;
365 }
366
367 sub git_submodule_init
368 {
369     my ($self) = @_;
370
371     my @init_args;
372     if ($self->{quiet}) {
373         push @init_args, '--quiet';
374     }
375     $self->exe('git', 'submodule', 'init', @init_args);
376
377     my $template = getcwd()."/.commit-template";
378     if (-e $template) {
379         $self->exe('git', 'config', 'commit.template', $template);
380     }
381
382     return;
383 }
384
385 sub git_disable_webkit_submodule
386 {
387     my ($self) = @_;
388
389     $self->exe('git', 'config', '--remove', 'submodule.qtwebkit');
390     $self->exe('git', 'config', '--remove', 'submodule.qtwebkit-examples-and-demos');
391
392     return;
393 }
394
395 sub git_set_submodule_config
396 {
397     my ($self) = @_;
398
399     my @configresult          = qx(git config -l);
400     my $protocol              = $self->{protocol};
401     my $url_base_for_protocol = $PROTOCOLS{$protocol};
402
403     foreach my $line (@configresult) {
404         # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
405         next if ($line !~ /(submodule\.[^.=]+\.url)=(.*)/);
406
407         my $key   = $1;
408         my $value = $2;
409
410         if ($protocol) {
411             # WebKit is special, and has only external link.
412             if ($key ne 'submodule.qtwebkit.url') {
413                 # qt-labs projects are still hosted under qt internally.
414                 if ($protocol ne 'http') {
415                     $value =~ s,^git://gitorious\.org/qt-labs/,${url_base_for_protocol}qt/,;
416                 }
417                 $value =~ s,^git://gitorious\.org/,$url_base_for_protocol,;
418             }
419         }
420
421         $self->exe('git', 'config', $key, $value);
422
423         if ($self->{'ignore-submodules'}) {
424             $key =~ s,\.url,.ignore,;
425             $self->exe('git', 'config', $key, 'all');
426         }
427     }
428
429     return;
430 }
431
432 sub git_clone_all_submodules
433 {
434     my ($self) = @_;
435
436     # manually clone each repo here, so we can easily use reference repos, mirrors and
437     # add all staging repos
438     my @configresult = qx(git config -l);
439     foreach my $line (@configresult) {
440         if ($line =~ /submodule\.([^.=]+)\.url=(.*)/) {
441             $self->git_clone_one_submodule($1, $2);
442         }
443     }
444
445     $self->exe('git', 'submodule', 'update');
446
447     return;
448 }
449
450 sub git_add_remotes
451 {
452     my ($self, $repo_basename) = @_;
453
454     my $protocol              = $self->{protocol};
455     my $url_base_for_protocol = $PROTOCOLS{$protocol};
456
457     my %current_remotes;
458     for my $line (qx(git remote show)) {
459         chomp $line;
460         $current_remotes{$line} = 1;
461     }
462
463     my @gerrit = grep { /^$repo_basename$/; } keys %GERRIT_REPOS;
464     if (!$current_remotes{'gerrit'} && $self->{'codereview-username'}) {
465         foreach my $gerrit_repo (@gerrit) {
466             my $gerrit_repo_url = $GERRIT_REPOS{$gerrit_repo};
467             $self->exe('git', 'remote', 'add', 'gerrit', $self->{'codereview-username'}."@".$gerrit_repo_url);
468         }
469     }
470
471     my @staging = grep { /^$repo_basename$/; } keys %STAGING_REPOS;
472     if (!$current_remotes{'staging'}) {
473         foreach my $staging_repo (@staging) {
474             my $staging_repo_url = $STAGING_REPOS{$staging_repo};
475             if ($protocol) {
476                 if ($protocol ne 'http') {
477                     $staging_repo_url =~ s,^git://gitorious\.org/qt-labs/,${url_base_for_protocol}qt/,;
478                 }
479                 $staging_repo_url =~ s,^git://gitorious\.org/,$url_base_for_protocol,;
480             }
481             $self->exe('git', 'remote', 'add', 'staging', $staging_repo_url);
482         }
483     }
484
485     # if repo has no staging repo defined, alias it to gerrit or origin
486     if (!$current_remotes{'staging'} && !@staging) {
487         my @configresult = qx(git remote -v);
488         my $staging_set = 0;
489         foreach (@configresult) {
490             if (/^gerrit\s+(\S+) \(fetch\)/) {
491                 $self->exe('git', 'remote', 'add', 'staging', $1);
492                 $staging_set = 1;
493             }
494         }
495         unless($staging_set) {
496             foreach (@configresult) {
497                 if (/^origin\s+(\S+) \(fetch\)/) {
498                     $self->exe('git', 'remote', 'add', 'staging', $1);
499                 }
500             }
501         }
502     }
503     #if repo has no gerrit repo defined, alias it to whatever staging now points to (could be origin)
504     if (!$current_remotes{'gerrit'} && !@gerrit) {
505         my @configresult = qx(git remote -v);
506         foreach (@configresult) {
507             if (/^staging\s+(\S+) \(fetch\)/) {
508                 $self->exe('git', 'remote', 'add', 'gerrit', $1);
509             }
510         }
511     }
512
513     return;
514 }
515
516 sub git_clone_one_submodule
517 {
518     my ($self, $submodule, $url) = @_;
519
520     my $alternates            = $self->{ 'alternates'        };
521     my $mirror_url            = $self->{ 'mirror-url'        };
522     my $mirror_webkit_url     = $self->{ 'mirror-webkit-url' };
523
524     # `--reference FOO' args for the clone, if any.
525     my @reference_args;
526
527     if ($alternates) {
528         # alternates is a qt5 repo, so the submodule will be under that.
529         if (-d "$alternates/$submodule") {
530             @reference_args = ('--reference', "$alternates/$submodule");
531         }
532         else {
533             print " *** $alternates/$submodule not found, ignoring alternate for this submodule\n";
534         }
535     }
536
537     my $mirror;
538     if ($mirror_url && ($submodule ne 'qtwebkit')) {
539         $mirror = $mirror_url.$submodule;
540         $mirror .= ".git" unless (-d $mirror); # Support local disk mirror
541     }
542     elsif ($mirror_webkit_url && ($submodule eq 'qtwebkit')) {
543         $mirror = $mirror_webkit_url;
544     }
545
546     my $do_clone = (! -d "$submodule/.git");
547     if ($do_clone) {
548         $self->exe('git', 'clone', @reference_args, ($mirror ? $mirror : $url), $submodule);
549     }
550
551     chdir($submodule) or confess "chdir $submodule: $OS_ERROR";
552
553     if (!$do_clone) {
554         $self->exe('git', 'fetch', ($mirror ? $mirror : $url));
555     }
556
557     my $template = getcwd()."/../.commit-template";
558     if (-e $template) {
559         $self->exe('git', 'config', 'commit.template', $template);
560     }
561
562     if ($mirror) {
563         $self->exe('git', 'config', 'remote.origin.url', $url);
564
565         # In `force' mode, remove the mirror if it already exists,
566         # since we may be reinitializing the module.
567         if ($self->{force}) {
568             eval { $self->exe('git', 'remote', 'rm', 'mirror'); }; # failure is OK
569         }
570
571         $self->exe('git', 'remote', 'add', 'mirror', $mirror);
572     }
573
574     $self->git_add_remotes($submodule);
575
576     if ($self->{'detach-alternates'}) {
577         $self->exe('git', 'repack', '-a');
578
579         my $alternates_path = '.git/objects/info/alternates';
580         unlink($alternates_path) || confess "unlink $alternates_path: $OS_ERROR";
581     }
582
583     if ($submodule eq "qtdeclarative") { #Extra step needed to setup declarative 
584         $self->exe('git', 'submodule', 'init'); 
585         $self->exe('git', 'submodule', 'update'); 
586     } 
587
588     chdir("..") or confess "cd ..: $OS_ERROR";
589
590     return;
591 }
592
593 sub run
594 {
595     my ($self) = @_;
596
597     $self->check_if_already_initialized;
598     $self->git_submodule_init;
599
600     if (!$self->{webkit}) {
601         $self->git_disable_webkit_submodule;
602     }
603
604     $self->git_set_submodule_config;
605
606     if ($self->{update}) {
607         $self->git_clone_all_submodules;
608     }
609
610     $self->git_add_remotes('qt5');
611
612     return;
613 }
614
615 #==============================================================================
616
617 Qt::InitRepository->new(@ARGV)->run if (!caller);
618 1;