644d1383e5b9263b6a4c5fdb201c97c2e159d06d
[mirror/qt/qt5.git] / init-repository
1 #!/usr/bin/env perl
2 #############################################################################
3 ##
4 ## Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
5 ## Contact: http://www.qt-project.org/
6 ##
7 ## This file is part of the utilities of the Qt Toolkit.
8 ##
9 ## $QT_BEGIN_LICENSE:LGPL$
10 ## GNU Lesser General Public License Usage
11 ## This file may be used under the terms of the GNU Lesser General Public
12 ## License version 2.1 as published by the Free Software Foundation and
13 ## appearing in the file LICENSE.LGPL included in the packaging of this
14 ## file. Please review the following information to ensure the GNU Lesser
15 ## General Public License version 2.1 requirements will be met:
16 ## http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
17 ##
18 ## In addition, as a special exception, Nokia gives you certain additional
19 ## rights. These rights are described in the Nokia Qt LGPL Exception
20 ## version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
21 ##
22 ## GNU General Public License Usage
23 ## Alternatively, this file may be used under the terms of the GNU General
24 ## Public License version 3.0 as published by the Free Software Foundation
25 ## and appearing in the file LICENSE.GPL included in the packaging of this
26 ## file. Please review the following information to ensure the GNU General
27 ## Public License version 3.0 requirements will be met:
28 ## http://www.gnu.org/copyleft/gpl.html.
29 ##
30 ## Other Usage
31 ## Alternatively, this file may be used in accordance with the terms and
32 ## conditions contained in a signed written agreement between you and Nokia.
33 ##
34 ##
35 ##
36 ##
37 ##
38 ##
39 ## $QT_END_LICENSE$
40 ##
41 #############################################################################
42
43 use v5.10;
44 use strict;
45 use warnings;
46
47 package Qt::InitRepository;
48
49
50 =head1 NAME
51
52 init-repository - initialize the Qt5 repository and all submodules
53
54 =head1 SYNOPSIS
55
56   ./init-repository [options]
57
58 This script may be run after an initial `git clone' of Qt5 in order to check
59 out all submodules.
60
61
62 =head1 OPTIONS
63
64 B<Global options:>
65
66 =over
67
68 =item --force, -f
69
70 Force initialization (even if the submodules are already checked out).
71
72
73 =item --quiet, -q
74
75 Be quiet.  Will exit cleanly if the repository is already initialized.
76
77 =back
78
79
80 B<Module options:>
81
82 =over
83
84 =item --no-webkit
85
86 Skip webkit and webkit examples submodules.
87 It may be desirable to skip these modules due to the large size of the webkit
88 git repository.
89
90 =item --module-subset=<module1>,<module2>...
91
92 Only initialize the specified subset of modules given as the argument. Specified
93 modules must already exist in .gitmodules.
94
95 =item --no-update
96
97 Skip the `git submodule update' command.
98
99
100 =item --ignore-submodules
101
102 Set git config to ignore submodules by default when doing operations on the
103 qt5 repo, such as `pull', `fetch', `diff' etc.
104
105 This option is default for --nokia-developer/--brisbane.
106
107 After using this option, pass `--ignore-submodules=none' to git to override
108 it as needed.
109
110 =back
111
112
113 B<Repository options:>
114
115 =over
116
117 =item --nokia-developer
118
119 Switch to internal Nokia URLs.
120
121
122 =item --brisbane
123
124 Switch to internal Nokia URLs and make use of the Brisbane git mirrors.
125 (Implies `--mirror' and `--mirror-webkit').
126
127 =item --berlin
128
129 Switch to internal Nokia URLs and make use of the Berlin git mirrors.
130 (Implies `--mirror' and `--mirror-webkit').
131
132
133 =item --ssh
134
135 Use the SSH protocol for git operations.  This may be useful if the git
136 protocol is blocked by a firewall. Note that this requires a user account
137 with an uploaded SSH key on all servers used.  (Implies `--nokia-developer').
138
139 The `--ssh' option does not affect the gerrit remotes.
140
141
142 =item --http
143
144 Use the HTTP protocol for git operations.  This may be useful if the git
145 protocol is blocked by a firewall.  Note that this only works with the
146 external Gitorious server.
147
148 The `--http' option does not affect the gerrit remotes.
149
150
151 =item --codereview-username <Gerrit/JIRA username>
152
153 Specify the user name for the (potentially) writable `gerrit' remote
154 for each module, for use with the Gerrit code review tool.
155
156 If this option is omitted, the gerrit remote is created without a username
157 and port number, and thus relies on a correct SSH configuration.
158
159
160 =item --alternates <path to other Qt5 repo>
161
162 Adds alternates for each submodule to another full qt5 checkout. This makes
163 this qt5 checkout very small, as it will use the object store of the
164 alternates before unique objects are stored in its own object store.
165
166 This option has no effect when using `--no-update'.
167
168 B<NOTE:> This will make this repo dependent on the alternate, which is
169 potentially dangerous!  The dependency can be broken by also using
170 the `--copy-objects' option, or by running C<git repack -a> in each
171 submodule, where required.  Please read the note about the `--shared' option
172 in the documentation of `git clone' for more information.
173
174
175 =item --copy-objects
176
177 When `--alternates' is used, automatically do a C<git repack -a> in each
178 submodule after cloning, to ensure that the repositories are independent
179 from the source used as a reference for cloning.
180
181 Note that this negates the disk usage benefits gained from the use of
182 `--alternates'.
183
184
185 =item --mirror <url-base>
186
187 Uses <url-base> as the base URL for submodule git mirrors.
188
189 For example:
190
191   --mirror user@machine:/foo/bar
192
193 ...will use the following as a mirror for qtbase:
194
195   user@machine:/foo/bar/qtbase.git
196
197 The mirror is permitted to contain a subset of the submodules; any
198 missing modules will fall back to the canonical URLs.
199
200 =item --mirror-webkit <url>
201
202 Uses <url> as the URL for the webkit git mirror.
203
204 =back
205
206 =cut
207
208 use Carp         qw( confess             );
209 use English      qw( -no_match_vars      );
210 use Getopt::Long qw( GetOptionsFromArray );
211 use Pod::Usage   qw( pod2usage           );
212 use Cwd          qw( getcwd              );
213
214 my %PROTOCOLS = (
215     'internal'  => 'git://scm.dev.nokia.troll.no/' ,
216     'ssh'       => 'git@scm.dev.nokia.troll.no:'   ,
217     'http'      => 'http://git.gitorious.org/'     ,
218 );
219
220 my %GERRIT_REPOS = map { $_ => "qt/$_" } qw(
221     qt3d
222     qt5
223     qlalr
224     qtactiveqt
225     qtbase
226     qtconnectivity
227     qtdeclarative
228     qtdoc
229     qtdocgallery
230     qtfeedback
231     qtjsondb
232     qtjsbackend
233     qtlocation
234     qtmultimedia
235     qtphonon
236     qtpim
237     qtqa
238     qtrepotools
239     qtscript
240     qtsensors
241     qtsvg
242     qtsystems
243     qttools
244     qttranslations
245     qtwayland
246     qtwebkit-examples-and-demos
247     qtxmlpatterns
248 );
249
250 my $GERRIT_SSH_BASE
251     = 'ssh://@USER@codereview.qt-project.org@PORT@/';
252
253 my $BNE_MIRROR_URL_BASE
254     = 'git://bq-git.apac.nokia.com/qtsoftware/';
255
256 my $BNE_MIRROR_WEBKIT_URL
257     = 'git://bq-git.apac.nokia.com/qtsoftware/research/gitorious-org-webkit-qtwebkit-mirror.git';
258
259 my $BER_MIRROR_URL_BASE
260     = 'git://ber-git.europe.nokia.com/';
261
262 my $BER_MIRROR_WEBKIT_URL
263     = 'git://ber-git.europe.nokia.com/qtwebkit/qtwebkit.git';
264
265
266 sub new
267 {
268     my ($class, @arguments) = @_;
269
270     my $self = {};
271     bless $self, $class;
272     $self->parse_arguments(@arguments);
273
274     return $self;
275 }
276
277 # Like `system', but possibly log the command, and die on non-zero exit code
278 sub exe
279 {
280     my ($self, @cmd) = @_;
281
282     if (!$self->{quiet}) {
283         print "+ @cmd\n";
284     }
285
286     if (system(@cmd) != 0) {
287         confess "@cmd exited with status $CHILD_ERROR";
288     }
289
290     return;
291 }
292
293 sub parse_arguments
294 {
295     my ($self, @args) = @_;
296
297     %{$self} = (%{$self},
298         'alternates'          => "",
299         'codereview-username' => "",
300         'detach-alternates'   => 0 ,
301         'force'               => 0 ,
302         'ignore-submodules'   => 0 ,
303         'mirror-url'          => "",
304         'mirror-webkit-url'   => "",
305         'nokia-developer'     => 0 ,
306         'protocol'            => "",
307         'update'              => 1 ,
308         'webkit'              => 1 ,
309         'module-subset'       => "",
310     );
311
312     GetOptionsFromArray(\@args,
313         'alternates=s'      =>  \$self->{qw{ alternates        }},
314         'codereview-username=s' => \$self->{qw{ codereview-username }},
315         'copy-objects'      =>  \$self->{qw{ detach-alternates }},
316         'force'             =>  \$self->{qw{ force             }},
317         'ignore-submodules' =>  \$self->{qw{ ignore-submodules }},
318         'mirror-webkit=s'   =>  \$self->{qw{ mirror-webkit-url }},
319         'mirror=s'          =>  \$self->{qw{ mirror-url        }},
320         'nokia-developer'   =>  \$self->{qw{ nokia-developer   }},
321         'quiet'             =>  \$self->{qw{ quiet             }},
322         'update!'           =>  \$self->{qw{ update            }},
323         'webkit!'           =>  \$self->{qw{ webkit            }},
324         'module-subset=s'   =>  \$self->{qw{ module-subset     }},
325
326         'help|?'            =>  sub { pod2usage(1);               },
327         'http'              =>  sub { $self->{protocol} = 'http'; },
328         'ssh|ssh-protocol'  =>  sub { $self->{protocol} = 'ssh';  },
329
330         'brisbane|brisbane-nokia-developer' => sub {
331             $self->{'nokia-developer'}   = 1;
332             $self->{'protocol'}          = 'internal';
333             $self->{'mirror-url'}        = $BNE_MIRROR_URL_BASE;
334             $self->{'mirror-webkit-url'} = $BNE_MIRROR_WEBKIT_URL;
335             $self->{'ignore-submodules'} = 1;
336         },
337
338         'berlin|berlin-nokia-developer' => sub {
339             $self->{'nokia-developer'}   = 1;
340             $self->{'protocol'}          = 'internal';
341             $self->{'mirror-url'}        = $BER_MIRROR_URL_BASE;
342             $self->{'mirror-webkit-url'} = $BER_MIRROR_WEBKIT_URL;
343         },
344
345         'nokia-developer' => sub {
346             $self->{'nokia-developer'}   = 1;
347             $self->{'protocol'}          = 'internal';
348             $self->{'ignore-submodules'} = 1;
349         },
350     ) || pod2usage(2);
351
352     if ($self->{'nokia-developer'} && $self->{'protocol'} eq 'http') {
353         print "*** Ignoring use of HTTP protocol, as it's only usable with external server\n";
354         $self->{'protocol'} = '';
355     }
356
357     # Replace any double trailing slashes from end of mirror
358     $self->{'mirror-url'} =~ s{//+$}{/};
359
360     if ($self->{'module-subset'}) {
361         $self->{'module-subset'} = {
362             map { $_ => 1 } split(qr{,}, $self->{'module-subset'})
363         };
364     }
365
366     return;
367 }
368
369 sub check_if_already_initialized
370 {
371     my ($self) = @_;
372
373     # We consider the repo as `initialized' if submodule.qtbase.url is set
374     if (qx(git config --get submodule.qtbase.url)) {
375         if ($self->{force}) {
376             my @configresult = qx(git config -l);
377             foreach (@configresult) {
378                 # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
379                 if (/(submodule\.[^.=]+)\.url=.*/) {
380                     $self->exe('git', 'config', '--remove-section', $1);
381                 }
382             }
383         }
384         else {
385             exit 0 if ($self->{quiet});
386             print "Will not reinitialize already initialized repository (use -f to force)!\n";
387             exit 1;
388         }
389     }
390
391     return;
392 }
393
394 sub git_submodule_init
395 {
396     my ($self) = @_;
397
398     my @init_args;
399     if ($self->{quiet}) {
400         push @init_args, '--quiet';
401     }
402     $self->exe('git', 'submodule', 'init', @init_args);
403
404     my $template = getcwd()."/.commit-template";
405     if (-e $template) {
406         $self->exe('git', 'config', 'commit.template', $template);
407     }
408
409     return;
410 }
411
412 sub git_disable_webkit_submodule
413 {
414     my ($self) = @_;
415
416     $self->exe('git', 'config', '--remove', 'submodule.qtwebkit');
417     $self->exe('git', 'config', '--remove', 'submodule.qtwebkit-examples-and-demos');
418
419     return;
420 }
421
422 sub git_prune_submodules
423 {
424     my ($self) = @_;
425
426     my @configresult = qx(git config -l);
427     foreach my $line (@configresult) {
428         if ($line =~ /submodule\.([^.=]+)\.url=/) {
429             my $module_name = $1;
430             if (!$self->{'module-subset'}{$module_name}) {
431                 $self->exe('git', 'config', '--remove', "submodule.$module_name");
432             }
433         }
434     }
435 }
436
437 sub git_set_submodule_config
438 {
439     my ($self) = @_;
440
441     my @configresult          = qx(git config -l);
442     my $protocol              = $self->{protocol};
443     my $url_base_for_protocol = $PROTOCOLS{$protocol};
444
445     foreach my $line (@configresult) {
446         # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
447         next if ($line !~ /submodule\.([^.=]+)\.url=(.*)/);
448
449         my $key   = $1;
450         my $value = $2;
451
452         if ($protocol) {
453             # WebKit is special, and has only external link.
454             if ($key ne 'qtwebkit') {
455                 # qt-labs projects are still hosted under qt internally.
456                 if ($protocol ne 'http') {
457                     $value =~ s,^git://gitorious\.org/qt-labs/,${url_base_for_protocol}qt/,;
458                 }
459
460                 # assume all other projects hosted under gitorious publicly.
461                 $value =~ s,^git://gitorious\.org/,$url_base_for_protocol,;
462             }
463         }
464
465         $self->exe('git', 'config', "submodule.$key.url", $value);
466
467         if ($self->{'ignore-submodules'}) {
468             $self->exe('git', 'config', "submodule.$key.ignore", 'all');
469         }
470     }
471
472     return;
473 }
474
475 sub git_clone_all_submodules
476 {
477     my ($self) = @_;
478
479     # manually clone each repo here, so we can easily use reference repos, mirrors etc
480     my @configresult = qx(git config -l);
481     foreach my $line (@configresult) {
482         if ($line =~ /submodule\.([^.=]+)\.url=(.*)/) {
483             $self->git_clone_one_submodule($1, $2);
484         }
485     }
486
487     if ($self->{update}) {
488         $self->exe('git', 'submodule', 'update', '--recursive');
489     }
490
491     return;
492 }
493
494 sub git_add_remotes
495 {
496     my ($self, $repo_basename) = @_;
497
498     my $gerrit_repo_basename = $GERRIT_REPOS{$repo_basename};
499     if ($gerrit_repo_basename) {
500         my $gerrit_repo_url;
501
502         # If given a username, make a "verbose" remote.
503         # Otherwise, rely on proper SSH configuration.
504         if ($self->{'codereview-username'}) {
505             $gerrit_repo_url = $GERRIT_SSH_BASE;
506             $gerrit_repo_url =~ s,\@USER\@,$self->{'codereview-username'}\@,;
507             $gerrit_repo_url =~ s,\@PORT\@,:29418,;
508         }
509         else {
510             $gerrit_repo_url = $GERRIT_SSH_BASE;
511             $gerrit_repo_url =~ s,\@[^\@]+\@,,g;
512         }
513
514         $gerrit_repo_url .= $gerrit_repo_basename;
515         $self->exe('git', 'config', 'remote.gerrit.url', $gerrit_repo_url);
516         $self->exe('git', 'config', 'remote.gerrit.fetch', '+refs/heads/*:refs/remotes/gerrit/*');
517     }
518
519     return;
520 }
521
522 sub git_clone_one_submodule
523 {
524     my ($self, $submodule, $url) = @_;
525
526     my $alternates            = $self->{ 'alternates'        };
527     my $mirror_url            = $self->{ 'mirror-url'        };
528     my $mirror_webkit_url     = $self->{ 'mirror-webkit-url' };
529     my $protocol              = $self->{ 'protocol'          };
530
531     # `--reference FOO' args for the clone, if any.
532     my @reference_args;
533
534     if ($alternates) {
535         # alternates is a qt5 repo, so the submodule will be under that.
536         if (-d "$alternates/$submodule") {
537             @reference_args = ('--reference', "$alternates/$submodule");
538         }
539         else {
540             print " *** $alternates/$submodule not found, ignoring alternate for this submodule\n";
541         }
542     }
543
544     my $mirror;
545     if ($mirror_url && ($submodule ne 'qtwebkit')) {
546         $mirror = $mirror_url."qt/$submodule";
547         $mirror .= ".git" unless (-d $mirror); # Support local disk mirror
548     }
549     elsif ($mirror_webkit_url && ($submodule eq 'qtwebkit')) {
550         $mirror = $mirror_webkit_url;
551     }
552
553     if ($mirror) {
554         # Only use the mirror if it can be reached.
555         eval { $self->exe('git', 'ls-remote', $mirror, 'test/if/mirror/exists') };
556         if ($@) {
557             warn "mirror [$mirror] is not accessible; $url will be used\n";
558             undef $mirror;
559         }
560     }
561
562     my $do_clone = (! -d "$submodule/.git");
563     if ($do_clone) {
564         $self->exe('git', 'clone', @reference_args, ($mirror ? $mirror : $url), $submodule);
565     }
566
567     chdir($submodule) or confess "chdir $submodule: $OS_ERROR";
568
569     $self->exe('git', 'config', 'remote.origin.url', $url);
570     if ($mirror) {
571         $self->exe('git', 'config', 'remote.mirror.url', $mirror);
572         $self->exe('git', 'config', 'remote.mirror.fetch', '+refs/heads/*:refs/remotes/mirror/*');
573     }
574
575     if (!$do_clone) {
576         $self->exe('git', 'fetch', ($mirror ? $mirror : $url));
577     }
578
579     my $template = getcwd()."/../.commit-template";
580     if (-e $template) {
581         $self->exe('git', 'config', 'commit.template', $template);
582     }
583
584     $self->git_add_remotes($submodule);
585
586     if ($self->{'detach-alternates'}) {
587         $self->exe('git', 'repack', '-a');
588
589         my $alternates_path = '.git/objects/info/alternates';
590         unlink($alternates_path) || confess "unlink $alternates_path: $OS_ERROR";
591     }
592
593     chdir("..") or confess "cd ..: $OS_ERROR";
594
595     return;
596 }
597
598 sub run
599 {
600     my ($self) = @_;
601
602     $self->check_if_already_initialized;
603     $self->git_submodule_init;
604
605     if (!$self->{webkit}) {
606         $self->git_disable_webkit_submodule;
607     }
608
609     if ($self->{'module-subset'}) {
610         $self->git_prune_submodules;
611     }
612
613     $self->git_set_submodule_config;
614
615     $self->git_clone_all_submodules;
616
617     $self->git_add_remotes('qt5');
618
619     return;
620 }
621
622 #==============================================================================
623
624 Qt::InitRepository->new(@ARGV)->run if (!caller);
625 1;