Add qtquick3d module.
[mirror/qt/qt5.git] / init-repository
1 #!/usr/bin/env perl
2 #############################################################################
3 ##
4 ## Copyright (C) 2011 Nokia Corporation and/or its subsidiary(-ies).
5 ## All rights reserved.
6 ## Contact: Nokia Corporation (qt-info@nokia.com)
7 ##
8 ## This file is part of the utilities of the Qt Toolkit.
9 ##
10 ## $QT_BEGIN_LICENSE:LGPL$
11 ## GNU Lesser General Public License Usage
12 ## This file may be used under the terms of the GNU Lesser General Public
13 ## License version 2.1 as published by the Free Software Foundation and
14 ## appearing in the file LICENSE.LGPL included in the packaging of this
15 ## file. Please review the following information to ensure the GNU Lesser
16 ## General Public License version 2.1 requirements will be met:
17 ## http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
18 ##
19 ## In addition, as a special exception, Nokia gives you certain additional
20 ## rights. These rights are described in the Nokia Qt LGPL Exception
21 ## version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
22 ##
23 ## GNU General Public License Usage
24 ## Alternatively, this file may be used under the terms of the GNU General
25 ## Public License version 3.0 as published by the Free Software Foundation
26 ## and appearing in the file LICENSE.GPL included in the packaging of this
27 ## file. Please review the following information to ensure the GNU General
28 ## Public License version 3.0 requirements will be met:
29 ## http://www.gnu.org/copyleft/gpl.html.
30 ##
31 ## Other Usage
32 ## Alternatively, this file may be used in accordance with the terms and
33 ## conditions contained in a signed written agreement between you and Nokia.
34 ##
35 ##
36 ##
37 ##
38 ##
39 ## $QT_END_LICENSE$
40 ##
41 #############################################################################
42
43 use v5.10;
44 use strict;
45 use warnings;
46
47 package Qt::InitRepository;
48
49
50 =head1 NAME
51
52 init-repository - initialize the Qt5 repository and all submodules
53
54 =head1 SYNOPSIS
55
56   ./init-repository [options]
57
58 This script may be run after an initial `git clone' of Qt5 in order to check
59 out all submodules.
60
61
62 =head1 OPTIONS
63
64 B<Global options:>
65
66 =over
67
68 =item --force, -f
69
70 Force initialization (even if the submodules are already checked out).
71
72
73 =item --quiet, -q
74
75 Be quiet.  Will exit cleanly if the repository is already initialized.
76
77 =back
78
79
80 B<Module options:>
81
82 =over
83
84 =item --no-webkit
85
86 Skip webkit and webkit examples submodules.
87 It may be desirable to skip these modules due to the large size of the webkit
88 git repository.
89
90 =item --module-subset=<module1>,<module2>...
91
92 Only initialize the specified subset of modules given as the argument. Specified
93 modules must already exist in .gitmodules.
94
95 =item --no-update
96
97 Skip the `git submodule update' command.
98
99
100 =item --ignore-submodules
101
102 Set git config to ignore submodules by default when doing operations on the
103 qt5 repo, such as `pull', `fetch', `diff' etc.
104
105 This option is default for --nokia-developer/--brisbane.
106
107 After using this option, pass `--ignore-submodules=none' to git to override
108 it as needed.
109
110 =back
111
112
113 B<Repository options:>
114
115 =over
116
117 =item --nokia-developer
118
119 Switch to internal Nokia URLs.
120
121
122 =item --brisbane
123
124 Switch to internal Nokia URLs and make use of the Brisbane git mirrors.
125 (Implies `--mirror' and `--mirror-webkit').
126
127 =item --berlin
128
129 Switch to internal Nokia URLs and make use of the Berlin git mirrors.
130 (Implies `--mirror' and `--mirror-webkit').
131
132
133 =item --ssh
134
135 Use the SSH protocol for git operations.  This may be useful if the git
136 protocol is blocked by a firewall. Note that this requires a user account
137 with an uploaded SSH key on all servers used.  (Implies `--nokia-developer').
138
139 The `--ssh' option does not affect the gerrit remotes.
140
141
142 =item --http
143
144 Use the HTTP protocol for git operations.  This may be useful if the git
145 protocol is blocked by a firewall.  Note that this only works with the
146 external Gitorious server.
147
148 The `--http' option does not affect the gerrit remotes.
149
150
151 =item --codereview-username <Gerrit/JIRA username>
152
153 Adds a (potentially) writable remote named `gerrit' for each module,
154 for use with the Gerrit code review tool.
155 This requires a username for SSH access to the codereview.qt.nokia.com
156 server, which will be the same username you have for the bugtracker at
157 bugreports.qt.nokia.com.
158
159 If this option is omitted, the gerrit remote is created with read-only
160 access (using HTTP protocol).
161
162
163 =item --alternates <path to other Qt5 repo>
164
165 Adds alternates for each submodule to another full qt5 checkout. This makes
166 this qt5 checkout very small, as it will use the object store of the
167 alternates before unique objects are stored in its own object store.
168
169 This option has no effect when using `--no-update'.
170
171 B<NOTE:> This will make this repo dependent on the alternate, which is
172 potentially dangerous!  The dependency can be broken by also using
173 the `--copy-objects' option, or by running C<git repack -a> in each
174 submodule, where required.  Please read the note about the `--shared' option
175 in the documentation of `git clone' for more information.
176
177
178 =item --copy-objects
179
180 When `--alternates' is used, automatically do a C<git repack -a> in each
181 submodule after cloning, to ensure that the repositories are independent
182 from the source used as a reference for cloning.
183
184 Note that this negates the disk usage benefits gained from the use of
185 `--alternates'.
186
187
188 =item --mirror <url-base>
189
190 Uses <url-base> as the base URL for submodule git mirrors.
191
192 For example:
193
194   --mirror user@machine:/foo/bar
195
196 ...will use the following as a mirror for qtbase:
197
198   user@machine:/foo/bar/qtbase.git
199
200
201 =item --mirror-webkit <url>
202
203 Uses <url> as the URL for the webkit git mirror.
204
205 =back
206
207 =cut
208
209 use Carp         qw( confess             );
210 use English      qw( -no_match_vars      );
211 use Getopt::Long qw( GetOptionsFromArray );
212 use Pod::Usage   qw( pod2usage           );
213 use Cwd          qw( getcwd              );
214
215 my %PROTOCOLS = (
216     'internal'  => 'git://scm.dev.nokia.troll.no/' ,
217     'ssh'       => 'git@scm.dev.nokia.troll.no:'   ,
218     'http'      => 'http://git.gitorious.org/'     ,
219 );
220
221 my %GERRIT_REPOS = map { $_ => "qt/$_" } qw(
222     qt5
223     qlalr
224     qtactiveqt
225     qtbase
226     qtdeclarative
227     qtdoc
228     qtfeedback
229     qtlocation
230     qtmultimedia
231     qtmultimediakit
232     qtphonon
233     qtqa
234     qtrepotools
235     qtscript
236     qtsensors
237     qtsvg
238     qtsystems
239     qttools
240     qttranslations
241     qtwebkit-examples-and-demos
242     qtxmlpatterns
243 );
244 $GERRIT_REPOS{qtquick3d} = "qt/quick3d";
245
246 # Protocol-specific repo overrides, if they differ from the values set in the git submodule config
247 # (e.g. because public vs private names differ for whatever reason)
248 my %PROTOCOL_REPOS = (
249     qtquick3d   =>  {
250         internal    =>  "qt/quick3d",   # instead of qt-quick3d/qt-quick3d on gitorious
251         ssh         =>  "qt/quick3d",
252     },
253 );
254
255 my $GERRIT_SSH_BASE
256     = 'ssh://codereview.qt.nokia.com:29418/';
257
258 my $GERRIT_HTTP_BASE
259     = 'http://codereview.qt.nokia.com/p/';
260
261 my $BNE_MIRROR_URL_BASE
262     = 'git://bq-git.apac.nokia.com/qtsoftware/';
263
264 my $BNE_MIRROR_WEBKIT_URL
265     = 'git://bq-git.apac.nokia.com/qtsoftware/research/gitorious-org-webkit-qtwebkit-mirror.git';
266
267 my $BNE_MIRROR_V8_URL
268     = 'git://bq-git.apac.nokia.com/github/v8.git';
269
270 my $BER_MIRROR_URL_BASE
271     = 'git://ber-git.europe.nokia.com/';
272
273 my $BER_MIRROR_WEBKIT_URL
274     = 'git://ber-git.europe.nokia.com/qtwebkit/qtwebkit.git';
275
276
277 sub new
278 {
279     my ($class, @arguments) = @_;
280
281     my $self = {};
282     bless $self, $class;
283     $self->parse_arguments(@arguments);
284
285     return $self;
286 }
287
288 # Like `system', but possibly log the command, and die on non-zero exit code
289 sub exe
290 {
291     my ($self, @cmd) = @_;
292
293     if (!$self->{quiet}) {
294         print "+ @cmd\n";
295     }
296
297     if (system(@cmd) != 0) {
298         confess "@cmd exited with status $CHILD_ERROR";
299     }
300
301     return;
302 }
303
304 sub parse_arguments
305 {
306     my ($self, @args) = @_;
307
308     %{$self} = (%{$self},
309         'alternates'          => "",
310         'codereview-username' => "",
311         'detach-alternates'   => 0 ,
312         'force'               => 0 ,
313         'ignore-submodules'   => 0 ,
314         'mirror-url'          => "",
315         'mirror-webkit-url'   => "",
316         'mirror-v8-url'       => "",
317         'nokia-developer'     => 0 ,
318         'protocol'            => "",
319         'update'              => 1 ,
320         'webkit'              => 1 ,
321         'module-subset'       => "",
322     );
323
324     GetOptionsFromArray(\@args,
325         'alternates=s'      =>  \$self->{qw{ alternates        }},
326         'codereview-username=s' => \$self->{qw{ codereview-username }},
327         'copy-objects'      =>  \$self->{qw{ detach-alternates }},
328         'force'             =>  \$self->{qw{ force             }},
329         'ignore-submodules' =>  \$self->{qw{ ignore-submodules }},
330         'mirror-webkit=s'   =>  \$self->{qw{ mirror-webkit-url }},
331         'mirror=s'          =>  \$self->{qw{ mirror-url        }},
332         'nokia-developer'   =>  \$self->{qw{ nokia-developer   }},
333         'quiet'             =>  \$self->{qw{ quiet             }},
334         'update!'           =>  \$self->{qw{ update            }},
335         'webkit!'           =>  \$self->{qw{ webkit            }},
336         'module-subset=s'   =>  \$self->{qw{ module-subset     }},
337
338         'help|?'            =>  sub { pod2usage(1);               },
339         'http'              =>  sub { $self->{protocol} = 'http'; },
340         'ssh|ssh-protocol'  =>  sub { $self->{protocol} = 'ssh';  },
341
342         'brisbane|brisbane-nokia-developer' => sub {
343             $self->{'nokia-developer'}   = 1;
344             $self->{'protocol'}          = 'internal';
345             $self->{'mirror-url'}        = $BNE_MIRROR_URL_BASE;
346             $self->{'mirror-v8-url'}     = $BNE_MIRROR_V8_URL;
347             $self->{'mirror-webkit-url'} = $BNE_MIRROR_WEBKIT_URL;
348             $self->{'ignore-submodules'} = 1;
349         },
350
351         'berlin|berlin-nokia-developer' => sub {
352             $self->{'nokia-developer'}   = 1;
353             $self->{'protocol'}          = 'internal';
354             $self->{'mirror-url'}        = $BER_MIRROR_URL_BASE;
355             $self->{'mirror-webkit-url'} = $BER_MIRROR_WEBKIT_URL;
356         },
357
358         'nokia-developer' => sub {
359             $self->{'nokia-developer'}   = 1;
360             $self->{'protocol'}          = 'internal';
361             $self->{'ignore-submodules'} = 1;
362         },
363     ) || pod2usage(2);
364
365     if ($self->{'nokia-developer'} && $self->{'protocol'} eq 'http') {
366         print "*** Ignoring use of HTTP protocol, as it's only usable with external server\n";
367         $self->{'protocol'} = '';
368     }
369
370     # Replace any double trailing slashes from end of mirror
371     $self->{'mirror-url'} =~ s{//+$}{/};
372
373     if ($self->{'module-subset'}) {
374         $self->{'module-subset'} = {
375             map { $_ => 1 } split(qr{,}, $self->{'module-subset'})
376         };
377     }
378
379     return;
380 }
381
382 sub check_if_already_initialized
383 {
384     my ($self) = @_;
385
386     # We consider the repo as `initialized' if submodule.qtbase.url is set
387     if (qx(git config --get submodule.qtbase.url)) {
388         if ($self->{force}) {
389             my @configresult = qx(git config -l);
390             foreach (@configresult) {
391                 # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
392                 if (/(submodule\.[^.=]+)\.url=.*/) {
393                     $self->exe('git', 'config', '--remove-section', $1);
394                 }
395             }
396         }
397         else {
398             exit 0 if ($self->{quiet});
399             print "Will not reinitialize already initialized repository (use -f to force)!\n";
400             exit 1;
401         }
402     }
403
404     return;
405 }
406
407 sub git_submodule_init
408 {
409     my ($self) = @_;
410
411     my @init_args;
412     if ($self->{quiet}) {
413         push @init_args, '--quiet';
414     }
415     $self->exe('git', 'submodule', 'init', @init_args);
416
417     my $template = getcwd()."/.commit-template";
418     if (-e $template) {
419         $self->exe('git', 'config', 'commit.template', $template);
420     }
421
422     return;
423 }
424
425 sub git_disable_webkit_submodule
426 {
427     my ($self) = @_;
428
429     $self->exe('git', 'config', '--remove', 'submodule.qtwebkit');
430     $self->exe('git', 'config', '--remove', 'submodule.qtwebkit-examples-and-demos');
431
432     return;
433 }
434
435 sub git_prune_submodules
436 {
437     my ($self) = @_;
438
439     my @configresult = qx(git config -l);
440     foreach my $line (@configresult) {
441         if ($line =~ /submodule\.([^.=]+)\.url=/) {
442             my $module_name = $1;
443             if (!$self->{'module-subset'}{$module_name}) {
444                 $self->exe('git', 'config', '--remove', "submodule.$module_name");
445             }
446         }
447     }
448 }
449
450 sub git_set_submodule_config
451 {
452     my ($self) = @_;
453
454     my @configresult          = qx(git config -l);
455     my $protocol              = $self->{protocol};
456     my $url_base_for_protocol = $PROTOCOLS{$protocol};
457
458     foreach my $line (@configresult) {
459         # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
460         next if ($line !~ /submodule\.([^.=]+)\.url=(.*)/);
461
462         my $key   = $1;
463         my $value = $2;
464
465         if ($protocol) {
466             # WebKit is special, and has only external link.
467             if ($key ne 'qtwebkit') {
468                 # qt-labs projects are still hosted under qt internally.
469                 if ($protocol ne 'http') {
470                     $value =~ s,^git://gitorious\.org/qt-labs/,${url_base_for_protocol}qt/,;
471                 }
472
473                 if ($PROTOCOL_REPOS{$key}->{$protocol}) {
474                     # If this repo has an explicitly set basename for this protocol, use it...
475                     # e.g.   'git@example.com:'     . 'qt/quick3d'
476                     $value = $url_base_for_protocol . $PROTOCOL_REPOS{$key}->{$protocol};
477                 }
478                 else {
479                     # ...otherwise, assume the selected protocol uses same naming structure
480                     # as gitorious.org
481                     # e.g. git://gitorious.org/qt/qt5 => git@example.com:qt/qt5
482                     $value =~ s,^git://gitorious\.org/,$url_base_for_protocol,;
483                 }
484             }
485         }
486
487         $self->exe('git', 'config', "submodule.$key.url", $value);
488
489         if ($self->{'ignore-submodules'}) {
490             $self->exe('git', 'config', "submodule.$key.ignore", 'all');
491         }
492     }
493
494     return;
495 }
496
497 sub git_clone_all_submodules
498 {
499     my ($self) = @_;
500
501     # manually clone each repo here, so we can easily use reference repos, mirrors etc
502     my @configresult = qx(git config -l);
503     foreach my $line (@configresult) {
504         if ($line =~ /submodule\.([^.=]+)\.url=(.*)/) {
505             $self->git_clone_one_submodule($1, $2);
506         }
507     }
508
509     $self->exe('git', 'submodule', 'update');
510
511     return;
512 }
513
514 sub git_add_remotes
515 {
516     my ($self, $repo_basename) = @_;
517
518     my $protocol              = $self->{protocol};
519     my $url_base_for_protocol = $PROTOCOLS{$protocol};
520
521     my %current_remotes;
522     for my $line (qx(git remote show)) {
523         chomp $line;
524         $current_remotes{$line} = 1;
525     }
526
527     my $gerrit_repo_basename = $GERRIT_REPOS{$repo_basename};
528     if ($gerrit_repo_basename && !$current_remotes{'gerrit'}) {
529         my $gerrit_repo_url;
530
531         # If given a username, we use writable remote (ssh).
532         # Otherwise, we use read-only (http).
533         if ($self->{'codereview-username'}) {
534             $gerrit_repo_url = $GERRIT_SSH_BASE;
535             $gerrit_repo_url =~ s[^ssh://][ssh://$self->{'codereview-username'}@];
536         }
537         else {
538             $gerrit_repo_url = $GERRIT_HTTP_BASE;
539         }
540
541         $gerrit_repo_url .= $gerrit_repo_basename;
542         $self->exe('git', 'remote', 'add', 'gerrit', $gerrit_repo_url);
543
544         $current_remotes{'gerrit'} = 1;
545     }
546
547     # if repo still has no gerrit repo defined, alias it to origin
548     if (!$current_remotes{'gerrit'}) {
549         my @configresult = qx(git remote -v);
550         foreach (@configresult) {
551             if (/^origin\s+(\S+) \(fetch\)/) {
552                 $self->exe('git', 'remote', 'add', 'gerrit', $1);
553             }
554         }
555     }
556
557     return;
558 }
559
560 sub git_clone_one_submodule
561 {
562     my ($self, $submodule, $url) = @_;
563
564     my $alternates            = $self->{ 'alternates'        };
565     my $mirror_url            = $self->{ 'mirror-url'        };
566     my $mirror_webkit_url     = $self->{ 'mirror-webkit-url' };
567     my $mirror_v8_url         = $self->{ 'mirror-v8-url'     };
568
569     # `--reference FOO' args for the clone, if any.
570     my @reference_args;
571
572     if ($alternates) {
573         # alternates is a qt5 repo, so the submodule will be under that.
574         if (-d "$alternates/$submodule") {
575             @reference_args = ('--reference', "$alternates/$submodule");
576         }
577         else {
578             print " *** $alternates/$submodule not found, ignoring alternate for this submodule\n";
579         }
580     }
581
582     my $mirror;
583     if ($mirror_url && ($submodule ne 'qtwebkit')) {
584         $mirror = $mirror_url.( $PROTOCOL_REPOS{$submodule}->{internal} // "qt/$submodule" );
585         $mirror .= ".git" unless (-d $mirror); # Support local disk mirror
586     }
587     elsif ($mirror_webkit_url && ($submodule eq 'qtwebkit')) {
588         $mirror = $mirror_webkit_url;
589     }
590
591     my $do_clone = (! -d "$submodule/.git");
592     if ($do_clone) {
593         $self->exe('git', 'clone', @reference_args, ($mirror ? $mirror : $url), $submodule);
594     }
595
596     chdir($submodule) or confess "chdir $submodule: $OS_ERROR";
597
598     if (!$do_clone) {
599         $self->exe('git', 'fetch', ($mirror ? $mirror : $url));
600     }
601
602     my $template = getcwd()."/../.commit-template";
603     if (-e $template) {
604         $self->exe('git', 'config', 'commit.template', $template);
605     }
606
607     if ($mirror) {
608         $self->exe('git', 'config', 'remote.origin.url', $url);
609
610         # In `force' mode, remove the mirror if it already exists,
611         # since we may be reinitializing the module.
612         if ($self->{force}) {
613             eval { $self->exe('git', 'remote', 'rm', 'mirror'); }; # failure is OK
614         }
615
616         $self->exe('git', 'remote', 'add', 'mirror', $mirror);
617     }
618
619     $self->git_add_remotes($submodule);
620
621     if ($self->{'detach-alternates'}) {
622         $self->exe('git', 'repack', '-a');
623
624         my $alternates_path = '.git/objects/info/alternates';
625         unlink($alternates_path) || confess "unlink $alternates_path: $OS_ERROR";
626     }
627
628     if ($submodule eq "qtdeclarative") { #Extra step needed to setup declarative 
629         $self->exe('git', 'submodule', 'init'); 
630         if ($do_clone and $mirror_v8_url) {
631             my @configresult = qx(git config -l);
632             my $v8url;
633             foreach my $line (@configresult) {
634                 # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
635                 next if ($line !~ /submodule.src\/3rdparty\/v8.url=(.*)/);
636                 $v8url = $1;
637             }
638             chdir('src/3rdparty/') or confess "chdir $submodule/src/3rdparty: $OS_ERROR";
639             $self->exe('git', 'clone', $mirror_v8_url, 'v8');
640             chdir('v8') or confess "chdir $submodule/src/3rdparty/v8: $OS_ERROR";
641             $self->exe('git', 'config', 'remote.origin.url', $v8url);
642             chdir('../../..') or confess "cd ../../..: $OS_ERROR";
643         }
644         $self->exe('git', 'submodule', 'update'); 
645     } 
646
647     chdir("..") or confess "cd ..: $OS_ERROR";
648
649     return;
650 }
651
652 sub run
653 {
654     my ($self) = @_;
655
656     $self->check_if_already_initialized;
657     $self->git_submodule_init;
658
659     if (!$self->{webkit}) {
660         $self->git_disable_webkit_submodule;
661     }
662
663     if ($self->{'module-subset'}) {
664         $self->git_prune_submodules;
665     }
666
667     $self->git_set_submodule_config;
668
669     if ($self->{update}) {
670         $self->git_clone_all_submodules;
671     }
672
673     $self->git_add_remotes('qt5');
674
675     return;
676 }
677
678 #==============================================================================
679
680 Qt::InitRepository->new(@ARGV)->run if (!caller);
681 1;