Updated submodules.
[mirror/qt/qt5.git] / init-repository
1 #!/usr/bin/env perl
2 #############################################################################
3 ##
4 ## Copyright (C) 2012 Digia Plc and/or its subsidiary(-ies).
5 ## Contact: http://www.qt-project.org/legal
6 ##
7 ## This file is part of the utilities of the Qt Toolkit.
8 ##
9 ## $QT_BEGIN_LICENSE:LGPL$
10 ## Commercial License Usage
11 ## Licensees holding valid commercial Qt licenses may use this file in
12 ## accordance with the commercial license agreement provided with the
13 ## Software or, alternatively, in accordance with the terms contained in
14 ## a written agreement between you and Digia.  For licensing terms and
15 ## conditions see http://qt.digia.com/licensing.  For further information
16 ## use the contact form at http://qt.digia.com/contact-us.
17 ##
18 ## GNU Lesser General Public License Usage
19 ## Alternatively, this file may be used under the terms of the GNU Lesser
20 ## General Public License version 2.1 as published by the Free Software
21 ## Foundation and appearing in the file LICENSE.LGPL included in the
22 ## packaging of this file.  Please review the following information to
23 ## ensure the GNU Lesser General Public License version 2.1 requirements
24 ## will be met: http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
25 ##
26 ## In addition, as a special exception, Digia gives you certain additional
27 ## rights.  These rights are described in the Digia Qt LGPL Exception
28 ## version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
29 ##
30 ## GNU General Public License Usage
31 ## Alternatively, this file may be used under the terms of the GNU
32 ## General Public License version 3.0 as published by the Free Software
33 ## Foundation and appearing in the file LICENSE.GPL included in the
34 ## packaging of this file.  Please review the following information to
35 ## ensure the GNU General Public License version 3.0 requirements will be
36 ## met: http://www.gnu.org/copyleft/gpl.html.
37 ##
38 ##
39 ## $QT_END_LICENSE$
40 ##
41 #############################################################################
42
43 use v5.8;
44 use strict;
45 use warnings;
46
47 package Qt::InitRepository;
48
49
50 =head1 NAME
51
52 init-repository - initialize the Qt5 repository and all submodules
53
54 =head1 SYNOPSIS
55
56   ./init-repository [options]
57
58 This script may be run after an initial `git clone' of Qt5 in order to check
59 out all submodules.
60
61
62 =head1 OPTIONS
63
64 B<Global options:>
65
66 =over
67
68 =item --force, -f
69
70 Force initialization (even if the submodules are already checked out).
71
72
73 =item --force-hooks
74
75 Force initialization of hooks (even if there are already hooks in checked out
76 submodules).
77
78
79 =item --quiet, -q
80
81 Be quiet.  Will exit cleanly if the repository is already initialized.
82
83 =back
84
85
86 B<Module options:>
87
88 =over
89
90 =item --no-webkit
91
92 Skip webkit and webkit examples submodules.
93 It may be desirable to skip these modules due to the large size of the webkit
94 git repository.
95
96 =item --module-subset=<module1>,<module2>...
97
98 Only initialize the specified subset of modules given as the argument. Specified
99 modules must already exist in .gitmodules.
100 The string "all" results in cloning all known modules. The default is the set of
101 maintained modules.
102 Module names may be prefixed with a dash to exclude them from a bigger set.
103
104 =item --no-update
105
106 Skip the `git submodule update' command.
107
108 =item --branch
109
110 Instead of checking out specific SHA1s, check out the submodule branches that
111 correspond with the current supermodule commit.
112 By default, this option will cause local commits in the submodules to be rebased.
113 With --no-update, the branches will be checked out, but their heads will not move.
114
115 =item --ignore-submodules
116
117 Set git config to ignore submodules by default when doing operations on the
118 qt5 repo, such as `pull', `fetch', `diff' etc.
119
120 After using this option, pass `--ignore-submodules=none' to git to override
121 it as needed.
122
123 =back
124
125
126 B<Repository options:>
127
128 =over
129
130 =item --berlin
131
132 Switch to internal URLs and make use of the Berlin git mirrors.
133 (Implies `--mirror').
134
135 =item --oslo
136
137 Switch to internal URLs and make use of the Oslo git mirrors.
138 (Implies `--mirror').
139
140
141 =item --codereview-username <Gerrit/JIRA username>
142
143 Specify the user name for the (potentially) writable `gerrit' remote
144 for each module, for use with the Gerrit code review tool.
145
146 If this option is omitted, the gerrit remote is created without a username
147 and port number, and thus relies on a correct SSH configuration.
148
149
150 =item --alternates <path to other Qt5 repo>
151
152 Adds alternates for each submodule to another full qt5 checkout. This makes
153 this qt5 checkout very small, as it will use the object store of the
154 alternates before unique objects are stored in its own object store.
155
156 This option has no effect when using `--no-update'.
157
158 B<NOTE:> This will make this repo dependent on the alternate, which is
159 potentially dangerous!  The dependency can be broken by also using
160 the `--copy-objects' option, or by running C<git repack -a> in each
161 submodule, where required.  Please read the note about the `--shared' option
162 in the documentation of `git clone' for more information.
163
164
165 =item --copy-objects
166
167 When `--alternates' is used, automatically do a C<git repack -a> in each
168 submodule after cloning, to ensure that the repositories are independent
169 from the source used as a reference for cloning.
170
171 Note that this negates the disk usage benefits gained from the use of
172 `--alternates'.
173
174
175 =item --mirror <url-base>
176
177 Uses <url-base> as the base URL for submodule git mirrors.
178
179 For example:
180
181   --mirror user@machine:/foo/bar/
182
183 ...will use the following as a mirror for qtbase:
184
185   user@machine:/foo/bar/qt/qtbase.git
186
187 The mirror is permitted to contain a subset of the submodules; any
188 missing modules will fall back to the canonical URLs.
189
190 =back
191
192 =cut
193
194 use Carp         qw( confess             );
195 use English      qw( -no_match_vars      );
196 use Getopt::Long qw( GetOptionsFromArray );
197 use Pod::Usage   qw( pod2usage           );
198 use Cwd          qw( getcwd              );
199
200 my $GERRIT_SSH_BASE
201     = 'ssh://@USER@codereview.qt-project.org@PORT@/';
202
203 my $BER_MIRROR_URL_BASE
204     = 'git://hegel/';
205
206 my $OSLO_MIRROR_URL_BASE
207     = 'git://qilin/';
208
209 sub new
210 {
211     my ($class, @arguments) = @_;
212
213     my $self = {};
214     bless $self, $class;
215     $self->parse_arguments(@arguments);
216
217     return $self;
218 }
219
220 # Like `system', but possibly log the command, and die on non-zero exit code
221 sub exe
222 {
223     my ($self, @cmd) = @_;
224
225     if (!$self->{quiet}) {
226         print "+ @cmd\n";
227     }
228
229     if (system(@cmd) != 0) {
230         confess "@cmd exited with status $CHILD_ERROR";
231     }
232
233     return;
234 }
235
236 sub parse_arguments
237 {
238     my ($self, @args) = @_;
239
240     %{$self} = (%{$self},
241         'alternates'          => "",
242         'branch'              => 0,
243         'codereview-username' => "",
244         'detach-alternates'   => 0 ,
245         'force'               => 0 ,
246         'force-hooks'         => 0 ,
247         'ignore-submodules'   => 0 ,
248         'mirror-url'          => "",
249         'update'              => 1 ,
250         'webkit'              => 1 ,
251         'module-subset'       => "default",
252     );
253
254     GetOptionsFromArray(\@args,
255         'alternates=s'      =>  \$self->{qw{ alternates        }},
256         'branch'            =>  \$self->{qw{ branch            }},
257         'codereview-username=s' => \$self->{qw{ codereview-username }},
258         'copy-objects'      =>  \$self->{qw{ detach-alternates }},
259         'force|f'           =>  \$self->{qw{ force             }},
260         'force-hooks'       =>  \$self->{qw{ force-hooks       }},
261         'ignore-submodules' =>  \$self->{qw{ ignore-submodules }},
262         'mirror=s'          =>  \$self->{qw{ mirror-url        }},
263         'quiet'             =>  \$self->{qw{ quiet             }},
264         'update!'           =>  \$self->{qw{ update            }},
265         'webkit!'           =>  \$self->{qw{ webkit            }},
266         'module-subset=s'   =>  \$self->{qw{ module-subset     }},
267
268         'help|?'            =>  sub { pod2usage(1);               },
269
270         'berlin' => sub {
271             $self->{'mirror-url'}        = $BER_MIRROR_URL_BASE;
272         },
273         'oslo' => sub {
274             $self->{'mirror-url'}        = $OSLO_MIRROR_URL_BASE;
275         },
276     ) || pod2usage(2);
277
278     # Replace any double trailing slashes from end of mirror
279     $self->{'mirror-url'} =~ s{//+$}{/};
280
281     $self->{'module-subset'} = [ split(/,/, $self->{'module-subset'}) ];
282     if (!$self->{webkit}) {
283         push @{$self->{'module-subset'}}, "-qtwebkit", "-qtwebkit-examples";
284     }
285
286     return;
287 }
288
289 sub check_if_already_initialized
290 {
291     my ($self) = @_;
292
293     # We consider the repo as `initialized' if submodule.qtbase.url is set
294     if (qx(git config --get submodule.qtbase.url)) {
295         if (!$self->{force}) {
296             exit 0 if ($self->{quiet});
297             print "Will not reinitialize already initialized repository (use -f to force)!\n";
298             exit 1;
299         }
300     }
301
302     return;
303 }
304
305 sub git_submodule_init
306 {
307     my ($self, @init_args) = @_;
308
309     if ($self->{quiet}) {
310         unshift @init_args, '--quiet';
311     }
312     $self->exe('git', 'submodule', 'init', @init_args);
313
314     my $template = getcwd()."/.commit-template";
315     if (-e $template) {
316         $self->exe('git', 'config', 'commit.template', $template);
317     }
318
319     return;
320 }
321
322 sub git_clone_all_submodules
323 {
324     my ($self, $my_repo_base, $co_branch, @subset) = @_;
325
326     my %subdirs = ();
327     my %subbranches = ();
328     my %subbases = ();
329     my %subinits = ();
330     my @submodconfig = qx(git config -l -f .gitmodules);
331     foreach my $line (@submodconfig) {
332         # Example line: submodule.qtqa.url=../qtqa.git
333         next if ($line !~ /^submodule\.([^.=]+)\.([^.=]+)=(.*)$/);
334         if ($2 eq "path") {
335             $subdirs{$1} = $3;
336         } elsif ($2 eq "branch") {
337             $subbranches{$1} = $3;
338         } elsif ($2 eq "url") {
339             my ($mod, $base) = ($1, $3);
340             next if ($base !~ /^\.\.\//);
341             $base = $my_repo_base.'/'.$base;
342             while ($base =~ s,/(?!\.\./)[^/]+/\.\./,/,g) {}
343             $subbases{$mod} = $base;
344         } elsif ($2 eq "update") {
345             push @subset, '-'.$1 if ($3 eq 'ignore');
346         } elsif ($2 eq "initrepo") {
347             $subinits{$1} = ($3 eq "yes" or $3 eq "true");
348         }
349     }
350
351     my %include = ();
352     foreach my $mod (@subset) {
353         if ($mod eq "all") {
354             map { $include{$_} = 1; } keys %subbases;
355         } elsif ($mod eq "default") {
356             map { $include{$_} = 1; } grep { $subinits{$_} } keys %subbases;
357         } elsif ($mod =~ s/^-//) {
358             delete $include{$mod};
359         } else {
360             $include{$mod} = 1;
361         }
362     }
363
364     my @modules = sort keys %include;
365
366     $self->git_submodule_init(map { $subdirs{$_} } @modules);
367
368     # manually clone each repo here, so we can easily use reference repos, mirrors etc
369     my @configresult = qx(git config -l);
370     foreach my $line (@configresult) {
371         # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
372         next if ($line !~ /submodule\.([^.=]+)\.url=/);
373         my $module = $1;
374
375         if (!defined($include{$module})) {
376             $self->exe('git', 'config', '--remove-section', "submodule.$module");
377             next;
378         }
379
380         if ($self->{'ignore-submodules'}) {
381             $self->exe('git', 'config', "submodule.$module.ignore", 'all');
382         }
383     }
384
385     foreach my $module (@modules) {
386         $self->git_clone_one_submodule($subdirs{$module}, $subbases{$module});
387     }
388
389     if ($self->{update}) {
390         $self->exe('git', 'submodule', 'update', ($co_branch ? ('--remote', '--rebase') : ()));
391
392         foreach my $module (@modules) {
393             if (-f $module.'/.gitmodules') {
394                 my $orig_cwd = getcwd();
395                 chdir($module) or confess "chdir $module: $OS_ERROR";
396                 $self->git_clone_all_submodules($subbases{$module}, 0, "all");
397                 chdir("$orig_cwd") or confess "chdir $orig_cwd: $OS_ERROR";
398             }
399         }
400     } elsif ($co_branch) {
401         foreach my $module (@modules) {
402             my $branch = $subbranches{$module};
403             die("No branch defined for submodule $module.\n") if (!defined($branch));
404             my $orig_cwd = getcwd();
405             chdir($module) or confess "chdir $module: $OS_ERROR";
406             my $br = qx(git rev-parse -q --verify $branch);
407             if (!$br) {
408                 $self->exe('git', 'checkout', '-b', $branch, "origin/$branch");
409             } else {
410                 $self->exe('git', 'checkout', $branch);
411             }
412             chdir("$orig_cwd") or confess "chdir $orig_cwd: $OS_ERROR";
413         }
414     }
415
416     return;
417 }
418
419 sub git_add_remotes
420 {
421     my ($self, $gerrit_repo_basename) = @_;
422
423     my $gerrit_repo_url = $GERRIT_SSH_BASE;
424     # If given a username, make a "verbose" remote.
425     # Otherwise, rely on proper SSH configuration.
426     if ($self->{'codereview-username'}) {
427         $gerrit_repo_url =~ s,\@USER\@,$self->{'codereview-username'}\@,;
428         $gerrit_repo_url =~ s,\@PORT\@,:29418,;
429     } else {
430         $gerrit_repo_url =~ s,\@[^\@]+\@,,g;
431     }
432
433     $gerrit_repo_url .= $gerrit_repo_basename;
434     $self->exe('git', 'config', 'remote.gerrit.url', $gerrit_repo_url);
435     $self->exe('git', 'config', 'remote.gerrit.fetch', '+refs/heads/*:refs/remotes/gerrit/*', '/heads/');
436 }
437
438 sub git_clone_one_submodule
439 {
440     my ($self, $submodule, $repo_basename) = @_;
441
442     my $alternates            = $self->{ 'alternates'        };
443     my $mirror_url            = $self->{ 'mirror-url'        };
444     my $protocol              = $self->{ 'protocol'          };
445
446     # `--reference FOO' args for the clone, if any.
447     my @reference_args;
448
449     if ($alternates) {
450         # alternates is a qt5 repo, so the submodule will be under that.
451         if (-e "$alternates/$submodule/.git") {
452             @reference_args = ('--reference', "$alternates/$submodule");
453         }
454         else {
455             print " *** $alternates/$submodule not found, ignoring alternate for this submodule\n";
456         }
457     }
458
459     my $url = $self->{'base-url'}.$repo_basename;
460     my $mirror;
461     if ($mirror_url) {
462         $mirror = $mirror_url.$repo_basename;
463     }
464
465     if ($mirror) {
466         # Only use the mirror if it can be reached.
467         eval { $self->exe('git', 'ls-remote', $mirror, 'test/if/mirror/exists') };
468         if ($@) {
469             warn "mirror [$mirror] is not accessible; $url will be used\n";
470             undef $mirror;
471         }
472     }
473
474     my $do_clone = (! -e "$submodule/.git");
475     if ($do_clone) {
476         $self->exe('git', 'clone', @reference_args, ($mirror ? $mirror : $url), $submodule);
477     }
478
479     my $orig_cwd = getcwd();
480     chdir($submodule) or confess "chdir $submodule: $OS_ERROR";
481
482     $self->exe('git', 'config', 'remote.origin.url', $url);
483     if ($mirror) {
484         $self->exe('git', 'config', 'remote.mirror.url', $mirror);
485         $self->exe('git', 'config', 'remote.mirror.fetch', '+refs/heads/*:refs/remotes/mirror/*');
486     }
487
488     if (!$do_clone && $self->{update}) {
489         $self->exe('git', 'fetch', ($mirror ? $mirror : $url));
490     }
491
492     my $template = getcwd()."/../.commit-template";
493     if (-e $template) {
494         $self->exe('git', 'config', 'commit.template', $template);
495     }
496
497     $self->git_add_remotes($repo_basename);
498
499     if ($self->{'detach-alternates'}) {
500         $self->exe('git', 'repack', '-a');
501
502         my $alternates_path = '.git/objects/info/alternates';
503         if (-e $alternates_path) {
504             unlink($alternates_path) || confess "unlink $alternates_path: $OS_ERROR";
505         }
506     }
507
508     chdir($orig_cwd) or confess "cd $orig_cwd: $OS_ERROR";
509
510     return;
511 }
512
513 sub ensure_link
514 {
515     my ($self, $src, $tgt) = @_;
516     return if (!$self->{'force-hooks'} and -f $tgt);
517     unlink($tgt); # In case we have a dead symlink or pre-existing hook
518     print "Aliasing $src\n      as $tgt ...\n" if (!$self->{quiet});
519     return if eval { symlink($src, $tgt) };
520     # Windows doesn't do (proper) symlinks. As the post_commit script needs
521     # them to locate itself, we write a forwarding script instead.
522     open SCRIPT, ">".$tgt or die "Cannot create forwarding script $tgt: $!\n";
523     print SCRIPT "#!/bin/sh\nexec `dirname \$0`/$src \"\$\@\"\n";
524     close SCRIPT;
525 }
526
527 sub git_install_hooks
528 {
529     my ($self) = @_;
530
531     return if (!-d 'qtrepotools/git-hooks');
532
533     # Force C locale as git submodule returns the localized string "Entering"
534     local $ENV{LC_ALL} = 'C';
535     chomp(my @modules = `git submodule foreach :`);
536     push @modules, "";
537     for my $module (@modules) {
538         $module =~ s,^Entering \'([^\']+)\'$,$1/,;
539         my $rel = $module;
540         $rel =~ s,[^/]+,..,g;
541         $rel .= "../../qtrepotools/git-hooks/";
542         $self->ensure_link($rel.'gerrit_commit_msg_hook', $module.'.git/hooks/commit-msg');
543         $self->ensure_link($rel.'git_post_commit_hook', $module.'.git/hooks/post-commit');
544     }
545 }
546
547 sub run
548 {
549     my ($self) = @_;
550
551     $self->check_if_already_initialized;
552
553     chomp(my $url = `git config remote.origin.url`);
554     die("Have no origin remote.\n") if (!$url);
555     $url =~ s,\.git$,,;
556     $url =~ s,qt/qt5$,,;
557     $self->{'base-url'} = $url;
558
559     $self->git_clone_all_submodules('qt/qt5', $self->{branch}, @{$self->{'module-subset'}});
560
561     $self->git_add_remotes('qt/qt5');
562
563     $self->git_install_hooks;
564
565     return;
566 }
567
568 #==============================================================================
569
570 Qt::InitRepository->new(@ARGV)->run if (!caller);
571 1;