abb2b93cc3abfb812289f50fea640f1846a925fb
[mirror/qt/qt5.git] / init-repository
1 #!/usr/bin/env perl
2 #############################################################################
3 ##
4 ## Copyright (C) 2011 Nokia Corporation and/or its subsidiary(-ies).
5 ## All rights reserved.
6 ## Contact: Nokia Corporation (qt-info@nokia.com)
7 ##
8 ## This file is part of the utilities of the Qt Toolkit.
9 ##
10 ## $QT_BEGIN_LICENSE:LGPL$
11 ## No Commercial Usage
12 ## This file contains pre-release code and may not be distributed.
13 ## You may use this file in accordance with the terms and conditions
14 ## contained in the Technology Preview License Agreement accompanying
15 ## this package.
16 ##
17 ## GNU Lesser General Public License Usage
18 ## Alternatively, this file may be used under the terms of the GNU Lesser
19 ## General Public License version 2.1 as published by the Free Software
20 ## Foundation and appearing in the file LICENSE.LGPL included in the
21 ## packaging of this file.  Please review the following information to
22 ## ensure the GNU Lesser General Public License version 2.1 requirements
23 ## will be met: http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
24 ##
25 ## In addition, as a special exception, Nokia gives you certain additional
26 ## rights.  These rights are described in the Nokia Qt LGPL Exception
27 ## version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
28 ##
29 ## If you have questions regarding the use of this file, please contact
30 ## Nokia at qt-info@nokia.com.
31 ##
32 ##
33 ##
34 ##
35 ##
36 ##
37 ##
38 ##
39 ## $QT_END_LICENSE$
40 ##
41 #############################################################################
42
43 use v5.10;
44 use strict;
45 use warnings;
46
47 package Qt::InitRepository;
48
49
50 =head1 NAME
51
52 init-repository - initialize the Qt5 repository and all submodules
53
54 =head1 SYNOPSIS
55
56   ./init-repository [options]
57
58 This script may be run after an initial `git clone' of Qt5 in order to check
59 out all submodules.
60
61
62 =head1 OPTIONS
63
64 B<Global options:>
65
66 =over
67
68 =item --force, -f
69
70 Force initialization (even if the submodules are already checked out).
71
72
73 =item --quiet, -q
74
75 Be quiet.  Will exit cleanly if the repository is already initialized.
76
77 =back
78
79
80 B<Module options:>
81
82 =over
83
84 =item --no-webkit
85
86 Skip webkit and webkit examples submodules.
87 It may be desirable to skip these modules due to the large size of the webkit
88 git repository.
89
90 =item --module-subset=<module1>,<module2>...
91
92 Only initialize the specified subset of modules given as the argument. Specified
93 modules must already exist in .gitmodules.
94
95 =item --no-update
96
97 Skip the `git submodule update' command.
98
99
100 =item --ignore-submodules
101
102 Set git config to ignore submodules by default when doing operations on the
103 qt5 repo, such as `pull', `fetch', `diff' etc.
104
105 This option is default for --nokia-developer/--brisbane.
106
107 After using this option, pass `--ignore-submodules=none' to git to override
108 it as needed.
109
110 =back
111
112
113 B<Repository options:>
114
115 =over
116
117 =item --nokia-developer
118
119 Switch to internal Nokia URLs.
120
121
122 =item --brisbane
123
124 Switch to internal Nokia URLs and make use of the Brisbane git mirrors.
125 (Implies `--mirror' and `--mirror-webkit').
126
127 =item --berlin
128
129 Switch to internal Nokia URLs and make use of the Berlin git mirrors.
130 (Implies `--mirror' and `--mirror-webkit').
131
132
133 =item --ssh
134
135 Use the SSH protocol for git operations.  This may be useful if the git
136 protocol is blocked by a firewall. Note that this requires a user account
137 with an uploaded SSH key on all servers used.  (Implies `--nokia-developer').
138
139 The `--ssh' option does not affect the gerrit remotes.
140
141
142 =item --http
143
144 Use the HTTP protocol for git operations.  This may be useful if the git
145 protocol is blocked by a firewall.  Note that this only works with the
146 external Gitorious server.
147
148 The `--http' option does not affect the gerrit remotes.
149
150
151 =item --codereview-username <Gerrit/JIRA username>
152
153 Adds a (potentially) writable remote named `gerrit' for each module,
154 for use with the Gerrit code review tool.
155 This requires a username for SSH access to the codereview.qt.nokia.com
156 server, which will be the same username you have for the bugtracker at
157 bugreports.qt.nokia.com.
158
159 If this option is omitted, the gerrit remote is created with read-only
160 access (using HTTP protocol).
161
162
163 =item --alternates <path to other Qt5 repo>
164
165 Adds alternates for each submodule to another full qt5 checkout. This makes
166 this qt5 checkout very small, as it will use the object store of the
167 alternates before unique objects are stored in its own object store.
168
169 This option has no effect when using `--no-update'.
170
171 B<NOTE:> This will make this repo dependent on the alternate, which is
172 potentially dangerous!  The dependency can be broken by also using
173 the `--copy-objects' option, or by running C<git repack -a> in each
174 submodule, where required.  Please read the note about the `--shared' option
175 in the documentation of `git clone' for more information.
176
177
178 =item --copy-objects
179
180 When `--alternates' is used, automatically do a C<git repack -a> in each
181 submodule after cloning, to ensure that the repositories are independent
182 from the source used as a reference for cloning.
183
184 Note that this negates the disk usage benefits gained from the use of
185 `--alternates'.
186
187
188 =item --mirror <url-base>
189
190 Uses <url-base> as the base URL for submodule git mirrors.
191
192 For example:
193
194   --mirror user@machine:/foo/bar
195
196 ...will use the following as a mirror for qtbase:
197
198   user@machine:/foo/bar/qtbase.git
199
200
201 =item --mirror-webkit <url>
202
203 Uses <url> as the URL for the webkit git mirror.
204
205 =back
206
207 =cut
208
209 use Carp         qw( confess             );
210 use English      qw( -no_match_vars      );
211 use Getopt::Long qw( GetOptionsFromArray );
212 use Pod::Usage   qw( pod2usage           );
213 use Cwd          qw( getcwd              );
214
215 my %PROTOCOLS = (
216     'internal'  => 'git://scm.dev.nokia.troll.no/' ,
217     'ssh'       => 'git@scm.dev.nokia.troll.no:'   ,
218     'http'      => 'http://git.gitorious.org/'     ,
219 );
220
221 my %GERRIT_REPOS = map { $_ => "qt/$_" } qw(
222     qt5
223     qlalr
224     qtactiveqt
225     qtbase
226     qtdeclarative
227     qtdoc
228     qtfeedback
229     qtlocation
230     qtmultimedia
231     qtmultimediakit
232     qtphonon
233     qtqa
234     qtrepotools
235     qtscript
236     qtsensors
237     qtsvg
238     qtsystems
239     qttools
240     qttranslations
241     qtwebkit-examples-and-demos
242     qtxmlpatterns
243 );
244
245 my $GERRIT_SSH_BASE
246     = 'ssh://codereview.qt.nokia.com:29418/';
247
248 my $GERRIT_HTTP_BASE
249     = 'http://codereview.qt.nokia.com/p/';
250
251 my $BNE_MIRROR_URL_BASE
252     = 'git://bq-git.apac.nokia.com/qtsoftware/qt/';
253
254 my $BNE_MIRROR_WEBKIT_URL
255     = 'git://bq-git.apac.nokia.com/qtsoftware/research/gitorious-org-webkit-qtwebkit-mirror.git';
256
257 my $BER_MIRROR_URL_BASE
258     = 'git://ber-git.europe.nokia.com/qt/';
259
260 my $BER_MIRROR_WEBKIT_URL
261     = 'git://ber-git.europe.nokia.com/qtwebkit/qtwebkit.git';
262
263
264 sub new
265 {
266     my ($class, @arguments) = @_;
267
268     my $self = {};
269     bless $self, $class;
270     $self->parse_arguments(@arguments);
271
272     return $self;
273 }
274
275 # Like `system', but possibly log the command, and die on non-zero exit code
276 sub exe
277 {
278     my ($self, @cmd) = @_;
279
280     if (!$self->{quiet}) {
281         print "+ @cmd\n";
282     }
283
284     if (system(@cmd) != 0) {
285         confess "@cmd exited with status $CHILD_ERROR";
286     }
287
288     return;
289 }
290
291 sub parse_arguments
292 {
293     my ($self, @args) = @_;
294
295     %{$self} = (%{$self},
296         'alternates'          => "",
297         'codereview-username' => "",
298         'detach-alternates'   => 0 ,
299         'force'               => 0 ,
300         'ignore-submodules'   => 0 ,
301         'mirror-url'          => "",
302         'mirror-webkit-url'   => "",
303         'nokia-developer'     => 0 ,
304         'protocol'            => "",
305         'update'              => 1 ,
306         'webkit'              => 1 ,
307         'module-subset'       => "",
308     );
309
310     GetOptionsFromArray(\@args,
311         'alternates=s'      =>  \$self->{qw{ alternates        }},
312         'codereview-username=s' => \$self->{qw{ codereview-username }},
313         'copy-objects'      =>  \$self->{qw{ detach-alternates }},
314         'force'             =>  \$self->{qw{ force             }},
315         'ignore-submodules' =>  \$self->{qw{ ignore-submodules }},
316         'mirror-webkit=s'   =>  \$self->{qw{ mirror-webkit-url }},
317         'mirror=s'          =>  \$self->{qw{ mirror-url        }},
318         'nokia-developer'   =>  \$self->{qw{ nokia-developer   }},
319         'quiet'             =>  \$self->{qw{ quiet             }},
320         'update!'           =>  \$self->{qw{ update            }},
321         'webkit!'           =>  \$self->{qw{ webkit            }},
322         'module-subset=s'   =>  \$self->{qw{ module-subset     }},
323
324         'help|?'            =>  sub { pod2usage(1);               },
325         'http'              =>  sub { $self->{protocol} = 'http'; },
326         'ssh|ssh-protocol'  =>  sub { $self->{protocol} = 'ssh';  },
327
328         'brisbane|brisbane-nokia-developer' => sub {
329             $self->{'nokia-developer'}   = 1;
330             $self->{'protocol'}          = 'internal';
331             $self->{'mirror-url'}        = $BNE_MIRROR_URL_BASE;
332             $self->{'mirror-webkit-url'} = $BNE_MIRROR_WEBKIT_URL;
333             $self->{'ignore-submodules'} = 1;
334         },
335
336         'berlin|berlin-nokia-developer' => sub {
337             $self->{'nokia-developer'}   = 1;
338             $self->{'protocol'}          = 'internal';
339             $self->{'mirror-url'}        = $BER_MIRROR_URL_BASE;
340             $self->{'mirror-webkit-url'} = $BER_MIRROR_WEBKIT_URL;
341         },
342
343         'nokia-developer' => sub {
344             $self->{'nokia-developer'}   = 1;
345             $self->{'protocol'}          = 'internal';
346             $self->{'ignore-submodules'} = 1;
347         },
348     ) || pod2usage(2);
349
350     if ($self->{'nokia-developer'} && $self->{'protocol'} eq 'http') {
351         print "*** Ignoring use of HTTP protocol, as it's only usable with external server\n";
352         $self->{'protocol'} = '';
353     }
354
355     # Replace any double trailing slashes from end of mirror
356     $self->{'mirror-url'} =~ s{//+$}{/};
357
358     if ($self->{'module-subset'}) {
359         $self->{'module-subset'} = {
360             map { $_ => 1 } split(qr{,}, $self->{'module-subset'})
361         };
362     }
363
364     return;
365 }
366
367 sub check_if_already_initialized
368 {
369     my ($self) = @_;
370
371     # We consider the repo as `initialized' if submodule.qtbase.url is set
372     if (qx(git config --get submodule.qtbase.url)) {
373         if ($self->{force}) {
374             my @configresult = qx(git config -l);
375             foreach (@configresult) {
376                 # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
377                 if (/(submodule\.[^.=]+)\.url=.*/) {
378                     $self->exe('git', 'config', '--remove-section', $1);
379                 }
380             }
381         }
382         else {
383             exit 0 if ($self->{quiet});
384             print "Will not reinitialize already initialized repository (use -f to force)!\n";
385             exit 1;
386         }
387     }
388
389     return;
390 }
391
392 sub git_submodule_init
393 {
394     my ($self) = @_;
395
396     my @init_args;
397     if ($self->{quiet}) {
398         push @init_args, '--quiet';
399     }
400     $self->exe('git', 'submodule', 'init', @init_args);
401
402     my $template = getcwd()."/.commit-template";
403     if (-e $template) {
404         $self->exe('git', 'config', 'commit.template', $template);
405     }
406
407     return;
408 }
409
410 sub git_disable_webkit_submodule
411 {
412     my ($self) = @_;
413
414     $self->exe('git', 'config', '--remove', 'submodule.qtwebkit');
415     $self->exe('git', 'config', '--remove', 'submodule.qtwebkit-examples-and-demos');
416
417     return;
418 }
419
420 sub git_prune_submodules
421 {
422     my ($self) = @_;
423
424     my @configresult = qx(git config -l);
425     foreach my $line (@configresult) {
426         if ($line =~ /submodule\.([^.=]+)\.url=/) {
427             my $module_name = $1;
428             if (!$self->{'module-subset'}{$module_name}) {
429                 $self->exe('git', 'config', '--remove', "submodule.$module_name");
430             }
431         }
432     }
433 }
434
435 sub git_set_submodule_config
436 {
437     my ($self) = @_;
438
439     my @configresult          = qx(git config -l);
440     my $protocol              = $self->{protocol};
441     my $url_base_for_protocol = $PROTOCOLS{$protocol};
442
443     foreach my $line (@configresult) {
444         # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
445         next if ($line !~ /(submodule\.[^.=]+\.url)=(.*)/);
446
447         my $key   = $1;
448         my $value = $2;
449
450         if ($protocol) {
451             # WebKit is special, and has only external link.
452             if ($key ne 'submodule.qtwebkit.url') {
453                 # qt-labs projects are still hosted under qt internally.
454                 if ($protocol ne 'http') {
455                     $value =~ s,^git://gitorious\.org/qt-labs/,${url_base_for_protocol}qt/,;
456                 }
457                 $value =~ s,^git://gitorious\.org/,$url_base_for_protocol,;
458             }
459         }
460
461         $self->exe('git', 'config', $key, $value);
462
463         if ($self->{'ignore-submodules'}) {
464             $key =~ s,\.url,.ignore,;
465             $self->exe('git', 'config', $key, 'all');
466         }
467     }
468
469     return;
470 }
471
472 sub git_clone_all_submodules
473 {
474     my ($self) = @_;
475
476     # manually clone each repo here, so we can easily use reference repos, mirrors etc
477     my @configresult = qx(git config -l);
478     foreach my $line (@configresult) {
479         if ($line =~ /submodule\.([^.=]+)\.url=(.*)/) {
480             $self->git_clone_one_submodule($1, $2);
481         }
482     }
483
484     $self->exe('git', 'submodule', 'update');
485
486     return;
487 }
488
489 sub git_add_remotes
490 {
491     my ($self, $repo_basename) = @_;
492
493     my $protocol              = $self->{protocol};
494     my $url_base_for_protocol = $PROTOCOLS{$protocol};
495
496     my %current_remotes;
497     for my $line (qx(git remote show)) {
498         chomp $line;
499         $current_remotes{$line} = 1;
500     }
501
502     my $gerrit_repo_basename = $GERRIT_REPOS{$repo_basename};
503     if ($gerrit_repo_basename && !$current_remotes{'gerrit'}) {
504         my $gerrit_repo_url;
505
506         # If given a username, we use writable remote (ssh).
507         # Otherwise, we use read-only (http).
508         if ($self->{'codereview-username'}) {
509             $gerrit_repo_url = $GERRIT_SSH_BASE;
510             $gerrit_repo_url =~ s[^ssh://][ssh://$self->{'codereview-username'}@];
511         }
512         else {
513             $gerrit_repo_url = $GERRIT_HTTP_BASE;
514         }
515
516         $gerrit_repo_url .= $gerrit_repo_basename;
517         $self->exe('git', 'remote', 'add', 'gerrit', $gerrit_repo_url);
518
519         $current_remotes{'gerrit'} = 1;
520     }
521
522     # if repo still has no gerrit repo defined, alias it to origin
523     if (!$current_remotes{'gerrit'}) {
524         my @configresult = qx(git remote -v);
525         foreach (@configresult) {
526             if (/^origin\s+(\S+) \(fetch\)/) {
527                 $self->exe('git', 'remote', 'add', 'gerrit', $1);
528             }
529         }
530     }
531
532     return;
533 }
534
535 sub git_clone_one_submodule
536 {
537     my ($self, $submodule, $url) = @_;
538
539     my $alternates            = $self->{ 'alternates'        };
540     my $mirror_url            = $self->{ 'mirror-url'        };
541     my $mirror_webkit_url     = $self->{ 'mirror-webkit-url' };
542
543     # `--reference FOO' args for the clone, if any.
544     my @reference_args;
545
546     if ($alternates) {
547         # alternates is a qt5 repo, so the submodule will be under that.
548         if (-d "$alternates/$submodule") {
549             @reference_args = ('--reference', "$alternates/$submodule");
550         }
551         else {
552             print " *** $alternates/$submodule not found, ignoring alternate for this submodule\n";
553         }
554     }
555
556     my $mirror;
557     if ($mirror_url && ($submodule ne 'qtwebkit')) {
558         $mirror = $mirror_url.$submodule;
559         $mirror .= ".git" unless (-d $mirror); # Support local disk mirror
560     }
561     elsif ($mirror_webkit_url && ($submodule eq 'qtwebkit')) {
562         $mirror = $mirror_webkit_url;
563     }
564
565     my $do_clone = (! -d "$submodule/.git");
566     if ($do_clone) {
567         $self->exe('git', 'clone', @reference_args, ($mirror ? $mirror : $url), $submodule);
568     }
569
570     chdir($submodule) or confess "chdir $submodule: $OS_ERROR";
571
572     if (!$do_clone) {
573         $self->exe('git', 'fetch', ($mirror ? $mirror : $url));
574     }
575
576     my $template = getcwd()."/../.commit-template";
577     if (-e $template) {
578         $self->exe('git', 'config', 'commit.template', $template);
579     }
580
581     if ($mirror) {
582         $self->exe('git', 'config', 'remote.origin.url', $url);
583
584         # In `force' mode, remove the mirror if it already exists,
585         # since we may be reinitializing the module.
586         if ($self->{force}) {
587             eval { $self->exe('git', 'remote', 'rm', 'mirror'); }; # failure is OK
588         }
589
590         $self->exe('git', 'remote', 'add', 'mirror', $mirror);
591     }
592
593     $self->git_add_remotes($submodule);
594
595     if ($self->{'detach-alternates'}) {
596         $self->exe('git', 'repack', '-a');
597
598         my $alternates_path = '.git/objects/info/alternates';
599         unlink($alternates_path) || confess "unlink $alternates_path: $OS_ERROR";
600     }
601
602     if ($submodule eq "qtdeclarative") { #Extra step needed to setup declarative 
603         $self->exe('git', 'submodule', 'init'); 
604         $self->exe('git', 'submodule', 'update'); 
605     } 
606
607     chdir("..") or confess "cd ..: $OS_ERROR";
608
609     return;
610 }
611
612 sub run
613 {
614     my ($self) = @_;
615
616     $self->check_if_already_initialized;
617     $self->git_submodule_init;
618
619     if (!$self->{webkit}) {
620         $self->git_disable_webkit_submodule;
621     }
622
623     if ($self->{'module-subset'}) {
624         $self->git_prune_submodules;
625     }
626
627     $self->git_set_submodule_config;
628
629     if ($self->{update}) {
630         $self->git_clone_all_submodules;
631     }
632
633     $self->git_add_remotes('qt5');
634
635     return;
636 }
637
638 #==============================================================================
639
640 Qt::InitRepository->new(@ARGV)->run if (!caller);
641 1;