b38a07e9b0027ea0c231b70995a4ecf4f1ff7f35
[mirror/qt/qt5.git] / init-repository
1 #!/usr/bin/env perl
2 #############################################################################
3 ##
4 ## Copyright (C) 2012 Digia Plc and/or its subsidiary(-ies).
5 ## Contact: http://www.qt-project.org/legal
6 ##
7 ## This file is part of the utilities of the Qt Toolkit.
8 ##
9 ## $QT_BEGIN_LICENSE:LGPL$
10 ## Commercial License Usage
11 ## Licensees holding valid commercial Qt licenses may use this file in
12 ## accordance with the commercial license agreement provided with the
13 ## Software or, alternatively, in accordance with the terms contained in
14 ## a written agreement between you and Digia.  For licensing terms and
15 ## conditions see http://qt.digia.com/licensing.  For further information
16 ## use the contact form at http://qt.digia.com/contact-us.
17 ##
18 ## GNU Lesser General Public License Usage
19 ## Alternatively, this file may be used under the terms of the GNU Lesser
20 ## General Public License version 2.1 as published by the Free Software
21 ## Foundation and appearing in the file LICENSE.LGPL included in the
22 ## packaging of this file.  Please review the following information to
23 ## ensure the GNU Lesser General Public License version 2.1 requirements
24 ## will be met: http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
25 ##
26 ## In addition, as a special exception, Digia gives you certain additional
27 ## rights.  These rights are described in the Digia Qt LGPL Exception
28 ## version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
29 ##
30 ## GNU General Public License Usage
31 ## Alternatively, this file may be used under the terms of the GNU
32 ## General Public License version 3.0 as published by the Free Software
33 ## Foundation and appearing in the file LICENSE.GPL included in the
34 ## packaging of this file.  Please review the following information to
35 ## ensure the GNU General Public License version 3.0 requirements will be
36 ## met: http://www.gnu.org/copyleft/gpl.html.
37 ##
38 ##
39 ## $QT_END_LICENSE$
40 ##
41 #############################################################################
42
43 use v5.8;
44 use strict;
45 use warnings;
46
47 package Qt::InitRepository;
48
49
50 =head1 NAME
51
52 init-repository - initialize the Qt5 repository and all submodules
53
54 =head1 SYNOPSIS
55
56   ./init-repository [options]
57
58 This script may be run after an initial `git clone' of Qt5 in order to check
59 out all submodules.
60
61
62 =head1 OPTIONS
63
64 B<Global options:>
65
66 =over
67
68 =item --force, -f
69
70 Force initialization (even if the submodules are already checked out).
71
72
73 =item --force-hooks
74
75 Force initialization of hooks (even if there are already hooks in checked out
76 submodules).
77
78
79 =item --quiet, -q
80
81 Be quiet.  Will exit cleanly if the repository is already initialized.
82
83 =back
84
85
86 B<Module options:>
87
88 =over
89
90 =item --no-webkit
91
92 Skip webkit and webkit examples submodules.
93 It may be desirable to skip these modules due to the large size of the webkit
94 git repository.
95
96 =item --module-subset=<module1>,<module2>...
97
98 Only initialize the specified subset of modules given as the argument. Specified
99 modules must already exist in .gitmodules.
100 The string "all" results in cloning all known modules. The default is the set of
101 maintained modules.
102
103 =item --no-update
104
105 Skip the `git submodule update' command.
106
107
108 =item --ignore-submodules
109
110 Set git config to ignore submodules by default when doing operations on the
111 qt5 repo, such as `pull', `fetch', `diff' etc.
112
113 After using this option, pass `--ignore-submodules=none' to git to override
114 it as needed.
115
116 =back
117
118
119 B<Repository options:>
120
121 =over
122
123 =item --berlin
124
125 Switch to internal URLs and make use of the Berlin git mirrors.
126 (Implies `--mirror').
127
128 =item --oslo
129
130 Switch to internal URLs and make use of the Oslo git mirrors.
131 (Implies `--mirror').
132
133
134 =item --http
135
136 Use the HTTP protocol for git operations.  This may be useful if the git
137 protocol is blocked by a firewall.  Note that this only works with the
138 external Gitorious server.
139
140 The `--http' option does not affect the gerrit remotes.
141
142
143 =item --codereview-username <Gerrit/JIRA username>
144
145 Specify the user name for the (potentially) writable `gerrit' remote
146 for each module, for use with the Gerrit code review tool.
147
148 If this option is omitted, the gerrit remote is created without a username
149 and port number, and thus relies on a correct SSH configuration.
150
151
152 =item --alternates <path to other Qt5 repo>
153
154 Adds alternates for each submodule to another full qt5 checkout. This makes
155 this qt5 checkout very small, as it will use the object store of the
156 alternates before unique objects are stored in its own object store.
157
158 This option has no effect when using `--no-update'.
159
160 B<NOTE:> This will make this repo dependent on the alternate, which is
161 potentially dangerous!  The dependency can be broken by also using
162 the `--copy-objects' option, or by running C<git repack -a> in each
163 submodule, where required.  Please read the note about the `--shared' option
164 in the documentation of `git clone' for more information.
165
166
167 =item --copy-objects
168
169 When `--alternates' is used, automatically do a C<git repack -a> in each
170 submodule after cloning, to ensure that the repositories are independent
171 from the source used as a reference for cloning.
172
173 Note that this negates the disk usage benefits gained from the use of
174 `--alternates'.
175
176
177 =item --mirror <url-base>
178
179 Uses <url-base> as the base URL for submodule git mirrors.
180
181 For example:
182
183   --mirror user@machine:/foo/bar
184
185 ...will use the following as a mirror for qtbase:
186
187   user@machine:/foo/bar/qt/qtbase.git
188
189 The mirror is permitted to contain a subset of the submodules; any
190 missing modules will fall back to the canonical URLs.
191
192 =back
193
194 =cut
195
196 use Carp         qw( confess             );
197 use English      qw( -no_match_vars      );
198 use Getopt::Long qw( GetOptionsFromArray );
199 use Pod::Usage   qw( pod2usage           );
200 use Cwd          qw( getcwd              );
201
202 my %PROTOCOLS = (
203     'http'      => 'http://git.gitorious.org/'     ,
204 );
205
206 my %GERRIT_REPOS = map { $_ => "qt/$_" } qw(
207     qt3d
208     qt5
209     qtactiveqt
210     qtandroidextras
211     qtbase
212     qtconnectivity
213     qtdeclarative
214     qtdoc
215     qtdocgallery
216     qtenginio
217     qtfeedback
218     qtgraphicaleffects
219     qtimageformats
220     qtjsondb
221     qtlocation
222     qtmacextras
223     qtmultimedia
224     qtpim
225     qtqa
226     qtquick1
227     qtquickcontrols
228     qtrepotools
229     qtscript
230     qtsensors
231     qtserialport
232     qtsvg
233     qtsystems
234     qttools
235     qttranslations
236     qtwayland
237     qtwebkit
238     qtwebkit-examples
239     qtwebsockets
240     qtwinextras
241     qtx11extras
242     qtxmlpatterns
243 );
244
245 my @DEFAULT_REPOS = qw(
246     qtactiveqt
247     qtandroidextras
248     qtbase
249     qtconnectivity
250     qtdeclarative
251     qtdoc
252     qtenginio
253     qtgraphicaleffects
254     qtimageformats
255     qtmacextras
256     qtmultimedia
257     qtqa
258     qtquick1
259     qtquickcontrols
260     qtlocation
261     qtrepotools
262     qtscript
263     qtsensors
264     qtserialport
265     qtsvg
266     qttools
267     qttranslations
268     qtwebsockets
269     qtwebkit
270     qtwebkit-examples
271     qtwinextras
272     qtx11extras
273     qtxmlpatterns
274 );
275
276 my $GERRIT_SSH_BASE
277     = 'ssh://@USER@codereview.qt-project.org@PORT@/';
278
279 my $BER_MIRROR_URL_BASE
280     = 'git://hegel/';
281
282 my $OSLO_MIRROR_URL_BASE
283     = 'git://qilin/';
284
285 sub new
286 {
287     my ($class, @arguments) = @_;
288
289     my $self = {};
290     bless $self, $class;
291     $self->parse_arguments(@arguments);
292
293     return $self;
294 }
295
296 # Like `system', but possibly log the command, and die on non-zero exit code
297 sub exe
298 {
299     my ($self, @cmd) = @_;
300
301     if (!$self->{quiet}) {
302         print "+ @cmd\n";
303     }
304
305     if (system(@cmd) != 0) {
306         confess "@cmd exited with status $CHILD_ERROR";
307     }
308
309     return;
310 }
311
312 sub parse_arguments
313 {
314     my ($self, @args) = @_;
315
316     %{$self} = (%{$self},
317         'alternates'          => "",
318         'codereview-username' => "",
319         'detach-alternates'   => 0 ,
320         'force'               => 0 ,
321         'force-hooks'         => 0 ,
322         'ignore-submodules'   => 0 ,
323         'mirror-url'          => "",
324         'protocol'            => "",
325         'update'              => 1 ,
326         'webkit'              => 1 ,
327         'module-subset'       => join(",", @DEFAULT_REPOS),
328     );
329
330     GetOptionsFromArray(\@args,
331         'alternates=s'      =>  \$self->{qw{ alternates        }},
332         'codereview-username=s' => \$self->{qw{ codereview-username }},
333         'copy-objects'      =>  \$self->{qw{ detach-alternates }},
334         'force|f'           =>  \$self->{qw{ force             }},
335         'force-hooks'       =>  \$self->{qw{ force-hooks       }},
336         'ignore-submodules' =>  \$self->{qw{ ignore-submodules }},
337         'mirror=s'          =>  \$self->{qw{ mirror-url        }},
338         'quiet'             =>  \$self->{qw{ quiet             }},
339         'update!'           =>  \$self->{qw{ update            }},
340         'webkit!'           =>  \$self->{qw{ webkit            }},
341         'module-subset=s'   =>  \$self->{qw{ module-subset     }},
342
343         'help|?'            =>  sub { pod2usage(1);               },
344         'http'              =>  sub { $self->{protocol} = 'http'; },
345
346         'berlin' => sub {
347             $self->{'mirror-url'}        = $BER_MIRROR_URL_BASE;
348         },
349         'oslo' => sub {
350             $self->{'mirror-url'}        = $OSLO_MIRROR_URL_BASE;
351         },
352     ) || pod2usage(2);
353
354     # Replace any double trailing slashes from end of mirror
355     $self->{'mirror-url'} =~ s{//+$}{/};
356
357     if ($self->{'module-subset'} eq "all") {
358         $self->{'module-subset'} = "";
359     } else {
360         $self->{'module-subset'} = {
361             map { $_ => 1 } split(qr{,}, $self->{'module-subset'})
362         };
363     }
364
365     return;
366 }
367
368 sub check_if_already_initialized
369 {
370     my ($self) = @_;
371
372     # We consider the repo as `initialized' if submodule.qtbase.url is set
373     if (qx(git config --get submodule.qtbase.url)) {
374         if ($self->{force}) {
375             my @configresult = qx(git config -l);
376             foreach (@configresult) {
377                 # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
378                 if (/(submodule\.[^.=]+)\.url=.*/) {
379                     $self->exe('git', 'config', '--remove-section', $1);
380                 }
381             }
382         }
383         else {
384             exit 0 if ($self->{quiet});
385             print "Will not reinitialize already initialized repository (use -f to force)!\n";
386             exit 1;
387         }
388     }
389
390     return;
391 }
392
393 sub git_submodule_init
394 {
395     my ($self) = @_;
396
397     my @init_args;
398     if ($self->{quiet}) {
399         push @init_args, '--quiet';
400     }
401     $self->exe('git', 'submodule', 'init', @init_args);
402
403     my $template = getcwd()."/.commit-template";
404     if (-e $template) {
405         $self->exe('git', 'config', 'commit.template', $template);
406     }
407
408     return;
409 }
410
411 sub git_disable_webkit_submodule
412 {
413     my ($self) = @_;
414
415     $self->exe('git', 'config', '--remove', 'submodule.qtwebkit');
416     $self->exe('git', 'config', '--remove', 'submodule.qtwebkit-examples');
417
418     return;
419 }
420
421 sub git_prune_submodules
422 {
423     my ($self) = @_;
424
425     my @configresult = qx(git config -l);
426     foreach my $line (@configresult) {
427         if ($line =~ /submodule\.([^.=]+)\.url=/) {
428             my $module_name = $1;
429             if (!$self->{'module-subset'}{$module_name}) {
430                 $self->exe('git', 'config', '--remove', "submodule.$module_name");
431             }
432         }
433     }
434 }
435
436 sub git_set_submodule_config
437 {
438     my ($self) = @_;
439
440     my @configresult          = qx(git config -l);
441     my $protocol              = $self->{protocol};
442     my $url_base_for_protocol = $PROTOCOLS{$protocol};
443
444     foreach my $line (@configresult) {
445         # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
446         next if ($line !~ /submodule\.([^.=]+)\.url=(.*)/);
447
448         my $key   = $1;
449         my $value = $2;
450
451         if ($protocol) {
452                 # rewrite URL to chosen protocol
453                 $value =~ s,^git://gitorious\.org/,$url_base_for_protocol,;
454         }
455
456         $self->exe('git', 'config', "submodule.$key.url", $value);
457
458         if ($self->{'ignore-submodules'}) {
459             $self->exe('git', 'config', "submodule.$key.ignore", 'all');
460         }
461     }
462
463     return;
464 }
465
466 sub git_clone_all_submodules
467 {
468     my ($self) = @_;
469
470     # manually clone each repo here, so we can easily use reference repos, mirrors etc
471     my @configresult = qx(git config -l);
472     foreach my $line (@configresult) {
473         if ($line =~ /submodule\.([^.=]+)\.url=(.*)/) {
474             $self->git_clone_one_submodule($1, $2);
475         }
476     }
477
478     if ($self->{update}) {
479         $self->exe('git', 'submodule', 'update', '--recursive');
480     }
481
482     return;
483 }
484
485 sub git_add_remotes
486 {
487     my ($self, $repo_basename) = @_;
488
489     my $gerrit_repo_basename = $GERRIT_REPOS{$repo_basename};
490     if ($gerrit_repo_basename) {
491         my $gerrit_repo_url;
492
493         # If given a username, make a "verbose" remote.
494         # Otherwise, rely on proper SSH configuration.
495         if ($self->{'codereview-username'}) {
496             $gerrit_repo_url = $GERRIT_SSH_BASE;
497             $gerrit_repo_url =~ s,\@USER\@,$self->{'codereview-username'}\@,;
498             $gerrit_repo_url =~ s,\@PORT\@,:29418,;
499         }
500         else {
501             $gerrit_repo_url = $GERRIT_SSH_BASE;
502             $gerrit_repo_url =~ s,\@[^\@]+\@,,g;
503         }
504
505         $gerrit_repo_url .= $gerrit_repo_basename;
506         $self->exe('git', 'config', 'remote.gerrit.url', $gerrit_repo_url);
507         $self->exe('git', 'config', 'remote.gerrit.fetch', '+refs/heads/*:refs/remotes/gerrit/*', '/heads/');
508     }
509
510     return;
511 }
512
513 sub git_clone_one_submodule
514 {
515     my ($self, $submodule, $url) = @_;
516
517     my $alternates            = $self->{ 'alternates'        };
518     my $mirror_url            = $self->{ 'mirror-url'        };
519     my $protocol              = $self->{ 'protocol'          };
520
521     # `--reference FOO' args for the clone, if any.
522     my @reference_args;
523
524     if ($alternates) {
525         # alternates is a qt5 repo, so the submodule will be under that.
526         if (-d "$alternates/$submodule") {
527             @reference_args = ('--reference', "$alternates/$submodule");
528         }
529         else {
530             print " *** $alternates/$submodule not found, ignoring alternate for this submodule\n";
531         }
532     }
533
534     my $mirror;
535     if ($mirror_url) {
536         $mirror = $mirror_url."qt/$submodule";
537         $mirror .= ".git" unless (-d $mirror); # Support local disk mirror
538     }
539
540     if ($mirror) {
541         # Only use the mirror if it can be reached.
542         eval { $self->exe('git', 'ls-remote', $mirror, 'test/if/mirror/exists') };
543         if ($@) {
544             warn "mirror [$mirror] is not accessible; $url will be used\n";
545             undef $mirror;
546         }
547     }
548
549     my $do_clone = (! -d "$submodule/.git");
550     if ($do_clone) {
551         $self->exe('git', 'clone', @reference_args, ($mirror ? $mirror : $url), $submodule);
552     }
553
554     chdir($submodule) or confess "chdir $submodule: $OS_ERROR";
555
556     $self->exe('git', 'config', 'remote.origin.url', $url);
557     if ($mirror) {
558         $self->exe('git', 'config', 'remote.mirror.url', $mirror);
559         $self->exe('git', 'config', 'remote.mirror.fetch', '+refs/heads/*:refs/remotes/mirror/*');
560     }
561
562     if (!$do_clone) {
563         $self->exe('git', 'fetch', ($mirror ? $mirror : $url));
564     }
565
566     my $template = getcwd()."/../.commit-template";
567     if (-e $template) {
568         $self->exe('git', 'config', 'commit.template', $template);
569     }
570
571     $self->git_add_remotes($submodule);
572
573     if ($self->{'detach-alternates'}) {
574         $self->exe('git', 'repack', '-a');
575
576         my $alternates_path = '.git/objects/info/alternates';
577         if (-e $alternates_path) {
578             unlink($alternates_path) || confess "unlink $alternates_path: $OS_ERROR";
579         }
580     }
581
582     chdir("..") or confess "cd ..: $OS_ERROR";
583
584     return;
585 }
586
587 sub ensure_link
588 {
589     my ($self, $src, $tgt) = @_;
590     return if (!$self->{'force-hooks'} and -f $tgt);
591     unlink($tgt); # In case we have a dead symlink or pre-existing hook
592     print "Aliasing $src\n      as $tgt ...\n" if (!$self->{quiet});
593     return if eval { symlink($src, $tgt) };
594     # Windows doesn't do (proper) symlinks. As the post_commit script needs
595     # them to locate itself, we write a forwarding script instead.
596     open SCRIPT, ">".$tgt or die "Cannot create forwarding script $tgt: $!\n";
597     print SCRIPT "#!/bin/sh\nexec `dirname \$0`/$src \"\$\@\"\n";
598     close SCRIPT;
599 }
600
601 sub git_install_hooks
602 {
603     my ($self) = @_;
604
605     return if (!-d 'qtrepotools/git-hooks');
606
607     chomp(my @modules = `git submodule foreach :`);
608     push @modules, "";
609     for my $module (@modules) {
610         $module =~ s,^Entering \'([^\']+)\'$,$1/,;
611         my $rel = $module;
612         $rel =~ s,[^/]+,..,g;
613         $rel .= "../../qtrepotools/git-hooks/";
614         $self->ensure_link($rel.'gerrit_commit_msg_hook', $module.'.git/hooks/commit-msg');
615         $self->ensure_link($rel.'git_post_commit_hook', $module.'.git/hooks/post-commit');
616     }
617 }
618
619 sub run
620 {
621     my ($self) = @_;
622
623     $self->check_if_already_initialized;
624     $self->git_submodule_init;
625
626     if (!$self->{webkit}) {
627         $self->git_disable_webkit_submodule;
628     }
629
630     if ($self->{'module-subset'}) {
631         $self->git_prune_submodules;
632     }
633
634     $self->git_set_submodule_config;
635
636     $self->git_clone_all_submodules;
637
638     $self->git_add_remotes('qt5');
639
640     $self->git_install_hooks;
641
642     return;
643 }
644
645 #==============================================================================
646
647 Qt::InitRepository->new(@ARGV)->run if (!caller);
648 1;