a89abbffc973b5bc04d7e12cf63855392626372b
[mirror/qt/qt5.git] / init-repository
1 #!/usr/bin/env perl
2 #############################################################################
3 ##
4 ## Copyright (C) 2012 Digia Plc and/or its subsidiary(-ies).
5 ## Contact: http://www.qt-project.org/legal
6 ##
7 ## This file is part of the utilities of the Qt Toolkit.
8 ##
9 ## $QT_BEGIN_LICENSE:LGPL$
10 ## Commercial License Usage
11 ## Licensees holding valid commercial Qt licenses may use this file in
12 ## accordance with the commercial license agreement provided with the
13 ## Software or, alternatively, in accordance with the terms contained in
14 ## a written agreement between you and Digia.  For licensing terms and
15 ## conditions see http://qt.digia.com/licensing.  For further information
16 ## use the contact form at http://qt.digia.com/contact-us.
17 ##
18 ## GNU Lesser General Public License Usage
19 ## Alternatively, this file may be used under the terms of the GNU Lesser
20 ## General Public License version 2.1 as published by the Free Software
21 ## Foundation and appearing in the file LICENSE.LGPL included in the
22 ## packaging of this file.  Please review the following information to
23 ## ensure the GNU Lesser General Public License version 2.1 requirements
24 ## will be met: http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
25 ##
26 ## In addition, as a special exception, Digia gives you certain additional
27 ## rights.  These rights are described in the Digia Qt LGPL Exception
28 ## version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
29 ##
30 ## GNU General Public License Usage
31 ## Alternatively, this file may be used under the terms of the GNU
32 ## General Public License version 3.0 as published by the Free Software
33 ## Foundation and appearing in the file LICENSE.GPL included in the
34 ## packaging of this file.  Please review the following information to
35 ## ensure the GNU General Public License version 3.0 requirements will be
36 ## met: http://www.gnu.org/copyleft/gpl.html.
37 ##
38 ##
39 ## $QT_END_LICENSE$
40 ##
41 #############################################################################
42
43 use v5.8;
44 use strict;
45 use warnings;
46
47 package Qt::InitRepository;
48
49
50 =head1 NAME
51
52 init-repository - initialize the Qt5 repository and all submodules
53
54 =head1 SYNOPSIS
55
56   ./init-repository [options]
57
58 This script may be run after an initial `git clone' of Qt5 in order to check
59 out all submodules.
60
61
62 =head1 OPTIONS
63
64 B<Global options:>
65
66 =over
67
68 =item --force, -f
69
70 Force initialization (even if the submodules are already checked out).
71
72
73 =item --quiet, -q
74
75 Be quiet.  Will exit cleanly if the repository is already initialized.
76
77 =back
78
79
80 B<Module options:>
81
82 =over
83
84 =item --no-webkit
85
86 Skip webkit and webkit examples submodules.
87 It may be desirable to skip these modules due to the large size of the webkit
88 git repository.
89
90 =item --module-subset=<module1>,<module2>...
91
92 Only initialize the specified subset of modules given as the argument. Specified
93 modules must already exist in .gitmodules.
94 The string "all" results in cloning all known modules. The default is the set of
95 maintained modules.
96
97 =item --no-update
98
99 Skip the `git submodule update' command.
100
101
102 =item --ignore-submodules
103
104 Set git config to ignore submodules by default when doing operations on the
105 qt5 repo, such as `pull', `fetch', `diff' etc.
106
107 This option is default for --nokia-developer.
108
109 After using this option, pass `--ignore-submodules=none' to git to override
110 it as needed.
111
112 =back
113
114
115 B<Repository options:>
116
117 =over
118
119 =item --nokia-developer
120
121 Switch to internal Nokia URLs.
122
123
124 =item --berlin
125
126 Switch to internal Nokia URLs and make use of the Berlin git mirrors.
127 (Implies `--mirror').
128
129
130 =item --ssh
131
132 Use the SSH protocol for git operations.  This may be useful if the git
133 protocol is blocked by a firewall. Note that this requires a user account
134 with an uploaded SSH key on all servers used.  (Implies `--nokia-developer').
135
136 The `--ssh' option does not affect the gerrit remotes.
137
138
139 =item --http
140
141 Use the HTTP protocol for git operations.  This may be useful if the git
142 protocol is blocked by a firewall.  Note that this only works with the
143 external Gitorious server.
144
145 The `--http' option does not affect the gerrit remotes.
146
147
148 =item --codereview-username <Gerrit/JIRA username>
149
150 Specify the user name for the (potentially) writable `gerrit' remote
151 for each module, for use with the Gerrit code review tool.
152
153 If this option is omitted, the gerrit remote is created without a username
154 and port number, and thus relies on a correct SSH configuration.
155
156
157 =item --alternates <path to other Qt5 repo>
158
159 Adds alternates for each submodule to another full qt5 checkout. This makes
160 this qt5 checkout very small, as it will use the object store of the
161 alternates before unique objects are stored in its own object store.
162
163 This option has no effect when using `--no-update'.
164
165 B<NOTE:> This will make this repo dependent on the alternate, which is
166 potentially dangerous!  The dependency can be broken by also using
167 the `--copy-objects' option, or by running C<git repack -a> in each
168 submodule, where required.  Please read the note about the `--shared' option
169 in the documentation of `git clone' for more information.
170
171
172 =item --copy-objects
173
174 When `--alternates' is used, automatically do a C<git repack -a> in each
175 submodule after cloning, to ensure that the repositories are independent
176 from the source used as a reference for cloning.
177
178 Note that this negates the disk usage benefits gained from the use of
179 `--alternates'.
180
181
182 =item --mirror <url-base>
183
184 Uses <url-base> as the base URL for submodule git mirrors.
185
186 For example:
187
188   --mirror user@machine:/foo/bar
189
190 ...will use the following as a mirror for qtbase:
191
192   user@machine:/foo/bar/qt/qtbase.git
193
194 The mirror is permitted to contain a subset of the submodules; any
195 missing modules will fall back to the canonical URLs.
196
197 =back
198
199 =cut
200
201 use Carp         qw( confess             );
202 use English      qw( -no_match_vars      );
203 use Getopt::Long qw( GetOptionsFromArray );
204 use Pod::Usage   qw( pod2usage           );
205 use Cwd          qw( getcwd              );
206
207 my %PROTOCOLS = (
208     'internal'  => 'git://scm.dev.nokia.troll.no/' ,
209     'ssh'       => 'git@scm.dev.nokia.troll.no:'   ,
210     'http'      => 'http://git.gitorious.org/'     ,
211 );
212
213 my %GERRIT_REPOS = map { $_ => "qt/$_" } qw(
214     qt3d
215     qt5
216     qlalr
217     qtactiveqt
218     qtbase
219     qtconnectivity
220     qtdeclarative
221     qtdoc
222     qtdocgallery
223     qtfeedback
224     qtgraphicaleffects
225     qtimageformats
226     qtjsondb
227     qtjsbackend
228     qtlocation
229     qtmultimedia
230     qtpim
231     qtqa
232     qtquick1
233     qtrepotools
234     qtscript
235     qtsensors
236     qtsvg
237     qtsystems
238     qttools
239     qttranslations
240     qtwayland
241     qtwebkit
242     qtwebkit-examples-and-demos
243     qtxmlpatterns
244 );
245
246 my @DEFAULT_REPOS = qw(
247     qtactiveqt
248     qtbase
249     qtdeclarative
250     qtdoc
251     qtgraphicaleffects
252     qtimageformats
253     qtjsbackend
254     qtmultimedia
255     qtqa
256     qtquick1
257     qtrepotools
258     qtscript
259     qtsvg
260     qttools
261     qttranslations
262     qtwebkit
263     qtwebkit-examples-and-demos
264     qtxmlpatterns
265 );
266
267 my $GERRIT_SSH_BASE
268     = 'ssh://@USER@codereview.qt-project.org@PORT@/';
269
270 my $BER_MIRROR_URL_BASE
271     = 'git://ber-git.europe.nokia.com/';
272
273 sub new
274 {
275     my ($class, @arguments) = @_;
276
277     my $self = {};
278     bless $self, $class;
279     $self->parse_arguments(@arguments);
280
281     return $self;
282 }
283
284 # Like `system', but possibly log the command, and die on non-zero exit code
285 sub exe
286 {
287     my ($self, @cmd) = @_;
288
289     if (!$self->{quiet}) {
290         print "+ @cmd\n";
291     }
292
293     if (system(@cmd) != 0) {
294         confess "@cmd exited with status $CHILD_ERROR";
295     }
296
297     return;
298 }
299
300 sub parse_arguments
301 {
302     my ($self, @args) = @_;
303
304     %{$self} = (%{$self},
305         'alternates'          => "",
306         'codereview-username' => "",
307         'detach-alternates'   => 0 ,
308         'force'               => 0 ,
309         'ignore-submodules'   => 0 ,
310         'mirror-url'          => "",
311         'nokia-developer'     => 0 ,
312         'protocol'            => "",
313         'update'              => 1 ,
314         'webkit'              => 1 ,
315         'module-subset'       => join(",", @DEFAULT_REPOS),
316     );
317
318     GetOptionsFromArray(\@args,
319         'alternates=s'      =>  \$self->{qw{ alternates        }},
320         'codereview-username=s' => \$self->{qw{ codereview-username }},
321         'copy-objects'      =>  \$self->{qw{ detach-alternates }},
322         'force'             =>  \$self->{qw{ force             }},
323         'ignore-submodules' =>  \$self->{qw{ ignore-submodules }},
324         'mirror=s'          =>  \$self->{qw{ mirror-url        }},
325         'nokia-developer'   =>  \$self->{qw{ nokia-developer   }},
326         'quiet'             =>  \$self->{qw{ quiet             }},
327         'update!'           =>  \$self->{qw{ update            }},
328         'webkit!'           =>  \$self->{qw{ webkit            }},
329         'module-subset=s'   =>  \$self->{qw{ module-subset     }},
330
331         'help|?'            =>  sub { pod2usage(1);               },
332         'http'              =>  sub { $self->{protocol} = 'http'; },
333         'ssh|ssh-protocol'  =>  sub { $self->{protocol} = 'ssh';  },
334
335         'berlin|berlin-nokia-developer' => sub {
336             $self->{'nokia-developer'}   = 1;
337             $self->{'protocol'}          = 'internal';
338             $self->{'mirror-url'}        = $BER_MIRROR_URL_BASE;
339         },
340
341         'nokia-developer' => sub {
342             $self->{'nokia-developer'}   = 1;
343             $self->{'protocol'}          = 'internal';
344             $self->{'ignore-submodules'} = 1;
345         },
346     ) || pod2usage(2);
347
348     if ($self->{'nokia-developer'} && $self->{'protocol'} eq 'http') {
349         print "*** Ignoring use of HTTP protocol, as it's only usable with external server\n";
350         $self->{'protocol'} = '';
351     }
352
353     # Replace any double trailing slashes from end of mirror
354     $self->{'mirror-url'} =~ s{//+$}{/};
355
356     if ($self->{'module-subset'} eq "all") {
357         $self->{'module-subset'} = "";
358     } else {
359         $self->{'module-subset'} = {
360             map { $_ => 1 } split(qr{,}, $self->{'module-subset'})
361         };
362     }
363
364     return;
365 }
366
367 sub check_if_already_initialized
368 {
369     my ($self) = @_;
370
371     # We consider the repo as `initialized' if submodule.qtbase.url is set
372     if (qx(git config --get submodule.qtbase.url)) {
373         if ($self->{force}) {
374             my @configresult = qx(git config -l);
375             foreach (@configresult) {
376                 # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
377                 if (/(submodule\.[^.=]+)\.url=.*/) {
378                     $self->exe('git', 'config', '--remove-section', $1);
379                 }
380             }
381         }
382         else {
383             exit 0 if ($self->{quiet});
384             print "Will not reinitialize already initialized repository (use -f to force)!\n";
385             exit 1;
386         }
387     }
388
389     return;
390 }
391
392 sub git_submodule_init
393 {
394     my ($self) = @_;
395
396     my @init_args;
397     if ($self->{quiet}) {
398         push @init_args, '--quiet';
399     }
400     $self->exe('git', 'submodule', 'init', @init_args);
401
402     my $template = getcwd()."/.commit-template";
403     if (-e $template) {
404         $self->exe('git', 'config', 'commit.template', $template);
405     }
406
407     return;
408 }
409
410 sub git_disable_webkit_submodule
411 {
412     my ($self) = @_;
413
414     $self->exe('git', 'config', '--remove', 'submodule.qtwebkit');
415     $self->exe('git', 'config', '--remove', 'submodule.qtwebkit-examples-and-demos');
416
417     return;
418 }
419
420 sub git_prune_submodules
421 {
422     my ($self) = @_;
423
424     my @configresult = qx(git config -l);
425     foreach my $line (@configresult) {
426         if ($line =~ /submodule\.([^.=]+)\.url=/) {
427             my $module_name = $1;
428             if (!$self->{'module-subset'}{$module_name}) {
429                 $self->exe('git', 'config', '--remove', "submodule.$module_name");
430             }
431         }
432     }
433 }
434
435 sub git_set_submodule_config
436 {
437     my ($self) = @_;
438
439     my @configresult          = qx(git config -l);
440     my $protocol              = $self->{protocol};
441     my $url_base_for_protocol = $PROTOCOLS{$protocol};
442
443     foreach my $line (@configresult) {
444         # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
445         next if ($line !~ /submodule\.([^.=]+)\.url=(.*)/);
446
447         my $key   = $1;
448         my $value = $2;
449
450         if ($protocol) {
451                 # qt-labs projects are still hosted under qt internally.
452                 if ($protocol ne 'http') {
453                     $value =~ s,^git://gitorious\.org/qt-labs/,${url_base_for_protocol}qt/,;
454                 }
455
456                 # assume all other projects hosted under gitorious publicly.
457                 $value =~ s,^git://gitorious\.org/,$url_base_for_protocol,;
458         }
459
460         $self->exe('git', 'config', "submodule.$key.url", $value);
461
462         if ($self->{'ignore-submodules'}) {
463             $self->exe('git', 'config', "submodule.$key.ignore", 'all');
464         }
465     }
466
467     return;
468 }
469
470 sub git_clone_all_submodules
471 {
472     my ($self) = @_;
473
474     # manually clone each repo here, so we can easily use reference repos, mirrors etc
475     my @configresult = qx(git config -l);
476     foreach my $line (@configresult) {
477         if ($line =~ /submodule\.([^.=]+)\.url=(.*)/) {
478             $self->git_clone_one_submodule($1, $2);
479         }
480     }
481
482     if ($self->{update}) {
483         $self->exe('git', 'submodule', 'update', '--recursive');
484     }
485
486     return;
487 }
488
489 sub git_add_remotes
490 {
491     my ($self, $repo_basename) = @_;
492
493     my $gerrit_repo_basename = $GERRIT_REPOS{$repo_basename};
494     if ($gerrit_repo_basename) {
495         my $gerrit_repo_url;
496
497         # If given a username, make a "verbose" remote.
498         # Otherwise, rely on proper SSH configuration.
499         if ($self->{'codereview-username'}) {
500             $gerrit_repo_url = $GERRIT_SSH_BASE;
501             $gerrit_repo_url =~ s,\@USER\@,$self->{'codereview-username'}\@,;
502             $gerrit_repo_url =~ s,\@PORT\@,:29418,;
503         }
504         else {
505             $gerrit_repo_url = $GERRIT_SSH_BASE;
506             $gerrit_repo_url =~ s,\@[^\@]+\@,,g;
507         }
508
509         $gerrit_repo_url .= $gerrit_repo_basename;
510         $self->exe('git', 'config', 'remote.gerrit.url', $gerrit_repo_url);
511         $self->exe('git', 'config', 'remote.gerrit.fetch', '+refs/heads/*:refs/remotes/gerrit/*', '/heads/');
512     }
513
514     return;
515 }
516
517 sub git_clone_one_submodule
518 {
519     my ($self, $submodule, $url) = @_;
520
521     my $alternates            = $self->{ 'alternates'        };
522     my $mirror_url            = $self->{ 'mirror-url'        };
523     my $protocol              = $self->{ 'protocol'          };
524
525     # `--reference FOO' args for the clone, if any.
526     my @reference_args;
527
528     if ($alternates) {
529         # alternates is a qt5 repo, so the submodule will be under that.
530         if (-d "$alternates/$submodule") {
531             @reference_args = ('--reference', "$alternates/$submodule");
532         }
533         else {
534             print " *** $alternates/$submodule not found, ignoring alternate for this submodule\n";
535         }
536     }
537
538     my $mirror;
539     if ($mirror_url) {
540         $mirror = $mirror_url."qt/$submodule";
541         $mirror .= ".git" unless (-d $mirror); # Support local disk mirror
542     }
543
544     if ($mirror) {
545         # Only use the mirror if it can be reached.
546         eval { $self->exe('git', 'ls-remote', $mirror, 'test/if/mirror/exists') };
547         if ($@) {
548             warn "mirror [$mirror] is not accessible; $url will be used\n";
549             undef $mirror;
550         }
551     }
552
553     my $do_clone = (! -d "$submodule/.git");
554     if ($do_clone) {
555         $self->exe('git', 'clone', @reference_args, ($mirror ? $mirror : $url), $submodule);
556     }
557
558     chdir($submodule) or confess "chdir $submodule: $OS_ERROR";
559
560     $self->exe('git', 'config', 'remote.origin.url', $url);
561     if ($mirror) {
562         $self->exe('git', 'config', 'remote.mirror.url', $mirror);
563         $self->exe('git', 'config', 'remote.mirror.fetch', '+refs/heads/*:refs/remotes/mirror/*');
564     }
565
566     if (!$do_clone) {
567         $self->exe('git', 'fetch', ($mirror ? $mirror : $url));
568     }
569
570     my $template = getcwd()."/../.commit-template";
571     if (-e $template) {
572         $self->exe('git', 'config', 'commit.template', $template);
573     }
574
575     $self->git_add_remotes($submodule);
576
577     if ($self->{'detach-alternates'}) {
578         $self->exe('git', 'repack', '-a');
579
580         my $alternates_path = '.git/objects/info/alternates';
581         if (-e $alternates_path) {
582             unlink($alternates_path) || confess "unlink $alternates_path: $OS_ERROR";
583         }
584     }
585
586     chdir("..") or confess "cd ..: $OS_ERROR";
587
588     return;
589 }
590
591 sub run
592 {
593     my ($self) = @_;
594
595     $self->check_if_already_initialized;
596     $self->git_submodule_init;
597
598     if (!$self->{webkit}) {
599         $self->git_disable_webkit_submodule;
600     }
601
602     if ($self->{'module-subset'}) {
603         $self->git_prune_submodules;
604     }
605
606     $self->git_set_submodule_config;
607
608     $self->git_clone_all_submodules;
609
610     $self->git_add_remotes('qt5');
611
612     return;
613 }
614
615 #==============================================================================
616
617 Qt::InitRepository->new(@ARGV)->run if (!caller);
618 1;