Updated submodules.
[mirror/qt/qt5.git] / init-repository
1 #!/usr/bin/env perl
2 #############################################################################
3 ##
4 ## Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
5 ## All rights reserved.
6 ## Contact: Nokia Corporation (qt-info@nokia.com)
7 ##
8 ## This file is part of the utilities of the Qt Toolkit.
9 ##
10 ## $QT_BEGIN_LICENSE:LGPL$
11 ## GNU Lesser General Public License Usage
12 ## This file may be used under the terms of the GNU Lesser General Public
13 ## License version 2.1 as published by the Free Software Foundation and
14 ## appearing in the file LICENSE.LGPL included in the packaging of this
15 ## file. Please review the following information to ensure the GNU Lesser
16 ## General Public License version 2.1 requirements will be met:
17 ## http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
18 ##
19 ## In addition, as a special exception, Nokia gives you certain additional
20 ## rights. These rights are described in the Nokia Qt LGPL Exception
21 ## version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
22 ##
23 ## GNU General Public License Usage
24 ## Alternatively, this file may be used under the terms of the GNU General
25 ## Public License version 3.0 as published by the Free Software Foundation
26 ## and appearing in the file LICENSE.GPL included in the packaging of this
27 ## file. Please review the following information to ensure the GNU General
28 ## Public License version 3.0 requirements will be met:
29 ## http://www.gnu.org/copyleft/gpl.html.
30 ##
31 ## Other Usage
32 ## Alternatively, this file may be used in accordance with the terms and
33 ## conditions contained in a signed written agreement between you and Nokia.
34 ##
35 ##
36 ##
37 ##
38 ##
39 ## $QT_END_LICENSE$
40 ##
41 #############################################################################
42
43 use v5.10;
44 use strict;
45 use warnings;
46
47 package Qt::InitRepository;
48
49
50 =head1 NAME
51
52 init-repository - initialize the Qt5 repository and all submodules
53
54 =head1 SYNOPSIS
55
56   ./init-repository [options]
57
58 This script may be run after an initial `git clone' of Qt5 in order to check
59 out all submodules.
60
61
62 =head1 OPTIONS
63
64 B<Global options:>
65
66 =over
67
68 =item --force, -f
69
70 Force initialization (even if the submodules are already checked out).
71
72
73 =item --quiet, -q
74
75 Be quiet.  Will exit cleanly if the repository is already initialized.
76
77 =back
78
79
80 B<Module options:>
81
82 =over
83
84 =item --no-webkit
85
86 Skip webkit and webkit examples submodules.
87 It may be desirable to skip these modules due to the large size of the webkit
88 git repository.
89
90 =item --module-subset=<module1>,<module2>...
91
92 Only initialize the specified subset of modules given as the argument. Specified
93 modules must already exist in .gitmodules.
94
95 =item --no-update
96
97 Skip the `git submodule update' command.
98
99
100 =item --ignore-submodules
101
102 Set git config to ignore submodules by default when doing operations on the
103 qt5 repo, such as `pull', `fetch', `diff' etc.
104
105 This option is default for --nokia-developer/--brisbane.
106
107 After using this option, pass `--ignore-submodules=none' to git to override
108 it as needed.
109
110 =back
111
112
113 B<Repository options:>
114
115 =over
116
117 =item --nokia-developer
118
119 Switch to internal Nokia URLs.
120
121
122 =item --brisbane
123
124 Switch to internal Nokia URLs and make use of the Brisbane git mirrors.
125 (Implies `--mirror' and `--mirror-webkit').
126
127 =item --berlin
128
129 Switch to internal Nokia URLs and make use of the Berlin git mirrors.
130 (Implies `--mirror' and `--mirror-webkit').
131
132
133 =item --ssh
134
135 Use the SSH protocol for git operations.  This may be useful if the git
136 protocol is blocked by a firewall. Note that this requires a user account
137 with an uploaded SSH key on all servers used.  (Implies `--nokia-developer').
138
139 The `--ssh' option does not affect the gerrit remotes.
140
141
142 =item --http
143
144 Use the HTTP protocol for git operations.  This may be useful if the git
145 protocol is blocked by a firewall.  Note that this only works with the
146 external Gitorious server.
147
148 The `--http' option does not affect the gerrit remotes.
149
150
151 =item --codereview-username <Gerrit/JIRA username>
152
153 Specify the user name for the (potentially) writable `gerrit' remote
154 for each module, for use with the Gerrit code review tool.
155
156 If this option is omitted, the gerrit remote is created without a username
157 and port number, and thus relies on a correct SSH configuration.
158
159
160 =item --alternates <path to other Qt5 repo>
161
162 Adds alternates for each submodule to another full qt5 checkout. This makes
163 this qt5 checkout very small, as it will use the object store of the
164 alternates before unique objects are stored in its own object store.
165
166 This option has no effect when using `--no-update'.
167
168 B<NOTE:> This will make this repo dependent on the alternate, which is
169 potentially dangerous!  The dependency can be broken by also using
170 the `--copy-objects' option, or by running C<git repack -a> in each
171 submodule, where required.  Please read the note about the `--shared' option
172 in the documentation of `git clone' for more information.
173
174
175 =item --copy-objects
176
177 When `--alternates' is used, automatically do a C<git repack -a> in each
178 submodule after cloning, to ensure that the repositories are independent
179 from the source used as a reference for cloning.
180
181 Note that this negates the disk usage benefits gained from the use of
182 `--alternates'.
183
184
185 =item --mirror <url-base>
186
187 Uses <url-base> as the base URL for submodule git mirrors.
188
189 For example:
190
191   --mirror user@machine:/foo/bar
192
193 ...will use the following as a mirror for qtbase:
194
195   user@machine:/foo/bar/qtbase.git
196
197 The mirror is permitted to contain a subset of the submodules; any
198 missing modules will fall back to the canonical URLs.
199
200 =item --mirror-webkit <url>
201
202 Uses <url> as the URL for the webkit git mirror.
203
204 =back
205
206 =cut
207
208 use Carp         qw( confess             );
209 use English      qw( -no_match_vars      );
210 use Getopt::Long qw( GetOptionsFromArray );
211 use Pod::Usage   qw( pod2usage           );
212 use Cwd          qw( getcwd              );
213
214 my %PROTOCOLS = (
215     'internal'  => 'git://scm.dev.nokia.troll.no/' ,
216     'ssh'       => 'git@scm.dev.nokia.troll.no:'   ,
217     'http'      => 'http://git.gitorious.org/'     ,
218 );
219
220 my %GERRIT_REPOS = map { $_ => "qt/$_" } qw(
221     qt3d
222     qt5
223     qlalr
224     qtactiveqt
225     qtbase
226     qtconnectivity
227     qtdeclarative
228     qtdoc
229     qtdocgallery
230     qtfeedback
231     qtjsondb
232     qtjsbackend
233     qtlocation
234     qtmultimedia
235     qtphonon
236     qtpim
237     qtqa
238     qtrepotools
239     qtscript
240     qtsensors
241     qtsvg
242     qtsystems
243     qttools
244     qttranslations
245     qtwayland
246     qtwebkit-examples-and-demos
247     qtxmlpatterns
248 );
249 $GERRIT_REPOS{qtquick3d} = "qt/quick3d";
250
251 # Protocol-specific repo overrides, if they differ from the values set in the git submodule config
252 # (e.g. because public vs private names differ for whatever reason)
253 my %PROTOCOL_REPOS = (
254     qtquick3d   =>  {
255         internal    =>  "qt/quick3d",   # instead of qt-quick3d/qt-quick3d on gitorious
256         ssh         =>  "qt/quick3d",
257     },
258 );
259
260 my $GERRIT_SSH_BASE
261     = 'ssh://@USER@codereview.qt-project.org@PORT@/';
262
263 my $BNE_MIRROR_URL_BASE
264     = 'git://bq-git.apac.nokia.com/qtsoftware/';
265
266 my $BNE_MIRROR_WEBKIT_URL
267     = 'git://bq-git.apac.nokia.com/qtsoftware/research/gitorious-org-webkit-qtwebkit-mirror.git';
268
269 my $BER_MIRROR_URL_BASE
270     = 'git://ber-git.europe.nokia.com/';
271
272 my $BER_MIRROR_WEBKIT_URL
273     = 'git://ber-git.europe.nokia.com/qtwebkit/qtwebkit.git';
274
275
276 sub new
277 {
278     my ($class, @arguments) = @_;
279
280     my $self = {};
281     bless $self, $class;
282     $self->parse_arguments(@arguments);
283
284     return $self;
285 }
286
287 # Like `system', but possibly log the command, and die on non-zero exit code
288 sub exe
289 {
290     my ($self, @cmd) = @_;
291
292     if (!$self->{quiet}) {
293         print "+ @cmd\n";
294     }
295
296     if (system(@cmd) != 0) {
297         confess "@cmd exited with status $CHILD_ERROR";
298     }
299
300     return;
301 }
302
303 sub parse_arguments
304 {
305     my ($self, @args) = @_;
306
307     %{$self} = (%{$self},
308         'alternates'          => "",
309         'codereview-username' => "",
310         'detach-alternates'   => 0 ,
311         'force'               => 0 ,
312         'ignore-submodules'   => 0 ,
313         'mirror-url'          => "",
314         'mirror-webkit-url'   => "",
315         'nokia-developer'     => 0 ,
316         'protocol'            => "",
317         'update'              => 1 ,
318         'webkit'              => 1 ,
319         'module-subset'       => "",
320     );
321
322     GetOptionsFromArray(\@args,
323         'alternates=s'      =>  \$self->{qw{ alternates        }},
324         'codereview-username=s' => \$self->{qw{ codereview-username }},
325         'copy-objects'      =>  \$self->{qw{ detach-alternates }},
326         'force'             =>  \$self->{qw{ force             }},
327         'ignore-submodules' =>  \$self->{qw{ ignore-submodules }},
328         'mirror-webkit=s'   =>  \$self->{qw{ mirror-webkit-url }},
329         'mirror=s'          =>  \$self->{qw{ mirror-url        }},
330         'nokia-developer'   =>  \$self->{qw{ nokia-developer   }},
331         'quiet'             =>  \$self->{qw{ quiet             }},
332         'update!'           =>  \$self->{qw{ update            }},
333         'webkit!'           =>  \$self->{qw{ webkit            }},
334         'module-subset=s'   =>  \$self->{qw{ module-subset     }},
335
336         'help|?'            =>  sub { pod2usage(1);               },
337         'http'              =>  sub { $self->{protocol} = 'http'; },
338         'ssh|ssh-protocol'  =>  sub { $self->{protocol} = 'ssh';  },
339
340         'brisbane|brisbane-nokia-developer' => sub {
341             $self->{'nokia-developer'}   = 1;
342             $self->{'protocol'}          = 'internal';
343             $self->{'mirror-url'}        = $BNE_MIRROR_URL_BASE;
344             $self->{'mirror-webkit-url'} = $BNE_MIRROR_WEBKIT_URL;
345             $self->{'ignore-submodules'} = 1;
346         },
347
348         'berlin|berlin-nokia-developer' => sub {
349             $self->{'nokia-developer'}   = 1;
350             $self->{'protocol'}          = 'internal';
351             $self->{'mirror-url'}        = $BER_MIRROR_URL_BASE;
352             $self->{'mirror-webkit-url'} = $BER_MIRROR_WEBKIT_URL;
353         },
354
355         'nokia-developer' => sub {
356             $self->{'nokia-developer'}   = 1;
357             $self->{'protocol'}          = 'internal';
358             $self->{'ignore-submodules'} = 1;
359         },
360     ) || pod2usage(2);
361
362     if ($self->{'nokia-developer'} && $self->{'protocol'} eq 'http') {
363         print "*** Ignoring use of HTTP protocol, as it's only usable with external server\n";
364         $self->{'protocol'} = '';
365     }
366
367     # Replace any double trailing slashes from end of mirror
368     $self->{'mirror-url'} =~ s{//+$}{/};
369
370     if ($self->{'module-subset'}) {
371         $self->{'module-subset'} = {
372             map { $_ => 1 } split(qr{,}, $self->{'module-subset'})
373         };
374     }
375
376     return;
377 }
378
379 sub check_if_already_initialized
380 {
381     my ($self) = @_;
382
383     # We consider the repo as `initialized' if submodule.qtbase.url is set
384     if (qx(git config --get submodule.qtbase.url)) {
385         if ($self->{force}) {
386             my @configresult = qx(git config -l);
387             foreach (@configresult) {
388                 # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
389                 if (/(submodule\.[^.=]+)\.url=.*/) {
390                     $self->exe('git', 'config', '--remove-section', $1);
391                 }
392             }
393         }
394         else {
395             exit 0 if ($self->{quiet});
396             print "Will not reinitialize already initialized repository (use -f to force)!\n";
397             exit 1;
398         }
399     }
400
401     return;
402 }
403
404 sub git_submodule_init
405 {
406     my ($self) = @_;
407
408     my @init_args;
409     if ($self->{quiet}) {
410         push @init_args, '--quiet';
411     }
412     $self->exe('git', 'submodule', 'init', @init_args);
413
414     my $template = getcwd()."/.commit-template";
415     if (-e $template) {
416         $self->exe('git', 'config', 'commit.template', $template);
417     }
418
419     return;
420 }
421
422 sub git_disable_webkit_submodule
423 {
424     my ($self) = @_;
425
426     $self->exe('git', 'config', '--remove', 'submodule.qtwebkit');
427     $self->exe('git', 'config', '--remove', 'submodule.qtwebkit-examples-and-demos');
428
429     return;
430 }
431
432 sub git_prune_submodules
433 {
434     my ($self) = @_;
435
436     my @configresult = qx(git config -l);
437     foreach my $line (@configresult) {
438         if ($line =~ /submodule\.([^.=]+)\.url=/) {
439             my $module_name = $1;
440             if (!$self->{'module-subset'}{$module_name}) {
441                 $self->exe('git', 'config', '--remove', "submodule.$module_name");
442             }
443         }
444     }
445 }
446
447 sub git_set_submodule_config
448 {
449     my ($self) = @_;
450
451     my @configresult          = qx(git config -l);
452     my $protocol              = $self->{protocol};
453     my $url_base_for_protocol = $PROTOCOLS{$protocol};
454
455     foreach my $line (@configresult) {
456         # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
457         next if ($line !~ /submodule\.([^.=]+)\.url=(.*)/);
458
459         my $key   = $1;
460         my $value = $2;
461
462         if ($protocol) {
463             # WebKit is special, and has only external link.
464             if ($key ne 'qtwebkit') {
465                 # qt-labs projects are still hosted under qt internally.
466                 if ($protocol ne 'http') {
467                     $value =~ s,^git://gitorious\.org/qt-labs/,${url_base_for_protocol}qt/,;
468                 }
469
470                 if ($PROTOCOL_REPOS{$key}->{$protocol}) {
471                     # If this repo has an explicitly set basename for this protocol, use it...
472                     # e.g.   'git@example.com:'     . 'qt/quick3d'
473                     $value = $url_base_for_protocol . $PROTOCOL_REPOS{$key}->{$protocol};
474                 }
475                 else {
476                     # ...otherwise, assume the selected protocol uses same naming structure
477                     # as gitorious.org
478                     # e.g. git://gitorious.org/qt/qt5 => git@example.com:qt/qt5
479                     $value =~ s,^git://gitorious\.org/,$url_base_for_protocol,;
480                 }
481             }
482         }
483
484         $self->exe('git', 'config', "submodule.$key.url", $value);
485
486         if ($self->{'ignore-submodules'}) {
487             $self->exe('git', 'config', "submodule.$key.ignore", 'all');
488         }
489     }
490
491     return;
492 }
493
494 sub git_clone_all_submodules
495 {
496     my ($self) = @_;
497
498     # manually clone each repo here, so we can easily use reference repos, mirrors etc
499     my @configresult = qx(git config -l);
500     foreach my $line (@configresult) {
501         if ($line =~ /submodule\.([^.=]+)\.url=(.*)/) {
502             $self->git_clone_one_submodule($1, $2);
503         }
504     }
505
506     if ($self->{update}) {
507         $self->exe('git', 'submodule', 'update', '--recursive');
508     }
509
510     return;
511 }
512
513 sub git_add_remotes
514 {
515     my ($self, $repo_basename) = @_;
516
517     my $gerrit_repo_basename = $GERRIT_REPOS{$repo_basename};
518     if ($gerrit_repo_basename) {
519         my $gerrit_repo_url;
520
521         # If given a username, make a "verbose" remote.
522         # Otherwise, rely on proper SSH configuration.
523         if ($self->{'codereview-username'}) {
524             $gerrit_repo_url = $GERRIT_SSH_BASE;
525             $gerrit_repo_url =~ s,\@USER\@,$self->{'codereview-username'}\@,;
526             $gerrit_repo_url =~ s,\@PORT\@,:29418,;
527         }
528         else {
529             $gerrit_repo_url = $GERRIT_SSH_BASE;
530             $gerrit_repo_url =~ s,\@[^\@]+\@,,g;
531         }
532
533         $gerrit_repo_url .= $gerrit_repo_basename;
534         $self->exe('git', 'config', 'remote.gerrit.url', $gerrit_repo_url);
535         $self->exe('git', 'config', 'remote.gerrit.fetch', '+refs/heads/*:refs/remotes/gerrit/*');
536     }
537
538     return;
539 }
540
541 sub git_clone_one_submodule
542 {
543     my ($self, $submodule, $url) = @_;
544
545     my $alternates            = $self->{ 'alternates'        };
546     my $mirror_url            = $self->{ 'mirror-url'        };
547     my $mirror_webkit_url     = $self->{ 'mirror-webkit-url' };
548     my $protocol              = $self->{ 'protocol'          };
549
550     # `--reference FOO' args for the clone, if any.
551     my @reference_args;
552
553     if ($alternates) {
554         # alternates is a qt5 repo, so the submodule will be under that.
555         if (-d "$alternates/$submodule") {
556             @reference_args = ('--reference', "$alternates/$submodule");
557         }
558         else {
559             print " *** $alternates/$submodule not found, ignoring alternate for this submodule\n";
560         }
561     }
562
563     my $mirror;
564     if ($mirror_url && ($submodule ne 'qtwebkit')) {
565         $mirror = $mirror_url.( $PROTOCOL_REPOS{$submodule}->{internal} // "qt/$submodule" );
566         $mirror .= ".git" unless (-d $mirror); # Support local disk mirror
567     }
568     elsif ($mirror_webkit_url && ($submodule eq 'qtwebkit')) {
569         $mirror = $mirror_webkit_url;
570     }
571
572     if ($mirror) {
573         # Only use the mirror if it can be reached.
574         eval { $self->exe('git', 'ls-remote', $mirror, 'test/if/mirror/exists') };
575         if ($@) {
576             warn "mirror [$mirror] is not accessible; $url will be used\n";
577             undef $mirror;
578         }
579     }
580
581     my $do_clone = (! -d "$submodule/.git");
582     if ($do_clone) {
583         $self->exe('git', 'clone', @reference_args, ($mirror ? $mirror : $url), $submodule);
584     }
585
586     chdir($submodule) or confess "chdir $submodule: $OS_ERROR";
587
588     $self->exe('git', 'config', 'remote.origin.url', $url);
589     if ($mirror) {
590         $self->exe('git', 'config', 'remote.mirror.url', $mirror);
591         $self->exe('git', 'config', 'remote.mirror.fetch', '+refs/heads/*:refs/remotes/mirror/*');
592     }
593
594     if (!$do_clone) {
595         $self->exe('git', 'fetch', ($mirror ? $mirror : $url));
596     }
597
598     my $template = getcwd()."/../.commit-template";
599     if (-e $template) {
600         $self->exe('git', 'config', 'commit.template', $template);
601     }
602
603     $self->git_add_remotes($submodule);
604
605     if ($self->{'detach-alternates'}) {
606         $self->exe('git', 'repack', '-a');
607
608         my $alternates_path = '.git/objects/info/alternates';
609         unlink($alternates_path) || confess "unlink $alternates_path: $OS_ERROR";
610     }
611
612     chdir("..") or confess "cd ..: $OS_ERROR";
613
614     return;
615 }
616
617 sub run
618 {
619     my ($self) = @_;
620
621     $self->check_if_already_initialized;
622     $self->git_submodule_init;
623
624     if (!$self->{webkit}) {
625         $self->git_disable_webkit_submodule;
626     }
627
628     if ($self->{'module-subset'}) {
629         $self->git_prune_submodules;
630     }
631
632     $self->git_set_submodule_config;
633
634     $self->git_clone_all_submodules;
635
636     $self->git_add_remotes('qt5');
637
638     return;
639 }
640
641 #==============================================================================
642
643 Qt::InitRepository->new(@ARGV)->run if (!caller);
644 1;