819e98f1bec94bf9438fe1ac036abbd3054c01c2
[mirror/qt/qt5.git] / init-repository
1 #!/usr/bin/env perl
2 #############################################################################
3 ##
4 ## Copyright (C) 2012 Digia Plc and/or its subsidiary(-ies).
5 ## Contact: http://www.qt-project.org/legal
6 ##
7 ## This file is part of the utilities of the Qt Toolkit.
8 ##
9 ## $QT_BEGIN_LICENSE:LGPL$
10 ## Commercial License Usage
11 ## Licensees holding valid commercial Qt licenses may use this file in
12 ## accordance with the commercial license agreement provided with the
13 ## Software or, alternatively, in accordance with the terms contained in
14 ## a written agreement between you and Digia.  For licensing terms and
15 ## conditions see http://qt.digia.com/licensing.  For further information
16 ## use the contact form at http://qt.digia.com/contact-us.
17 ##
18 ## GNU Lesser General Public License Usage
19 ## Alternatively, this file may be used under the terms of the GNU Lesser
20 ## General Public License version 2.1 as published by the Free Software
21 ## Foundation and appearing in the file LICENSE.LGPL included in the
22 ## packaging of this file.  Please review the following information to
23 ## ensure the GNU Lesser General Public License version 2.1 requirements
24 ## will be met: http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
25 ##
26 ## In addition, as a special exception, Digia gives you certain additional
27 ## rights.  These rights are described in the Digia Qt LGPL Exception
28 ## version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
29 ##
30 ## GNU General Public License Usage
31 ## Alternatively, this file may be used under the terms of the GNU
32 ## General Public License version 3.0 as published by the Free Software
33 ## Foundation and appearing in the file LICENSE.GPL included in the
34 ## packaging of this file.  Please review the following information to
35 ## ensure the GNU General Public License version 3.0 requirements will be
36 ## met: http://www.gnu.org/copyleft/gpl.html.
37 ##
38 ##
39 ## $QT_END_LICENSE$
40 ##
41 #############################################################################
42
43 use v5.8;
44 use strict;
45 use warnings;
46
47 package Qt::InitRepository;
48
49
50 =head1 NAME
51
52 init-repository - initialize the Qt5 repository and all submodules
53
54 =head1 SYNOPSIS
55
56   ./init-repository [options]
57
58 This script may be run after an initial `git clone' of Qt5 in order to check
59 out all submodules.
60
61
62 =head1 OPTIONS
63
64 B<Global options:>
65
66 =over
67
68 =item --force, -f
69
70 Force initialization (even if the submodules are already checked out).
71
72
73 =item --quiet, -q
74
75 Be quiet.  Will exit cleanly if the repository is already initialized.
76
77 =back
78
79
80 B<Module options:>
81
82 =over
83
84 =item --no-webkit
85
86 Skip webkit and webkit examples submodules.
87 It may be desirable to skip these modules due to the large size of the webkit
88 git repository.
89
90 =item --module-subset=<module1>,<module2>...
91
92 Only initialize the specified subset of modules given as the argument. Specified
93 modules must already exist in .gitmodules.
94 The string "all" results in cloning all known modules. The default is the set of
95 maintained modules.
96
97 =item --no-update
98
99 Skip the `git submodule update' command.
100
101
102 =item --ignore-submodules
103
104 Set git config to ignore submodules by default when doing operations on the
105 qt5 repo, such as `pull', `fetch', `diff' etc.
106
107 After using this option, pass `--ignore-submodules=none' to git to override
108 it as needed.
109
110 =back
111
112
113 B<Repository options:>
114
115 =over
116
117 =item --berlin
118
119 Switch to internal URLs and make use of the Berlin git mirrors.
120 (Implies `--mirror').
121
122 =item --oslo
123
124 Switch to internal URLs and make use of the Oslo git mirrors.
125 (Implies `--mirror').
126
127
128 =item --http
129
130 Use the HTTP protocol for git operations.  This may be useful if the git
131 protocol is blocked by a firewall.  Note that this only works with the
132 external Gitorious server.
133
134 The `--http' option does not affect the gerrit remotes.
135
136
137 =item --codereview-username <Gerrit/JIRA username>
138
139 Specify the user name for the (potentially) writable `gerrit' remote
140 for each module, for use with the Gerrit code review tool.
141
142 If this option is omitted, the gerrit remote is created without a username
143 and port number, and thus relies on a correct SSH configuration.
144
145
146 =item --alternates <path to other Qt5 repo>
147
148 Adds alternates for each submodule to another full qt5 checkout. This makes
149 this qt5 checkout very small, as it will use the object store of the
150 alternates before unique objects are stored in its own object store.
151
152 This option has no effect when using `--no-update'.
153
154 B<NOTE:> This will make this repo dependent on the alternate, which is
155 potentially dangerous!  The dependency can be broken by also using
156 the `--copy-objects' option, or by running C<git repack -a> in each
157 submodule, where required.  Please read the note about the `--shared' option
158 in the documentation of `git clone' for more information.
159
160
161 =item --copy-objects
162
163 When `--alternates' is used, automatically do a C<git repack -a> in each
164 submodule after cloning, to ensure that the repositories are independent
165 from the source used as a reference for cloning.
166
167 Note that this negates the disk usage benefits gained from the use of
168 `--alternates'.
169
170
171 =item --mirror <url-base>
172
173 Uses <url-base> as the base URL for submodule git mirrors.
174
175 For example:
176
177   --mirror user@machine:/foo/bar
178
179 ...will use the following as a mirror for qtbase:
180
181   user@machine:/foo/bar/qt/qtbase.git
182
183 The mirror is permitted to contain a subset of the submodules; any
184 missing modules will fall back to the canonical URLs.
185
186 =back
187
188 =cut
189
190 use Carp         qw( confess             );
191 use English      qw( -no_match_vars      );
192 use Getopt::Long qw( GetOptionsFromArray );
193 use Pod::Usage   qw( pod2usage           );
194 use Cwd          qw( getcwd              );
195
196 my %PROTOCOLS = (
197     'http'      => 'http://git.gitorious.org/'     ,
198 );
199
200 my %GERRIT_REPOS = map { $_ => "qt/$_" } qw(
201     qt3d
202     qt5
203     qlalr
204     qtactiveqt
205     qtandroidextras
206     qtbase
207     qtconnectivity
208     qtdeclarative
209     qtdoc
210     qtdocgallery
211     qtfeedback
212     qtgraphicaleffects
213     qtimageformats
214     qtjsondb
215     qtlocation
216     qtmacextras
217     qtmultimedia
218     qtpim
219     qtqa
220     qtquick1
221     qtquickcontrols
222     qtrepotools
223     qtscript
224     qtsensors
225     qtserialport
226     qtsvg
227     qtsystems
228     qttools
229     qttranslations
230     qtwayland
231     qtwebkit
232     qtwebkit-examples
233     qtwinextras
234     qtx11extras
235     qtxmlpatterns
236 );
237
238 my @DEFAULT_REPOS = qw(
239     qtactiveqt
240     qtandroidextras
241     qtbase
242     qtconnectivity
243     qtdeclarative
244     qtdoc
245     qtgraphicaleffects
246     qtimageformats
247     qtmacextras
248     qtmultimedia
249     qtqa
250     qtquick1
251     qtquickcontrols
252     qtlocation
253     qtrepotools
254     qtscript
255     qtsensors
256     qtserialport
257     qtsvg
258     qttools
259     qttranslations
260     qtwebkit
261     qtwebkit-examples
262     qtwinextras
263     qtx11extras
264     qtxmlpatterns
265 );
266
267 my $GERRIT_SSH_BASE
268     = 'ssh://@USER@codereview.qt-project.org@PORT@/';
269
270 my $BER_MIRROR_URL_BASE
271     = 'git://hegel/';
272
273 my $OSLO_MIRROR_URL_BASE
274     = 'git://qilin/';
275
276 sub new
277 {
278     my ($class, @arguments) = @_;
279
280     my $self = {};
281     bless $self, $class;
282     $self->parse_arguments(@arguments);
283
284     return $self;
285 }
286
287 # Like `system', but possibly log the command, and die on non-zero exit code
288 sub exe
289 {
290     my ($self, @cmd) = @_;
291
292     if (!$self->{quiet}) {
293         print "+ @cmd\n";
294     }
295
296     if (system(@cmd) != 0) {
297         confess "@cmd exited with status $CHILD_ERROR";
298     }
299
300     return;
301 }
302
303 sub parse_arguments
304 {
305     my ($self, @args) = @_;
306
307     %{$self} = (%{$self},
308         'alternates'          => "",
309         'codereview-username' => "",
310         'detach-alternates'   => 0 ,
311         'force'               => 0 ,
312         'ignore-submodules'   => 0 ,
313         'mirror-url'          => "",
314         'protocol'            => "",
315         'update'              => 1 ,
316         'webkit'              => 1 ,
317         'module-subset'       => join(",", @DEFAULT_REPOS),
318     );
319
320     GetOptionsFromArray(\@args,
321         'alternates=s'      =>  \$self->{qw{ alternates        }},
322         'codereview-username=s' => \$self->{qw{ codereview-username }},
323         'copy-objects'      =>  \$self->{qw{ detach-alternates }},
324         'force'             =>  \$self->{qw{ force             }},
325         'ignore-submodules' =>  \$self->{qw{ ignore-submodules }},
326         'mirror=s'          =>  \$self->{qw{ mirror-url        }},
327         'quiet'             =>  \$self->{qw{ quiet             }},
328         'update!'           =>  \$self->{qw{ update            }},
329         'webkit!'           =>  \$self->{qw{ webkit            }},
330         'module-subset=s'   =>  \$self->{qw{ module-subset     }},
331
332         'help|?'            =>  sub { pod2usage(1);               },
333         'http'              =>  sub { $self->{protocol} = 'http'; },
334
335         'berlin' => sub {
336             $self->{'mirror-url'}        = $BER_MIRROR_URL_BASE;
337         },
338         'oslo' => sub {
339             $self->{'mirror-url'}        = $OSLO_MIRROR_URL_BASE;
340         },
341     ) || pod2usage(2);
342
343     # Replace any double trailing slashes from end of mirror
344     $self->{'mirror-url'} =~ s{//+$}{/};
345
346     if ($self->{'module-subset'} eq "all") {
347         $self->{'module-subset'} = "";
348     } else {
349         $self->{'module-subset'} = {
350             map { $_ => 1 } split(qr{,}, $self->{'module-subset'})
351         };
352     }
353
354     return;
355 }
356
357 sub check_if_already_initialized
358 {
359     my ($self) = @_;
360
361     # We consider the repo as `initialized' if submodule.qtbase.url is set
362     if (qx(git config --get submodule.qtbase.url)) {
363         if ($self->{force}) {
364             my @configresult = qx(git config -l);
365             foreach (@configresult) {
366                 # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
367                 if (/(submodule\.[^.=]+)\.url=.*/) {
368                     $self->exe('git', 'config', '--remove-section', $1);
369                 }
370             }
371         }
372         else {
373             exit 0 if ($self->{quiet});
374             print "Will not reinitialize already initialized repository (use -f to force)!\n";
375             exit 1;
376         }
377     }
378
379     return;
380 }
381
382 sub git_submodule_init
383 {
384     my ($self) = @_;
385
386     my @init_args;
387     if ($self->{quiet}) {
388         push @init_args, '--quiet';
389     }
390     $self->exe('git', 'submodule', 'init', @init_args);
391
392     my $template = getcwd()."/.commit-template";
393     if (-e $template) {
394         $self->exe('git', 'config', 'commit.template', $template);
395     }
396
397     return;
398 }
399
400 sub git_disable_webkit_submodule
401 {
402     my ($self) = @_;
403
404     $self->exe('git', 'config', '--remove', 'submodule.qtwebkit');
405     $self->exe('git', 'config', '--remove', 'submodule.qtwebkit-examples');
406
407     return;
408 }
409
410 sub git_prune_submodules
411 {
412     my ($self) = @_;
413
414     my @configresult = qx(git config -l);
415     foreach my $line (@configresult) {
416         if ($line =~ /submodule\.([^.=]+)\.url=/) {
417             my $module_name = $1;
418             if (!$self->{'module-subset'}{$module_name}) {
419                 $self->exe('git', 'config', '--remove', "submodule.$module_name");
420             }
421         }
422     }
423 }
424
425 sub git_set_submodule_config
426 {
427     my ($self) = @_;
428
429     my @configresult          = qx(git config -l);
430     my $protocol              = $self->{protocol};
431     my $url_base_for_protocol = $PROTOCOLS{$protocol};
432
433     foreach my $line (@configresult) {
434         # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
435         next if ($line !~ /submodule\.([^.=]+)\.url=(.*)/);
436
437         my $key   = $1;
438         my $value = $2;
439
440         if ($protocol) {
441                 # rewrite URL to chosen protocol
442                 $value =~ s,^git://gitorious\.org/,$url_base_for_protocol,;
443         }
444
445         $self->exe('git', 'config', "submodule.$key.url", $value);
446
447         if ($self->{'ignore-submodules'}) {
448             $self->exe('git', 'config', "submodule.$key.ignore", 'all');
449         }
450     }
451
452     return;
453 }
454
455 sub git_clone_all_submodules
456 {
457     my ($self) = @_;
458
459     # manually clone each repo here, so we can easily use reference repos, mirrors etc
460     my @configresult = qx(git config -l);
461     foreach my $line (@configresult) {
462         if ($line =~ /submodule\.([^.=]+)\.url=(.*)/) {
463             $self->git_clone_one_submodule($1, $2);
464         }
465     }
466
467     if ($self->{update}) {
468         $self->exe('git', 'submodule', 'update', '--recursive');
469     }
470
471     return;
472 }
473
474 sub git_add_remotes
475 {
476     my ($self, $repo_basename) = @_;
477
478     my $gerrit_repo_basename = $GERRIT_REPOS{$repo_basename};
479     if ($gerrit_repo_basename) {
480         my $gerrit_repo_url;
481
482         # If given a username, make a "verbose" remote.
483         # Otherwise, rely on proper SSH configuration.
484         if ($self->{'codereview-username'}) {
485             $gerrit_repo_url = $GERRIT_SSH_BASE;
486             $gerrit_repo_url =~ s,\@USER\@,$self->{'codereview-username'}\@,;
487             $gerrit_repo_url =~ s,\@PORT\@,:29418,;
488         }
489         else {
490             $gerrit_repo_url = $GERRIT_SSH_BASE;
491             $gerrit_repo_url =~ s,\@[^\@]+\@,,g;
492         }
493
494         $gerrit_repo_url .= $gerrit_repo_basename;
495         $self->exe('git', 'config', 'remote.gerrit.url', $gerrit_repo_url);
496         $self->exe('git', 'config', 'remote.gerrit.fetch', '+refs/heads/*:refs/remotes/gerrit/*', '/heads/');
497     }
498
499     return;
500 }
501
502 sub git_clone_one_submodule
503 {
504     my ($self, $submodule, $url) = @_;
505
506     my $alternates            = $self->{ 'alternates'        };
507     my $mirror_url            = $self->{ 'mirror-url'        };
508     my $protocol              = $self->{ 'protocol'          };
509
510     # `--reference FOO' args for the clone, if any.
511     my @reference_args;
512
513     if ($alternates) {
514         # alternates is a qt5 repo, so the submodule will be under that.
515         if (-d "$alternates/$submodule") {
516             @reference_args = ('--reference', "$alternates/$submodule");
517         }
518         else {
519             print " *** $alternates/$submodule not found, ignoring alternate for this submodule\n";
520         }
521     }
522
523     my $mirror;
524     if ($mirror_url) {
525         $mirror = $mirror_url."qt/$submodule";
526         $mirror .= ".git" unless (-d $mirror); # Support local disk mirror
527     }
528
529     if ($mirror) {
530         # Only use the mirror if it can be reached.
531         eval { $self->exe('git', 'ls-remote', $mirror, 'test/if/mirror/exists') };
532         if ($@) {
533             warn "mirror [$mirror] is not accessible; $url will be used\n";
534             undef $mirror;
535         }
536     }
537
538     my $do_clone = (! -d "$submodule/.git");
539     if ($do_clone) {
540         $self->exe('git', 'clone', @reference_args, ($mirror ? $mirror : $url), $submodule);
541     }
542
543     chdir($submodule) or confess "chdir $submodule: $OS_ERROR";
544
545     $self->exe('git', 'config', 'remote.origin.url', $url);
546     if ($mirror) {
547         $self->exe('git', 'config', 'remote.mirror.url', $mirror);
548         $self->exe('git', 'config', 'remote.mirror.fetch', '+refs/heads/*:refs/remotes/mirror/*');
549     }
550
551     if (!$do_clone) {
552         $self->exe('git', 'fetch', ($mirror ? $mirror : $url));
553     }
554
555     my $template = getcwd()."/../.commit-template";
556     if (-e $template) {
557         $self->exe('git', 'config', 'commit.template', $template);
558     }
559
560     $self->git_add_remotes($submodule);
561
562     if ($self->{'detach-alternates'}) {
563         $self->exe('git', 'repack', '-a');
564
565         my $alternates_path = '.git/objects/info/alternates';
566         if (-e $alternates_path) {
567             unlink($alternates_path) || confess "unlink $alternates_path: $OS_ERROR";
568         }
569     }
570
571     chdir("..") or confess "cd ..: $OS_ERROR";
572
573     return;
574 }
575
576 sub run
577 {
578     my ($self) = @_;
579
580     $self->check_if_already_initialized;
581     $self->git_submodule_init;
582
583     if (!$self->{webkit}) {
584         $self->git_disable_webkit_submodule;
585     }
586
587     if ($self->{'module-subset'}) {
588         $self->git_prune_submodules;
589     }
590
591     $self->git_set_submodule_config;
592
593     $self->git_clone_all_submodules;
594
595     $self->git_add_remotes('qt5');
596
597     return;
598 }
599
600 #==============================================================================
601
602 Qt::InitRepository->new(@ARGV)->run if (!caller);
603 1;