Add the QtQuick1 module.
[mirror/qt/qt5.git] / init-repository
1 #!/usr/bin/env perl
2 #############################################################################
3 ##
4 ## Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
5 ## Contact: http://www.qt-project.org/
6 ##
7 ## This file is part of the utilities of the Qt Toolkit.
8 ##
9 ## $QT_BEGIN_LICENSE:LGPL$
10 ## GNU Lesser General Public License Usage
11 ## This file may be used under the terms of the GNU Lesser General Public
12 ## License version 2.1 as published by the Free Software Foundation and
13 ## appearing in the file LICENSE.LGPL included in the packaging of this
14 ## file. Please review the following information to ensure the GNU Lesser
15 ## General Public License version 2.1 requirements will be met:
16 ## http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
17 ##
18 ## In addition, as a special exception, Nokia gives you certain additional
19 ## rights. These rights are described in the Nokia Qt LGPL Exception
20 ## version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
21 ##
22 ## GNU General Public License Usage
23 ## Alternatively, this file may be used under the terms of the GNU General
24 ## Public License version 3.0 as published by the Free Software Foundation
25 ## and appearing in the file LICENSE.GPL included in the packaging of this
26 ## file. Please review the following information to ensure the GNU General
27 ## Public License version 3.0 requirements will be met:
28 ## http://www.gnu.org/copyleft/gpl.html.
29 ##
30 ## Other Usage
31 ## Alternatively, this file may be used in accordance with the terms and
32 ## conditions contained in a signed written agreement between you and Nokia.
33 ##
34 ##
35 ##
36 ##
37 ##
38 ##
39 ## $QT_END_LICENSE$
40 ##
41 #############################################################################
42
43 use v5.10;
44 use strict;
45 use warnings;
46
47 package Qt::InitRepository;
48
49
50 =head1 NAME
51
52 init-repository - initialize the Qt5 repository and all submodules
53
54 =head1 SYNOPSIS
55
56   ./init-repository [options]
57
58 This script may be run after an initial `git clone' of Qt5 in order to check
59 out all submodules.
60
61
62 =head1 OPTIONS
63
64 B<Global options:>
65
66 =over
67
68 =item --force, -f
69
70 Force initialization (even if the submodules are already checked out).
71
72
73 =item --quiet, -q
74
75 Be quiet.  Will exit cleanly if the repository is already initialized.
76
77 =back
78
79
80 B<Module options:>
81
82 =over
83
84 =item --no-webkit
85
86 Skip webkit and webkit examples submodules.
87 It may be desirable to skip these modules due to the large size of the webkit
88 git repository.
89
90 =item --module-subset=<module1>,<module2>...
91
92 Only initialize the specified subset of modules given as the argument. Specified
93 modules must already exist in .gitmodules.
94
95 =item --no-update
96
97 Skip the `git submodule update' command.
98
99
100 =item --ignore-submodules
101
102 Set git config to ignore submodules by default when doing operations on the
103 qt5 repo, such as `pull', `fetch', `diff' etc.
104
105 This option is default for --nokia-developer/--brisbane.
106
107 After using this option, pass `--ignore-submodules=none' to git to override
108 it as needed.
109
110 =back
111
112
113 B<Repository options:>
114
115 =over
116
117 =item --nokia-developer
118
119 Switch to internal Nokia URLs.
120
121
122 =item --brisbane
123
124 Switch to internal Nokia URLs and make use of the Brisbane git mirrors.
125 (Implies `--mirror' and `--mirror-webkit').
126
127 =item --berlin
128
129 Switch to internal Nokia URLs and make use of the Berlin git mirrors.
130 (Implies `--mirror' and `--mirror-webkit').
131
132
133 =item --ssh
134
135 Use the SSH protocol for git operations.  This may be useful if the git
136 protocol is blocked by a firewall. Note that this requires a user account
137 with an uploaded SSH key on all servers used.  (Implies `--nokia-developer').
138
139 The `--ssh' option does not affect the gerrit remotes.
140
141
142 =item --http
143
144 Use the HTTP protocol for git operations.  This may be useful if the git
145 protocol is blocked by a firewall.  Note that this only works with the
146 external Gitorious server.
147
148 The `--http' option does not affect the gerrit remotes.
149
150
151 =item --codereview-username <Gerrit/JIRA username>
152
153 Specify the user name for the (potentially) writable `gerrit' remote
154 for each module, for use with the Gerrit code review tool.
155
156 If this option is omitted, the gerrit remote is created without a username
157 and port number, and thus relies on a correct SSH configuration.
158
159
160 =item --alternates <path to other Qt5 repo>
161
162 Adds alternates for each submodule to another full qt5 checkout. This makes
163 this qt5 checkout very small, as it will use the object store of the
164 alternates before unique objects are stored in its own object store.
165
166 This option has no effect when using `--no-update'.
167
168 B<NOTE:> This will make this repo dependent on the alternate, which is
169 potentially dangerous!  The dependency can be broken by also using
170 the `--copy-objects' option, or by running C<git repack -a> in each
171 submodule, where required.  Please read the note about the `--shared' option
172 in the documentation of `git clone' for more information.
173
174
175 =item --copy-objects
176
177 When `--alternates' is used, automatically do a C<git repack -a> in each
178 submodule after cloning, to ensure that the repositories are independent
179 from the source used as a reference for cloning.
180
181 Note that this negates the disk usage benefits gained from the use of
182 `--alternates'.
183
184
185 =item --mirror <url-base>
186
187 Uses <url-base> as the base URL for submodule git mirrors.
188
189 For example:
190
191   --mirror user@machine:/foo/bar
192
193 ...will use the following as a mirror for qtbase:
194
195   user@machine:/foo/bar/qtbase.git
196
197 The mirror is permitted to contain a subset of the submodules; any
198 missing modules will fall back to the canonical URLs.
199
200 =item --mirror-webkit <url>
201
202 Uses <url> as the URL for the webkit git mirror.
203
204 =back
205
206 =cut
207
208 use Carp         qw( confess             );
209 use English      qw( -no_match_vars      );
210 use Getopt::Long qw( GetOptionsFromArray );
211 use Pod::Usage   qw( pod2usage           );
212 use Cwd          qw( getcwd              );
213
214 my %PROTOCOLS = (
215     'internal'  => 'git://scm.dev.nokia.troll.no/' ,
216     'ssh'       => 'git@scm.dev.nokia.troll.no:'   ,
217     'http'      => 'http://git.gitorious.org/'     ,
218 );
219
220 my %GERRIT_REPOS = map { $_ => "qt/$_" } qw(
221     qt3d
222     qt5
223     qlalr
224     qtactiveqt
225     qtbase
226     qtconnectivity
227     qtdeclarative
228     qtdoc
229     qtdocgallery
230     qtfeedback
231     qtimageformats
232     qtjsondb
233     qtjsbackend
234     qtlocation
235     qtmultimedia
236     qtphonon
237     qtpim
238     qtqa
239     qtquick1
240     qtrepotools
241     qtscript
242     qtsensors
243     qtsvg
244     qtsystems
245     qttools
246     qttranslations
247     qtwayland
248     qtwebkit-examples-and-demos
249     qtxmlpatterns
250 );
251
252 my $GERRIT_SSH_BASE
253     = 'ssh://@USER@codereview.qt-project.org@PORT@/';
254
255 my $BNE_MIRROR_URL_BASE
256     = 'git://bq-git.apac.nokia.com/qtsoftware/';
257
258 my $BNE_MIRROR_WEBKIT_URL
259     = 'git://bq-git.apac.nokia.com/qtsoftware/research/gitorious-org-webkit-qtwebkit-mirror.git';
260
261 my $BER_MIRROR_URL_BASE
262     = 'git://ber-git.europe.nokia.com/';
263
264 my $BER_MIRROR_WEBKIT_URL
265     = 'git://ber-git.europe.nokia.com/qtwebkit/qtwebkit.git';
266
267
268 sub new
269 {
270     my ($class, @arguments) = @_;
271
272     my $self = {};
273     bless $self, $class;
274     $self->parse_arguments(@arguments);
275
276     return $self;
277 }
278
279 # Like `system', but possibly log the command, and die on non-zero exit code
280 sub exe
281 {
282     my ($self, @cmd) = @_;
283
284     if (!$self->{quiet}) {
285         print "+ @cmd\n";
286     }
287
288     if (system(@cmd) != 0) {
289         confess "@cmd exited with status $CHILD_ERROR";
290     }
291
292     return;
293 }
294
295 sub parse_arguments
296 {
297     my ($self, @args) = @_;
298
299     %{$self} = (%{$self},
300         'alternates'          => "",
301         'codereview-username' => "",
302         'detach-alternates'   => 0 ,
303         'force'               => 0 ,
304         'ignore-submodules'   => 0 ,
305         'mirror-url'          => "",
306         'mirror-webkit-url'   => "",
307         'nokia-developer'     => 0 ,
308         'protocol'            => "",
309         'update'              => 1 ,
310         'webkit'              => 1 ,
311         'module-subset'       => "",
312     );
313
314     GetOptionsFromArray(\@args,
315         'alternates=s'      =>  \$self->{qw{ alternates        }},
316         'codereview-username=s' => \$self->{qw{ codereview-username }},
317         'copy-objects'      =>  \$self->{qw{ detach-alternates }},
318         'force'             =>  \$self->{qw{ force             }},
319         'ignore-submodules' =>  \$self->{qw{ ignore-submodules }},
320         'mirror-webkit=s'   =>  \$self->{qw{ mirror-webkit-url }},
321         'mirror=s'          =>  \$self->{qw{ mirror-url        }},
322         'nokia-developer'   =>  \$self->{qw{ nokia-developer   }},
323         'quiet'             =>  \$self->{qw{ quiet             }},
324         'update!'           =>  \$self->{qw{ update            }},
325         'webkit!'           =>  \$self->{qw{ webkit            }},
326         'module-subset=s'   =>  \$self->{qw{ module-subset     }},
327
328         'help|?'            =>  sub { pod2usage(1);               },
329         'http'              =>  sub { $self->{protocol} = 'http'; },
330         'ssh|ssh-protocol'  =>  sub { $self->{protocol} = 'ssh';  },
331
332         'brisbane|brisbane-nokia-developer' => sub {
333             $self->{'nokia-developer'}   = 1;
334             $self->{'protocol'}          = 'internal';
335             $self->{'mirror-url'}        = $BNE_MIRROR_URL_BASE;
336             $self->{'mirror-webkit-url'} = $BNE_MIRROR_WEBKIT_URL;
337             $self->{'ignore-submodules'} = 1;
338         },
339
340         'berlin|berlin-nokia-developer' => sub {
341             $self->{'nokia-developer'}   = 1;
342             $self->{'protocol'}          = 'internal';
343             $self->{'mirror-url'}        = $BER_MIRROR_URL_BASE;
344             $self->{'mirror-webkit-url'} = $BER_MIRROR_WEBKIT_URL;
345         },
346
347         'nokia-developer' => sub {
348             $self->{'nokia-developer'}   = 1;
349             $self->{'protocol'}          = 'internal';
350             $self->{'ignore-submodules'} = 1;
351         },
352     ) || pod2usage(2);
353
354     if ($self->{'nokia-developer'} && $self->{'protocol'} eq 'http') {
355         print "*** Ignoring use of HTTP protocol, as it's only usable with external server\n";
356         $self->{'protocol'} = '';
357     }
358
359     # Replace any double trailing slashes from end of mirror
360     $self->{'mirror-url'} =~ s{//+$}{/};
361
362     if ($self->{'module-subset'}) {
363         $self->{'module-subset'} = {
364             map { $_ => 1 } split(qr{,}, $self->{'module-subset'})
365         };
366     }
367
368     return;
369 }
370
371 sub check_if_already_initialized
372 {
373     my ($self) = @_;
374
375     # We consider the repo as `initialized' if submodule.qtbase.url is set
376     if (qx(git config --get submodule.qtbase.url)) {
377         if ($self->{force}) {
378             my @configresult = qx(git config -l);
379             foreach (@configresult) {
380                 # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
381                 if (/(submodule\.[^.=]+)\.url=.*/) {
382                     $self->exe('git', 'config', '--remove-section', $1);
383                 }
384             }
385         }
386         else {
387             exit 0 if ($self->{quiet});
388             print "Will not reinitialize already initialized repository (use -f to force)!\n";
389             exit 1;
390         }
391     }
392
393     return;
394 }
395
396 sub git_submodule_init
397 {
398     my ($self) = @_;
399
400     my @init_args;
401     if ($self->{quiet}) {
402         push @init_args, '--quiet';
403     }
404     $self->exe('git', 'submodule', 'init', @init_args);
405
406     my $template = getcwd()."/.commit-template";
407     if (-e $template) {
408         $self->exe('git', 'config', 'commit.template', $template);
409     }
410
411     return;
412 }
413
414 sub git_disable_webkit_submodule
415 {
416     my ($self) = @_;
417
418     $self->exe('git', 'config', '--remove', 'submodule.qtwebkit');
419     $self->exe('git', 'config', '--remove', 'submodule.qtwebkit-examples-and-demos');
420
421     return;
422 }
423
424 sub git_prune_submodules
425 {
426     my ($self) = @_;
427
428     my @configresult = qx(git config -l);
429     foreach my $line (@configresult) {
430         if ($line =~ /submodule\.([^.=]+)\.url=/) {
431             my $module_name = $1;
432             if (!$self->{'module-subset'}{$module_name}) {
433                 $self->exe('git', 'config', '--remove', "submodule.$module_name");
434             }
435         }
436     }
437 }
438
439 sub git_set_submodule_config
440 {
441     my ($self) = @_;
442
443     my @configresult          = qx(git config -l);
444     my $protocol              = $self->{protocol};
445     my $url_base_for_protocol = $PROTOCOLS{$protocol};
446
447     foreach my $line (@configresult) {
448         # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
449         next if ($line !~ /submodule\.([^.=]+)\.url=(.*)/);
450
451         my $key   = $1;
452         my $value = $2;
453
454         if ($protocol) {
455             # WebKit is special, and has only external link.
456             if ($key ne 'qtwebkit') {
457                 # qt-labs projects are still hosted under qt internally.
458                 if ($protocol ne 'http') {
459                     $value =~ s,^git://gitorious\.org/qt-labs/,${url_base_for_protocol}qt/,;
460                 }
461
462                 # assume all other projects hosted under gitorious publicly.
463                 $value =~ s,^git://gitorious\.org/,$url_base_for_protocol,;
464             }
465         }
466
467         $self->exe('git', 'config', "submodule.$key.url", $value);
468
469         if ($self->{'ignore-submodules'}) {
470             $self->exe('git', 'config', "submodule.$key.ignore", 'all');
471         }
472     }
473
474     return;
475 }
476
477 sub git_clone_all_submodules
478 {
479     my ($self) = @_;
480
481     # manually clone each repo here, so we can easily use reference repos, mirrors etc
482     my @configresult = qx(git config -l);
483     foreach my $line (@configresult) {
484         if ($line =~ /submodule\.([^.=]+)\.url=(.*)/) {
485             $self->git_clone_one_submodule($1, $2);
486         }
487     }
488
489     if ($self->{update}) {
490         $self->exe('git', 'submodule', 'update', '--recursive');
491     }
492
493     return;
494 }
495
496 sub git_add_remotes
497 {
498     my ($self, $repo_basename) = @_;
499
500     my $gerrit_repo_basename = $GERRIT_REPOS{$repo_basename};
501     if ($gerrit_repo_basename) {
502         my $gerrit_repo_url;
503
504         # If given a username, make a "verbose" remote.
505         # Otherwise, rely on proper SSH configuration.
506         if ($self->{'codereview-username'}) {
507             $gerrit_repo_url = $GERRIT_SSH_BASE;
508             $gerrit_repo_url =~ s,\@USER\@,$self->{'codereview-username'}\@,;
509             $gerrit_repo_url =~ s,\@PORT\@,:29418,;
510         }
511         else {
512             $gerrit_repo_url = $GERRIT_SSH_BASE;
513             $gerrit_repo_url =~ s,\@[^\@]+\@,,g;
514         }
515
516         $gerrit_repo_url .= $gerrit_repo_basename;
517         $self->exe('git', 'config', 'remote.gerrit.url', $gerrit_repo_url);
518         $self->exe('git', 'config', 'remote.gerrit.fetch', '+refs/heads/*:refs/remotes/gerrit/*');
519     }
520
521     return;
522 }
523
524 sub git_clone_one_submodule
525 {
526     my ($self, $submodule, $url) = @_;
527
528     my $alternates            = $self->{ 'alternates'        };
529     my $mirror_url            = $self->{ 'mirror-url'        };
530     my $mirror_webkit_url     = $self->{ 'mirror-webkit-url' };
531     my $protocol              = $self->{ 'protocol'          };
532
533     # `--reference FOO' args for the clone, if any.
534     my @reference_args;
535
536     if ($alternates) {
537         # alternates is a qt5 repo, so the submodule will be under that.
538         if (-d "$alternates/$submodule") {
539             @reference_args = ('--reference', "$alternates/$submodule");
540         }
541         else {
542             print " *** $alternates/$submodule not found, ignoring alternate for this submodule\n";
543         }
544     }
545
546     my $mirror;
547     if ($mirror_url && ($submodule ne 'qtwebkit')) {
548         $mirror = $mirror_url."qt/$submodule";
549         $mirror .= ".git" unless (-d $mirror); # Support local disk mirror
550     }
551     elsif ($mirror_webkit_url && ($submodule eq 'qtwebkit')) {
552         $mirror = $mirror_webkit_url;
553     }
554
555     if ($mirror) {
556         # Only use the mirror if it can be reached.
557         eval { $self->exe('git', 'ls-remote', $mirror, 'test/if/mirror/exists') };
558         if ($@) {
559             warn "mirror [$mirror] is not accessible; $url will be used\n";
560             undef $mirror;
561         }
562     }
563
564     my $do_clone = (! -d "$submodule/.git");
565     if ($do_clone) {
566         $self->exe('git', 'clone', @reference_args, ($mirror ? $mirror : $url), $submodule);
567     }
568
569     chdir($submodule) or confess "chdir $submodule: $OS_ERROR";
570
571     $self->exe('git', 'config', 'remote.origin.url', $url);
572     if ($mirror) {
573         $self->exe('git', 'config', 'remote.mirror.url', $mirror);
574         $self->exe('git', 'config', 'remote.mirror.fetch', '+refs/heads/*:refs/remotes/mirror/*');
575     }
576
577     if (!$do_clone) {
578         $self->exe('git', 'fetch', ($mirror ? $mirror : $url));
579     }
580
581     my $template = getcwd()."/../.commit-template";
582     if (-e $template) {
583         $self->exe('git', 'config', 'commit.template', $template);
584     }
585
586     $self->git_add_remotes($submodule);
587
588     if ($self->{'detach-alternates'}) {
589         $self->exe('git', 'repack', '-a');
590
591         my $alternates_path = '.git/objects/info/alternates';
592         unlink($alternates_path) || confess "unlink $alternates_path: $OS_ERROR";
593     }
594
595     chdir("..") or confess "cd ..: $OS_ERROR";
596
597     return;
598 }
599
600 sub run
601 {
602     my ($self) = @_;
603
604     $self->check_if_already_initialized;
605     $self->git_submodule_init;
606
607     if (!$self->{webkit}) {
608         $self->git_disable_webkit_submodule;
609     }
610
611     if ($self->{'module-subset'}) {
612         $self->git_prune_submodules;
613     }
614
615     $self->git_set_submodule_config;
616
617     $self->git_clone_all_submodules;
618
619     $self->git_add_remotes('qt5');
620
621     return;
622 }
623
624 #==============================================================================
625
626 Qt::InitRepository->new(@ARGV)->run if (!caller);
627 1;