Add ChangeLog template.
[mirror/qt/qt5.git] / init-repository
1 #!/usr/bin/env perl
2 #############################################################################
3 ##
4 ## Copyright (C) 2012 Digia Plc and/or its subsidiary(-ies).
5 ## Contact: http://www.qt-project.org/legal
6 ##
7 ## This file is part of the utilities of the Qt Toolkit.
8 ##
9 ## $QT_BEGIN_LICENSE:LGPL$
10 ## Commercial License Usage
11 ## Licensees holding valid commercial Qt licenses may use this file in
12 ## accordance with the commercial license agreement provided with the
13 ## Software or, alternatively, in accordance with the terms contained in
14 ## a written agreement between you and Digia.  For licensing terms and
15 ## conditions see http://qt.digia.com/licensing.  For further information
16 ## use the contact form at http://qt.digia.com/contact-us.
17 ##
18 ## GNU Lesser General Public License Usage
19 ## Alternatively, this file may be used under the terms of the GNU Lesser
20 ## General Public License version 2.1 as published by the Free Software
21 ## Foundation and appearing in the file LICENSE.LGPL included in the
22 ## packaging of this file.  Please review the following information to
23 ## ensure the GNU Lesser General Public License version 2.1 requirements
24 ## will be met: http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
25 ##
26 ## In addition, as a special exception, Digia gives you certain additional
27 ## rights.  These rights are described in the Digia Qt LGPL Exception
28 ## version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
29 ##
30 ## GNU General Public License Usage
31 ## Alternatively, this file may be used under the terms of the GNU
32 ## General Public License version 3.0 as published by the Free Software
33 ## Foundation and appearing in the file LICENSE.GPL included in the
34 ## packaging of this file.  Please review the following information to
35 ## ensure the GNU General Public License version 3.0 requirements will be
36 ## met: http://www.gnu.org/copyleft/gpl.html.
37 ##
38 ##
39 ## $QT_END_LICENSE$
40 ##
41 #############################################################################
42
43 use v5.8;
44 use strict;
45 use warnings;
46
47 package Qt::InitRepository;
48
49
50 =head1 NAME
51
52 init-repository - initialize the Qt5 repository and all submodules
53
54 =head1 SYNOPSIS
55
56   ./init-repository [options]
57
58 This script may be run after an initial `git clone' of Qt5 in order to check
59 out all submodules.
60
61
62 =head1 OPTIONS
63
64 B<Global options:>
65
66 =over
67
68 =item --force, -f
69
70 Force initialization (even if the submodules are already checked out).
71
72
73 =item --quiet, -q
74
75 Be quiet.  Will exit cleanly if the repository is already initialized.
76
77 =back
78
79
80 B<Module options:>
81
82 =over
83
84 =item --no-webkit
85
86 Skip webkit and webkit examples submodules.
87 It may be desirable to skip these modules due to the large size of the webkit
88 git repository.
89
90 =item --module-subset=<module1>,<module2>...
91
92 Only initialize the specified subset of modules given as the argument. Specified
93 modules must already exist in .gitmodules.
94 The string "all" results in cloning all known modules. The default is the set of
95 maintained modules.
96
97 =item --no-update
98
99 Skip the `git submodule update' command.
100
101
102 =item --ignore-submodules
103
104 Set git config to ignore submodules by default when doing operations on the
105 qt5 repo, such as `pull', `fetch', `diff' etc.
106
107 After using this option, pass `--ignore-submodules=none' to git to override
108 it as needed.
109
110 =back
111
112
113 B<Repository options:>
114
115 =over
116
117 =item --berlin
118
119 Switch to internal URLs and make use of the Berlin git mirrors.
120 (Implies `--mirror').
121
122 =item --oslo
123
124 Switch to internal URLs and make use of the Oslo git mirrors.
125 (Implies `--mirror').
126
127
128 =item --http
129
130 Use the HTTP protocol for git operations.  This may be useful if the git
131 protocol is blocked by a firewall.  Note that this only works with the
132 external Gitorious server.
133
134 The `--http' option does not affect the gerrit remotes.
135
136
137 =item --codereview-username <Gerrit/JIRA username>
138
139 Specify the user name for the (potentially) writable `gerrit' remote
140 for each module, for use with the Gerrit code review tool.
141
142 If this option is omitted, the gerrit remote is created without a username
143 and port number, and thus relies on a correct SSH configuration.
144
145
146 =item --alternates <path to other Qt5 repo>
147
148 Adds alternates for each submodule to another full qt5 checkout. This makes
149 this qt5 checkout very small, as it will use the object store of the
150 alternates before unique objects are stored in its own object store.
151
152 This option has no effect when using `--no-update'.
153
154 B<NOTE:> This will make this repo dependent on the alternate, which is
155 potentially dangerous!  The dependency can be broken by also using
156 the `--copy-objects' option, or by running C<git repack -a> in each
157 submodule, where required.  Please read the note about the `--shared' option
158 in the documentation of `git clone' for more information.
159
160
161 =item --copy-objects
162
163 When `--alternates' is used, automatically do a C<git repack -a> in each
164 submodule after cloning, to ensure that the repositories are independent
165 from the source used as a reference for cloning.
166
167 Note that this negates the disk usage benefits gained from the use of
168 `--alternates'.
169
170
171 =item --mirror <url-base>
172
173 Uses <url-base> as the base URL for submodule git mirrors.
174
175 For example:
176
177   --mirror user@machine:/foo/bar
178
179 ...will use the following as a mirror for qtbase:
180
181   user@machine:/foo/bar/qt/qtbase.git
182
183 The mirror is permitted to contain a subset of the submodules; any
184 missing modules will fall back to the canonical URLs.
185
186 =back
187
188 =cut
189
190 use Carp         qw( confess             );
191 use English      qw( -no_match_vars      );
192 use Getopt::Long qw( GetOptionsFromArray );
193 use Pod::Usage   qw( pod2usage           );
194 use Cwd          qw( getcwd              );
195
196 my %PROTOCOLS = (
197     'http'      => 'http://git.gitorious.org/'     ,
198 );
199
200 my %GERRIT_REPOS = map { $_ => "qt/$_" } qw(
201     qt3d
202     qt5
203     qlalr
204     qtactiveqt
205     qtbase
206     qtconnectivity
207     qtdeclarative
208     qtdoc
209     qtdocgallery
210     qtfeedback
211     qtgraphicaleffects
212     qtimageformats
213     qtjsondb
214     qtjsbackend
215     qtlocation
216     qtmacextras
217     qtmultimedia
218     qtpim
219     qtqa
220     qtquick1
221     qtquickcontrols
222     qtrepotools
223     qtscript
224     qtsensors
225     qtserialport
226     qtsvg
227     qtsystems
228     qttools
229     qttranslations
230     qtwayland
231     qtwebkit
232     qtwebkit-examples
233     qtwinextras
234     qtx11extras
235     qtxmlpatterns
236 );
237
238 my @DEFAULT_REPOS = qw(
239     qtactiveqt
240     qtbase
241     qtdeclarative
242     qtdoc
243     qtgraphicaleffects
244     qtimageformats
245     qtjsbackend
246     qtmultimedia
247     qtqa
248     qtquick1
249     qtquickcontrols
250     qtrepotools
251     qtscript
252     qtsensors
253     qtserialport
254     qtsvg
255     qttools
256     qttranslations
257     qtwebkit
258     qtwebkit-examples
259     qtx11extras
260     qtxmlpatterns
261 );
262
263 my $GERRIT_SSH_BASE
264     = 'ssh://@USER@codereview.qt-project.org@PORT@/';
265
266 my $BER_MIRROR_URL_BASE
267     = 'git://hegel/';
268
269 my $OSLO_MIRROR_URL_BASE
270     = 'git://qilin/';
271
272 sub new
273 {
274     my ($class, @arguments) = @_;
275
276     my $self = {};
277     bless $self, $class;
278     $self->parse_arguments(@arguments);
279
280     return $self;
281 }
282
283 # Like `system', but possibly log the command, and die on non-zero exit code
284 sub exe
285 {
286     my ($self, @cmd) = @_;
287
288     if (!$self->{quiet}) {
289         print "+ @cmd\n";
290     }
291
292     if (system(@cmd) != 0) {
293         confess "@cmd exited with status $CHILD_ERROR";
294     }
295
296     return;
297 }
298
299 sub parse_arguments
300 {
301     my ($self, @args) = @_;
302
303     %{$self} = (%{$self},
304         'alternates'          => "",
305         'codereview-username' => "",
306         'detach-alternates'   => 0 ,
307         'force'               => 0 ,
308         'ignore-submodules'   => 0 ,
309         'mirror-url'          => "",
310         'protocol'            => "",
311         'update'              => 1 ,
312         'webkit'              => 1 ,
313         'module-subset'       => join(",", @DEFAULT_REPOS),
314     );
315
316     GetOptionsFromArray(\@args,
317         'alternates=s'      =>  \$self->{qw{ alternates        }},
318         'codereview-username=s' => \$self->{qw{ codereview-username }},
319         'copy-objects'      =>  \$self->{qw{ detach-alternates }},
320         'force'             =>  \$self->{qw{ force             }},
321         'ignore-submodules' =>  \$self->{qw{ ignore-submodules }},
322         'mirror=s'          =>  \$self->{qw{ mirror-url        }},
323         'quiet'             =>  \$self->{qw{ quiet             }},
324         'update!'           =>  \$self->{qw{ update            }},
325         'webkit!'           =>  \$self->{qw{ webkit            }},
326         'module-subset=s'   =>  \$self->{qw{ module-subset     }},
327
328         'help|?'            =>  sub { pod2usage(1);               },
329         'http'              =>  sub { $self->{protocol} = 'http'; },
330
331         'berlin' => sub {
332             $self->{'mirror-url'}        = $BER_MIRROR_URL_BASE;
333         },
334         'oslo' => sub {
335             $self->{'mirror-url'}        = $OSLO_MIRROR_URL_BASE;
336         },
337     ) || pod2usage(2);
338
339     # Replace any double trailing slashes from end of mirror
340     $self->{'mirror-url'} =~ s{//+$}{/};
341
342     if ($self->{'module-subset'} eq "all") {
343         $self->{'module-subset'} = "";
344     } else {
345         $self->{'module-subset'} = {
346             map { $_ => 1 } split(qr{,}, $self->{'module-subset'})
347         };
348     }
349
350     return;
351 }
352
353 sub check_if_already_initialized
354 {
355     my ($self) = @_;
356
357     # We consider the repo as `initialized' if submodule.qtbase.url is set
358     if (qx(git config --get submodule.qtbase.url)) {
359         if ($self->{force}) {
360             my @configresult = qx(git config -l);
361             foreach (@configresult) {
362                 # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
363                 if (/(submodule\.[^.=]+)\.url=.*/) {
364                     $self->exe('git', 'config', '--remove-section', $1);
365                 }
366             }
367         }
368         else {
369             exit 0 if ($self->{quiet});
370             print "Will not reinitialize already initialized repository (use -f to force)!\n";
371             exit 1;
372         }
373     }
374
375     return;
376 }
377
378 sub git_submodule_init
379 {
380     my ($self) = @_;
381
382     my @init_args;
383     if ($self->{quiet}) {
384         push @init_args, '--quiet';
385     }
386     $self->exe('git', 'submodule', 'init', @init_args);
387
388     my $template = getcwd()."/.commit-template";
389     if (-e $template) {
390         $self->exe('git', 'config', 'commit.template', $template);
391     }
392
393     return;
394 }
395
396 sub git_disable_webkit_submodule
397 {
398     my ($self) = @_;
399
400     $self->exe('git', 'config', '--remove', 'submodule.qtwebkit');
401     $self->exe('git', 'config', '--remove', 'submodule.qtwebkit-examples');
402
403     return;
404 }
405
406 sub git_prune_submodules
407 {
408     my ($self) = @_;
409
410     my @configresult = qx(git config -l);
411     foreach my $line (@configresult) {
412         if ($line =~ /submodule\.([^.=]+)\.url=/) {
413             my $module_name = $1;
414             if (!$self->{'module-subset'}{$module_name}) {
415                 $self->exe('git', 'config', '--remove', "submodule.$module_name");
416             }
417         }
418     }
419 }
420
421 sub git_set_submodule_config
422 {
423     my ($self) = @_;
424
425     my @configresult          = qx(git config -l);
426     my $protocol              = $self->{protocol};
427     my $url_base_for_protocol = $PROTOCOLS{$protocol};
428
429     foreach my $line (@configresult) {
430         # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
431         next if ($line !~ /submodule\.([^.=]+)\.url=(.*)/);
432
433         my $key   = $1;
434         my $value = $2;
435
436         if ($protocol) {
437                 # rewrite URL to chosen protocol
438                 $value =~ s,^git://gitorious\.org/,$url_base_for_protocol,;
439         }
440
441         $self->exe('git', 'config', "submodule.$key.url", $value);
442
443         if ($self->{'ignore-submodules'}) {
444             $self->exe('git', 'config', "submodule.$key.ignore", 'all');
445         }
446     }
447
448     return;
449 }
450
451 sub git_clone_all_submodules
452 {
453     my ($self) = @_;
454
455     # manually clone each repo here, so we can easily use reference repos, mirrors etc
456     my @configresult = qx(git config -l);
457     foreach my $line (@configresult) {
458         if ($line =~ /submodule\.([^.=]+)\.url=(.*)/) {
459             $self->git_clone_one_submodule($1, $2);
460         }
461     }
462
463     if ($self->{update}) {
464         $self->exe('git', 'submodule', 'update', '--recursive');
465     }
466
467     return;
468 }
469
470 sub git_add_remotes
471 {
472     my ($self, $repo_basename) = @_;
473
474     my $gerrit_repo_basename = $GERRIT_REPOS{$repo_basename};
475     if ($gerrit_repo_basename) {
476         my $gerrit_repo_url;
477
478         # If given a username, make a "verbose" remote.
479         # Otherwise, rely on proper SSH configuration.
480         if ($self->{'codereview-username'}) {
481             $gerrit_repo_url = $GERRIT_SSH_BASE;
482             $gerrit_repo_url =~ s,\@USER\@,$self->{'codereview-username'}\@,;
483             $gerrit_repo_url =~ s,\@PORT\@,:29418,;
484         }
485         else {
486             $gerrit_repo_url = $GERRIT_SSH_BASE;
487             $gerrit_repo_url =~ s,\@[^\@]+\@,,g;
488         }
489
490         $gerrit_repo_url .= $gerrit_repo_basename;
491         $self->exe('git', 'config', 'remote.gerrit.url', $gerrit_repo_url);
492         $self->exe('git', 'config', 'remote.gerrit.fetch', '+refs/heads/*:refs/remotes/gerrit/*', '/heads/');
493     }
494
495     return;
496 }
497
498 sub git_clone_one_submodule
499 {
500     my ($self, $submodule, $url) = @_;
501
502     my $alternates            = $self->{ 'alternates'        };
503     my $mirror_url            = $self->{ 'mirror-url'        };
504     my $protocol              = $self->{ 'protocol'          };
505
506     # `--reference FOO' args for the clone, if any.
507     my @reference_args;
508
509     if ($alternates) {
510         # alternates is a qt5 repo, so the submodule will be under that.
511         if (-d "$alternates/$submodule") {
512             @reference_args = ('--reference', "$alternates/$submodule");
513         }
514         else {
515             print " *** $alternates/$submodule not found, ignoring alternate for this submodule\n";
516         }
517     }
518
519     my $mirror;
520     if ($mirror_url) {
521         $mirror = $mirror_url."qt/$submodule";
522         $mirror .= ".git" unless (-d $mirror); # Support local disk mirror
523     }
524
525     if ($mirror) {
526         # Only use the mirror if it can be reached.
527         eval { $self->exe('git', 'ls-remote', $mirror, 'test/if/mirror/exists') };
528         if ($@) {
529             warn "mirror [$mirror] is not accessible; $url will be used\n";
530             undef $mirror;
531         }
532     }
533
534     my $do_clone = (! -d "$submodule/.git");
535     if ($do_clone) {
536         $self->exe('git', 'clone', @reference_args, ($mirror ? $mirror : $url), $submodule);
537     }
538
539     chdir($submodule) or confess "chdir $submodule: $OS_ERROR";
540
541     $self->exe('git', 'config', 'remote.origin.url', $url);
542     if ($mirror) {
543         $self->exe('git', 'config', 'remote.mirror.url', $mirror);
544         $self->exe('git', 'config', 'remote.mirror.fetch', '+refs/heads/*:refs/remotes/mirror/*');
545     }
546
547     if (!$do_clone) {
548         $self->exe('git', 'fetch', ($mirror ? $mirror : $url));
549     }
550
551     my $template = getcwd()."/../.commit-template";
552     if (-e $template) {
553         $self->exe('git', 'config', 'commit.template', $template);
554     }
555
556     $self->git_add_remotes($submodule);
557
558     if ($self->{'detach-alternates'}) {
559         $self->exe('git', 'repack', '-a');
560
561         my $alternates_path = '.git/objects/info/alternates';
562         if (-e $alternates_path) {
563             unlink($alternates_path) || confess "unlink $alternates_path: $OS_ERROR";
564         }
565     }
566
567     chdir("..") or confess "cd ..: $OS_ERROR";
568
569     return;
570 }
571
572 sub run
573 {
574     my ($self) = @_;
575
576     $self->check_if_already_initialized;
577     $self->git_submodule_init;
578
579     if (!$self->{webkit}) {
580         $self->git_disable_webkit_submodule;
581     }
582
583     if ($self->{'module-subset'}) {
584         $self->git_prune_submodules;
585     }
586
587     $self->git_set_submodule_config;
588
589     $self->git_clone_all_submodules;
590
591     $self->git_add_remotes('qt5');
592
593     return;
594 }
595
596 #==============================================================================
597
598 Qt::InitRepository->new(@ARGV)->run if (!caller);
599 1;