cc4bf02cea9da656e43c81911936a209b39104c6
[mirror/qt/qt5.git] / init-repository
1 #!/usr/bin/env perl
2 #############################################################################
3 ##
4 ## Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
5 ## Contact: http://www.qt-project.org/
6 ##
7 ## This file is part of the utilities of the Qt Toolkit.
8 ##
9 ## $QT_BEGIN_LICENSE:LGPL$
10 ## GNU Lesser General Public License Usage
11 ## This file may be used under the terms of the GNU Lesser General Public
12 ## License version 2.1 as published by the Free Software Foundation and
13 ## appearing in the file LICENSE.LGPL included in the packaging of this
14 ## file. Please review the following information to ensure the GNU Lesser
15 ## General Public License version 2.1 requirements will be met:
16 ## http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
17 ##
18 ## In addition, as a special exception, Nokia gives you certain additional
19 ## rights. These rights are described in the Nokia Qt LGPL Exception
20 ## version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
21 ##
22 ## GNU General Public License Usage
23 ## Alternatively, this file may be used under the terms of the GNU General
24 ## Public License version 3.0 as published by the Free Software Foundation
25 ## and appearing in the file LICENSE.GPL included in the packaging of this
26 ## file. Please review the following information to ensure the GNU General
27 ## Public License version 3.0 requirements will be met:
28 ## http://www.gnu.org/copyleft/gpl.html.
29 ##
30 ## Other Usage
31 ## Alternatively, this file may be used in accordance with the terms and
32 ## conditions contained in a signed written agreement between you and Nokia.
33 ##
34 ##
35 ##
36 ##
37 ##
38 ##
39 ## $QT_END_LICENSE$
40 ##
41 #############################################################################
42
43 use v5.10;
44 use strict;
45 use warnings;
46
47 package Qt::InitRepository;
48
49
50 =head1 NAME
51
52 init-repository - initialize the Qt5 repository and all submodules
53
54 =head1 SYNOPSIS
55
56   ./init-repository [options]
57
58 This script may be run after an initial `git clone' of Qt5 in order to check
59 out all submodules.
60
61
62 =head1 OPTIONS
63
64 B<Global options:>
65
66 =over
67
68 =item --force, -f
69
70 Force initialization (even if the submodules are already checked out).
71
72
73 =item --quiet, -q
74
75 Be quiet.  Will exit cleanly if the repository is already initialized.
76
77 =back
78
79
80 B<Module options:>
81
82 =over
83
84 =item --no-webkit
85
86 Skip webkit and webkit examples submodules.
87 It may be desirable to skip these modules due to the large size of the webkit
88 git repository.
89
90 =item --module-subset=<module1>,<module2>...
91
92 Only initialize the specified subset of modules given as the argument. Specified
93 modules must already exist in .gitmodules.
94
95 =item --no-update
96
97 Skip the `git submodule update' command.
98
99
100 =item --ignore-submodules
101
102 Set git config to ignore submodules by default when doing operations on the
103 qt5 repo, such as `pull', `fetch', `diff' etc.
104
105 This option is default for --nokia-developer/--brisbane.
106
107 After using this option, pass `--ignore-submodules=none' to git to override
108 it as needed.
109
110 =back
111
112
113 B<Repository options:>
114
115 =over
116
117 =item --nokia-developer
118
119 Switch to internal Nokia URLs.
120
121
122 =item --brisbane
123
124 Switch to internal Nokia URLs and make use of the Brisbane git mirrors.
125 (Implies `--mirror' and `--mirror-webkit').
126
127 =item --berlin
128
129 Switch to internal Nokia URLs and make use of the Berlin git mirrors.
130 (Implies `--mirror' and `--mirror-webkit').
131
132
133 =item --ssh
134
135 Use the SSH protocol for git operations.  This may be useful if the git
136 protocol is blocked by a firewall. Note that this requires a user account
137 with an uploaded SSH key on all servers used.  (Implies `--nokia-developer').
138
139 The `--ssh' option does not affect the gerrit remotes.
140
141
142 =item --http
143
144 Use the HTTP protocol for git operations.  This may be useful if the git
145 protocol is blocked by a firewall.  Note that this only works with the
146 external Gitorious server.
147
148 The `--http' option does not affect the gerrit remotes.
149
150
151 =item --codereview-username <Gerrit/JIRA username>
152
153 Specify the user name for the (potentially) writable `gerrit' remote
154 for each module, for use with the Gerrit code review tool.
155
156 If this option is omitted, the gerrit remote is created without a username
157 and port number, and thus relies on a correct SSH configuration.
158
159
160 =item --alternates <path to other Qt5 repo>
161
162 Adds alternates for each submodule to another full qt5 checkout. This makes
163 this qt5 checkout very small, as it will use the object store of the
164 alternates before unique objects are stored in its own object store.
165
166 This option has no effect when using `--no-update'.
167
168 B<NOTE:> This will make this repo dependent on the alternate, which is
169 potentially dangerous!  The dependency can be broken by also using
170 the `--copy-objects' option, or by running C<git repack -a> in each
171 submodule, where required.  Please read the note about the `--shared' option
172 in the documentation of `git clone' for more information.
173
174
175 =item --copy-objects
176
177 When `--alternates' is used, automatically do a C<git repack -a> in each
178 submodule after cloning, to ensure that the repositories are independent
179 from the source used as a reference for cloning.
180
181 Note that this negates the disk usage benefits gained from the use of
182 `--alternates'.
183
184
185 =item --mirror <url-base>
186
187 Uses <url-base> as the base URL for submodule git mirrors.
188
189 For example:
190
191   --mirror user@machine:/foo/bar
192
193 ...will use the following as a mirror for qtbase:
194
195   user@machine:/foo/bar/qtbase.git
196
197 The mirror is permitted to contain a subset of the submodules; any
198 missing modules will fall back to the canonical URLs.
199
200 =item --mirror-webkit <url>
201
202 Uses <url> as the URL for the webkit git mirror.
203
204 =back
205
206 =cut
207
208 use Carp         qw( confess             );
209 use English      qw( -no_match_vars      );
210 use Getopt::Long qw( GetOptionsFromArray );
211 use Pod::Usage   qw( pod2usage           );
212 use Cwd          qw( getcwd              );
213
214 my %PROTOCOLS = (
215     'internal'  => 'git://scm.dev.nokia.troll.no/' ,
216     'ssh'       => 'git@scm.dev.nokia.troll.no:'   ,
217     'http'      => 'http://git.gitorious.org/'     ,
218 );
219
220 my %GERRIT_REPOS = map { $_ => "qt/$_" } qw(
221     qt3d
222     qt5
223     qlalr
224     qtactiveqt
225     qtbase
226     qtconnectivity
227     qtdeclarative
228     qtdoc
229     qtdocgallery
230     qtfeedback
231     qtimageformats
232     qtjsondb
233     qtjsbackend
234     qtlocation
235     qtmultimedia
236     qtphonon
237     qtpim
238     qtqa
239     qtrepotools
240     qtscript
241     qtsensors
242     qtsvg
243     qtsystems
244     qttools
245     qttranslations
246     qtwayland
247     qtwebkit-examples-and-demos
248     qtxmlpatterns
249 );
250
251 my $GERRIT_SSH_BASE
252     = 'ssh://@USER@codereview.qt-project.org@PORT@/';
253
254 my $BNE_MIRROR_URL_BASE
255     = 'git://bq-git.apac.nokia.com/qtsoftware/';
256
257 my $BNE_MIRROR_WEBKIT_URL
258     = 'git://bq-git.apac.nokia.com/qtsoftware/research/gitorious-org-webkit-qtwebkit-mirror.git';
259
260 my $BER_MIRROR_URL_BASE
261     = 'git://ber-git.europe.nokia.com/';
262
263 my $BER_MIRROR_WEBKIT_URL
264     = 'git://ber-git.europe.nokia.com/qtwebkit/qtwebkit.git';
265
266
267 sub new
268 {
269     my ($class, @arguments) = @_;
270
271     my $self = {};
272     bless $self, $class;
273     $self->parse_arguments(@arguments);
274
275     return $self;
276 }
277
278 # Like `system', but possibly log the command, and die on non-zero exit code
279 sub exe
280 {
281     my ($self, @cmd) = @_;
282
283     if (!$self->{quiet}) {
284         print "+ @cmd\n";
285     }
286
287     if (system(@cmd) != 0) {
288         confess "@cmd exited with status $CHILD_ERROR";
289     }
290
291     return;
292 }
293
294 sub parse_arguments
295 {
296     my ($self, @args) = @_;
297
298     %{$self} = (%{$self},
299         'alternates'          => "",
300         'codereview-username' => "",
301         'detach-alternates'   => 0 ,
302         'force'               => 0 ,
303         'ignore-submodules'   => 0 ,
304         'mirror-url'          => "",
305         'mirror-webkit-url'   => "",
306         'nokia-developer'     => 0 ,
307         'protocol'            => "",
308         'update'              => 1 ,
309         'webkit'              => 1 ,
310         'module-subset'       => "",
311     );
312
313     GetOptionsFromArray(\@args,
314         'alternates=s'      =>  \$self->{qw{ alternates        }},
315         'codereview-username=s' => \$self->{qw{ codereview-username }},
316         'copy-objects'      =>  \$self->{qw{ detach-alternates }},
317         'force'             =>  \$self->{qw{ force             }},
318         'ignore-submodules' =>  \$self->{qw{ ignore-submodules }},
319         'mirror-webkit=s'   =>  \$self->{qw{ mirror-webkit-url }},
320         'mirror=s'          =>  \$self->{qw{ mirror-url        }},
321         'nokia-developer'   =>  \$self->{qw{ nokia-developer   }},
322         'quiet'             =>  \$self->{qw{ quiet             }},
323         'update!'           =>  \$self->{qw{ update            }},
324         'webkit!'           =>  \$self->{qw{ webkit            }},
325         'module-subset=s'   =>  \$self->{qw{ module-subset     }},
326
327         'help|?'            =>  sub { pod2usage(1);               },
328         'http'              =>  sub { $self->{protocol} = 'http'; },
329         'ssh|ssh-protocol'  =>  sub { $self->{protocol} = 'ssh';  },
330
331         'brisbane|brisbane-nokia-developer' => sub {
332             $self->{'nokia-developer'}   = 1;
333             $self->{'protocol'}          = 'internal';
334             $self->{'mirror-url'}        = $BNE_MIRROR_URL_BASE;
335             $self->{'mirror-webkit-url'} = $BNE_MIRROR_WEBKIT_URL;
336             $self->{'ignore-submodules'} = 1;
337         },
338
339         'berlin|berlin-nokia-developer' => sub {
340             $self->{'nokia-developer'}   = 1;
341             $self->{'protocol'}          = 'internal';
342             $self->{'mirror-url'}        = $BER_MIRROR_URL_BASE;
343             $self->{'mirror-webkit-url'} = $BER_MIRROR_WEBKIT_URL;
344         },
345
346         'nokia-developer' => sub {
347             $self->{'nokia-developer'}   = 1;
348             $self->{'protocol'}          = 'internal';
349             $self->{'ignore-submodules'} = 1;
350         },
351     ) || pod2usage(2);
352
353     if ($self->{'nokia-developer'} && $self->{'protocol'} eq 'http') {
354         print "*** Ignoring use of HTTP protocol, as it's only usable with external server\n";
355         $self->{'protocol'} = '';
356     }
357
358     # Replace any double trailing slashes from end of mirror
359     $self->{'mirror-url'} =~ s{//+$}{/};
360
361     if ($self->{'module-subset'}) {
362         $self->{'module-subset'} = {
363             map { $_ => 1 } split(qr{,}, $self->{'module-subset'})
364         };
365     }
366
367     return;
368 }
369
370 sub check_if_already_initialized
371 {
372     my ($self) = @_;
373
374     # We consider the repo as `initialized' if submodule.qtbase.url is set
375     if (qx(git config --get submodule.qtbase.url)) {
376         if ($self->{force}) {
377             my @configresult = qx(git config -l);
378             foreach (@configresult) {
379                 # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
380                 if (/(submodule\.[^.=]+)\.url=.*/) {
381                     $self->exe('git', 'config', '--remove-section', $1);
382                 }
383             }
384         }
385         else {
386             exit 0 if ($self->{quiet});
387             print "Will not reinitialize already initialized repository (use -f to force)!\n";
388             exit 1;
389         }
390     }
391
392     return;
393 }
394
395 sub git_submodule_init
396 {
397     my ($self) = @_;
398
399     my @init_args;
400     if ($self->{quiet}) {
401         push @init_args, '--quiet';
402     }
403     $self->exe('git', 'submodule', 'init', @init_args);
404
405     my $template = getcwd()."/.commit-template";
406     if (-e $template) {
407         $self->exe('git', 'config', 'commit.template', $template);
408     }
409
410     return;
411 }
412
413 sub git_disable_webkit_submodule
414 {
415     my ($self) = @_;
416
417     $self->exe('git', 'config', '--remove', 'submodule.qtwebkit');
418     $self->exe('git', 'config', '--remove', 'submodule.qtwebkit-examples-and-demos');
419
420     return;
421 }
422
423 sub git_prune_submodules
424 {
425     my ($self) = @_;
426
427     my @configresult = qx(git config -l);
428     foreach my $line (@configresult) {
429         if ($line =~ /submodule\.([^.=]+)\.url=/) {
430             my $module_name = $1;
431             if (!$self->{'module-subset'}{$module_name}) {
432                 $self->exe('git', 'config', '--remove', "submodule.$module_name");
433             }
434         }
435     }
436 }
437
438 sub git_set_submodule_config
439 {
440     my ($self) = @_;
441
442     my @configresult          = qx(git config -l);
443     my $protocol              = $self->{protocol};
444     my $url_base_for_protocol = $PROTOCOLS{$protocol};
445
446     foreach my $line (@configresult) {
447         # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
448         next if ($line !~ /submodule\.([^.=]+)\.url=(.*)/);
449
450         my $key   = $1;
451         my $value = $2;
452
453         if ($protocol) {
454             # WebKit is special, and has only external link.
455             if ($key ne 'qtwebkit') {
456                 # qt-labs projects are still hosted under qt internally.
457                 if ($protocol ne 'http') {
458                     $value =~ s,^git://gitorious\.org/qt-labs/,${url_base_for_protocol}qt/,;
459                 }
460
461                 # assume all other projects hosted under gitorious publicly.
462                 $value =~ s,^git://gitorious\.org/,$url_base_for_protocol,;
463             }
464         }
465
466         $self->exe('git', 'config', "submodule.$key.url", $value);
467
468         if ($self->{'ignore-submodules'}) {
469             $self->exe('git', 'config', "submodule.$key.ignore", 'all');
470         }
471     }
472
473     return;
474 }
475
476 sub git_clone_all_submodules
477 {
478     my ($self) = @_;
479
480     # manually clone each repo here, so we can easily use reference repos, mirrors etc
481     my @configresult = qx(git config -l);
482     foreach my $line (@configresult) {
483         if ($line =~ /submodule\.([^.=]+)\.url=(.*)/) {
484             $self->git_clone_one_submodule($1, $2);
485         }
486     }
487
488     if ($self->{update}) {
489         $self->exe('git', 'submodule', 'update', '--recursive');
490     }
491
492     return;
493 }
494
495 sub git_add_remotes
496 {
497     my ($self, $repo_basename) = @_;
498
499     my $gerrit_repo_basename = $GERRIT_REPOS{$repo_basename};
500     if ($gerrit_repo_basename) {
501         my $gerrit_repo_url;
502
503         # If given a username, make a "verbose" remote.
504         # Otherwise, rely on proper SSH configuration.
505         if ($self->{'codereview-username'}) {
506             $gerrit_repo_url = $GERRIT_SSH_BASE;
507             $gerrit_repo_url =~ s,\@USER\@,$self->{'codereview-username'}\@,;
508             $gerrit_repo_url =~ s,\@PORT\@,:29418,;
509         }
510         else {
511             $gerrit_repo_url = $GERRIT_SSH_BASE;
512             $gerrit_repo_url =~ s,\@[^\@]+\@,,g;
513         }
514
515         $gerrit_repo_url .= $gerrit_repo_basename;
516         $self->exe('git', 'config', 'remote.gerrit.url', $gerrit_repo_url);
517         $self->exe('git', 'config', 'remote.gerrit.fetch', '+refs/heads/*:refs/remotes/gerrit/*');
518     }
519
520     return;
521 }
522
523 sub git_clone_one_submodule
524 {
525     my ($self, $submodule, $url) = @_;
526
527     my $alternates            = $self->{ 'alternates'        };
528     my $mirror_url            = $self->{ 'mirror-url'        };
529     my $mirror_webkit_url     = $self->{ 'mirror-webkit-url' };
530     my $protocol              = $self->{ 'protocol'          };
531
532     # `--reference FOO' args for the clone, if any.
533     my @reference_args;
534
535     if ($alternates) {
536         # alternates is a qt5 repo, so the submodule will be under that.
537         if (-d "$alternates/$submodule") {
538             @reference_args = ('--reference', "$alternates/$submodule");
539         }
540         else {
541             print " *** $alternates/$submodule not found, ignoring alternate for this submodule\n";
542         }
543     }
544
545     my $mirror;
546     if ($mirror_url && ($submodule ne 'qtwebkit')) {
547         $mirror = $mirror_url."qt/$submodule";
548         $mirror .= ".git" unless (-d $mirror); # Support local disk mirror
549     }
550     elsif ($mirror_webkit_url && ($submodule eq 'qtwebkit')) {
551         $mirror = $mirror_webkit_url;
552     }
553
554     if ($mirror) {
555         # Only use the mirror if it can be reached.
556         eval { $self->exe('git', 'ls-remote', $mirror, 'test/if/mirror/exists') };
557         if ($@) {
558             warn "mirror [$mirror] is not accessible; $url will be used\n";
559             undef $mirror;
560         }
561     }
562
563     my $do_clone = (! -d "$submodule/.git");
564     if ($do_clone) {
565         $self->exe('git', 'clone', @reference_args, ($mirror ? $mirror : $url), $submodule);
566     }
567
568     chdir($submodule) or confess "chdir $submodule: $OS_ERROR";
569
570     $self->exe('git', 'config', 'remote.origin.url', $url);
571     if ($mirror) {
572         $self->exe('git', 'config', 'remote.mirror.url', $mirror);
573         $self->exe('git', 'config', 'remote.mirror.fetch', '+refs/heads/*:refs/remotes/mirror/*');
574     }
575
576     if (!$do_clone) {
577         $self->exe('git', 'fetch', ($mirror ? $mirror : $url));
578     }
579
580     my $template = getcwd()."/../.commit-template";
581     if (-e $template) {
582         $self->exe('git', 'config', 'commit.template', $template);
583     }
584
585     $self->git_add_remotes($submodule);
586
587     if ($self->{'detach-alternates'}) {
588         $self->exe('git', 'repack', '-a');
589
590         my $alternates_path = '.git/objects/info/alternates';
591         unlink($alternates_path) || confess "unlink $alternates_path: $OS_ERROR";
592     }
593
594     chdir("..") or confess "cd ..: $OS_ERROR";
595
596     return;
597 }
598
599 sub run
600 {
601     my ($self) = @_;
602
603     $self->check_if_already_initialized;
604     $self->git_submodule_init;
605
606     if (!$self->{webkit}) {
607         $self->git_disable_webkit_submodule;
608     }
609
610     if ($self->{'module-subset'}) {
611         $self->git_prune_submodules;
612     }
613
614     $self->git_set_submodule_config;
615
616     $self->git_clone_all_submodules;
617
618     $self->git_add_remotes('qt5');
619
620     return;
621 }
622
623 #==============================================================================
624
625 Qt::InitRepository->new(@ARGV)->run if (!caller);
626 1;