Add qtwebchannel as submodule
[mirror/qt/qt5.git] / init-repository
1 #!/usr/bin/env perl
2 #############################################################################
3 ##
4 ## Copyright (C) 2012 Digia Plc and/or its subsidiary(-ies).
5 ## Contact: http://www.qt-project.org/legal
6 ##
7 ## This file is part of the utilities of the Qt Toolkit.
8 ##
9 ## $QT_BEGIN_LICENSE:LGPL$
10 ## Commercial License Usage
11 ## Licensees holding valid commercial Qt licenses may use this file in
12 ## accordance with the commercial license agreement provided with the
13 ## Software or, alternatively, in accordance with the terms contained in
14 ## a written agreement between you and Digia.  For licensing terms and
15 ## conditions see http://qt.digia.com/licensing.  For further information
16 ## use the contact form at http://qt.digia.com/contact-us.
17 ##
18 ## GNU Lesser General Public License Usage
19 ## Alternatively, this file may be used under the terms of the GNU Lesser
20 ## General Public License version 2.1 as published by the Free Software
21 ## Foundation and appearing in the file LICENSE.LGPL included in the
22 ## packaging of this file.  Please review the following information to
23 ## ensure the GNU Lesser General Public License version 2.1 requirements
24 ## will be met: http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
25 ##
26 ## In addition, as a special exception, Digia gives you certain additional
27 ## rights.  These rights are described in the Digia Qt LGPL Exception
28 ## version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
29 ##
30 ## GNU General Public License Usage
31 ## Alternatively, this file may be used under the terms of the GNU
32 ## General Public License version 3.0 as published by the Free Software
33 ## Foundation and appearing in the file LICENSE.GPL included in the
34 ## packaging of this file.  Please review the following information to
35 ## ensure the GNU General Public License version 3.0 requirements will be
36 ## met: http://www.gnu.org/copyleft/gpl.html.
37 ##
38 ##
39 ## $QT_END_LICENSE$
40 ##
41 #############################################################################
42
43 use v5.8;
44 use strict;
45 use warnings;
46
47 package Qt::InitRepository;
48
49
50 =head1 NAME
51
52 init-repository - initialize the Qt5 repository and all submodules
53
54 =head1 SYNOPSIS
55
56   ./init-repository [options]
57
58 This script may be run after an initial `git clone' of Qt5 in order to check
59 out all submodules.
60
61
62 =head1 OPTIONS
63
64 B<Global options:>
65
66 =over
67
68 =item --force, -f
69
70 Force initialization (even if the submodules are already checked out).
71
72
73 =item --force-hooks
74
75 Force initialization of hooks (even if there are already hooks in checked out
76 submodules).
77
78
79 =item --quiet, -q
80
81 Be quiet.  Will exit cleanly if the repository is already initialized.
82
83 =back
84
85
86 B<Module options:>
87
88 =over
89
90 =item --no-webkit
91
92 Skip webkit and webkit examples submodules.
93 It may be desirable to skip these modules due to the large size of the webkit
94 git repository.
95
96 =item --module-subset=<module1>,<module2>...
97
98 Only initialize the specified subset of modules given as the argument. Specified
99 modules must already exist in .gitmodules.
100 The string "all" results in cloning all known modules. The default is the set of
101 maintained modules.
102
103 =item --no-update
104
105 Skip the `git submodule update' command.
106
107
108 =item --ignore-submodules
109
110 Set git config to ignore submodules by default when doing operations on the
111 qt5 repo, such as `pull', `fetch', `diff' etc.
112
113 After using this option, pass `--ignore-submodules=none' to git to override
114 it as needed.
115
116 =back
117
118
119 B<Repository options:>
120
121 =over
122
123 =item --berlin
124
125 Switch to internal URLs and make use of the Berlin git mirrors.
126 (Implies `--mirror').
127
128 =item --oslo
129
130 Switch to internal URLs and make use of the Oslo git mirrors.
131 (Implies `--mirror').
132
133
134 =item --http
135
136 Use the HTTP protocol for git operations.  This may be useful if the git
137 protocol is blocked by a firewall.  Note that this only works with the
138 external Gitorious server.
139
140 The `--http' option does not affect the gerrit remotes.
141
142
143 =item --codereview-username <Gerrit/JIRA username>
144
145 Specify the user name for the (potentially) writable `gerrit' remote
146 for each module, for use with the Gerrit code review tool.
147
148 If this option is omitted, the gerrit remote is created without a username
149 and port number, and thus relies on a correct SSH configuration.
150
151
152 =item --alternates <path to other Qt5 repo>
153
154 Adds alternates for each submodule to another full qt5 checkout. This makes
155 this qt5 checkout very small, as it will use the object store of the
156 alternates before unique objects are stored in its own object store.
157
158 This option has no effect when using `--no-update'.
159
160 B<NOTE:> This will make this repo dependent on the alternate, which is
161 potentially dangerous!  The dependency can be broken by also using
162 the `--copy-objects' option, or by running C<git repack -a> in each
163 submodule, where required.  Please read the note about the `--shared' option
164 in the documentation of `git clone' for more information.
165
166
167 =item --copy-objects
168
169 When `--alternates' is used, automatically do a C<git repack -a> in each
170 submodule after cloning, to ensure that the repositories are independent
171 from the source used as a reference for cloning.
172
173 Note that this negates the disk usage benefits gained from the use of
174 `--alternates'.
175
176
177 =item --mirror <url-base>
178
179 Uses <url-base> as the base URL for submodule git mirrors.
180
181 For example:
182
183   --mirror user@machine:/foo/bar
184
185 ...will use the following as a mirror for qtbase:
186
187   user@machine:/foo/bar/qt/qtbase.git
188
189 The mirror is permitted to contain a subset of the submodules; any
190 missing modules will fall back to the canonical URLs.
191
192 =back
193
194 =cut
195
196 use Carp         qw( confess             );
197 use English      qw( -no_match_vars      );
198 use Getopt::Long qw( GetOptionsFromArray );
199 use Pod::Usage   qw( pod2usage           );
200 use Cwd          qw( getcwd              );
201
202 my %PROTOCOLS = (
203     'http'      => 'http://git.gitorious.org/'     ,
204 );
205
206 my %GERRIT_REPOS = map { $_ => "qt/$_" } qw(
207     qt3d
208     qt5
209     qtactiveqt
210     qtandroidextras
211     qtbase
212     qtconnectivity
213     qtdeclarative
214     qtdoc
215     qtdocgallery
216     qtenginio
217     qtfeedback
218     qtgraphicaleffects
219     qtimageformats
220     qtjsondb
221     qtlocation
222     qtmacextras
223     qtmultimedia
224     qtpim
225     qtqa
226     qtquick1
227     qtquickcontrols
228     qtrepotools
229     qtscript
230     qtsensors
231     qtserialport
232     qtsvg
233     qtsystems
234     qttools
235     qttranslations
236     qtwayland
237     qtwebchannel
238     qtwebkit
239     qtwebkit-examples
240     qtwebsockets
241     qtwinextras
242     qtx11extras
243     qtxmlpatterns
244 );
245
246 my @DEFAULT_REPOS = qw(
247     qtactiveqt
248     qtandroidextras
249     qtbase
250     qtconnectivity
251     qtdeclarative
252     qtdoc
253     qtenginio
254     qtgraphicaleffects
255     qtimageformats
256     qtmacextras
257     qtmultimedia
258     qtqa
259     qtquick1
260     qtquickcontrols
261     qtlocation
262     qtrepotools
263     qtscript
264     qtsensors
265     qtserialport
266     qtsvg
267     qttools
268     qttranslations
269     qtwebchannel
270     qtwebsockets
271     qtwebkit
272     qtwebkit-examples
273     qtwinextras
274     qtx11extras
275     qtxmlpatterns
276 );
277
278 my $GERRIT_SSH_BASE
279     = 'ssh://@USER@codereview.qt-project.org@PORT@/';
280
281 my $BER_MIRROR_URL_BASE
282     = 'git://hegel/';
283
284 my $OSLO_MIRROR_URL_BASE
285     = 'git://qilin/';
286
287 sub new
288 {
289     my ($class, @arguments) = @_;
290
291     my $self = {};
292     bless $self, $class;
293     $self->parse_arguments(@arguments);
294
295     return $self;
296 }
297
298 # Like `system', but possibly log the command, and die on non-zero exit code
299 sub exe
300 {
301     my ($self, @cmd) = @_;
302
303     if (!$self->{quiet}) {
304         print "+ @cmd\n";
305     }
306
307     if (system(@cmd) != 0) {
308         confess "@cmd exited with status $CHILD_ERROR";
309     }
310
311     return;
312 }
313
314 sub parse_arguments
315 {
316     my ($self, @args) = @_;
317
318     %{$self} = (%{$self},
319         'alternates'          => "",
320         'codereview-username' => "",
321         'detach-alternates'   => 0 ,
322         'force'               => 0 ,
323         'force-hooks'         => 0 ,
324         'ignore-submodules'   => 0 ,
325         'mirror-url'          => "",
326         'protocol'            => "",
327         'update'              => 1 ,
328         'webkit'              => 1 ,
329         'module-subset'       => join(",", @DEFAULT_REPOS),
330     );
331
332     GetOptionsFromArray(\@args,
333         'alternates=s'      =>  \$self->{qw{ alternates        }},
334         'codereview-username=s' => \$self->{qw{ codereview-username }},
335         'copy-objects'      =>  \$self->{qw{ detach-alternates }},
336         'force|f'           =>  \$self->{qw{ force             }},
337         'force-hooks'       =>  \$self->{qw{ force-hooks       }},
338         'ignore-submodules' =>  \$self->{qw{ ignore-submodules }},
339         'mirror=s'          =>  \$self->{qw{ mirror-url        }},
340         'quiet'             =>  \$self->{qw{ quiet             }},
341         'update!'           =>  \$self->{qw{ update            }},
342         'webkit!'           =>  \$self->{qw{ webkit            }},
343         'module-subset=s'   =>  \$self->{qw{ module-subset     }},
344
345         'help|?'            =>  sub { pod2usage(1);               },
346         'http'              =>  sub { $self->{protocol} = 'http'; },
347
348         'berlin' => sub {
349             $self->{'mirror-url'}        = $BER_MIRROR_URL_BASE;
350         },
351         'oslo' => sub {
352             $self->{'mirror-url'}        = $OSLO_MIRROR_URL_BASE;
353         },
354     ) || pod2usage(2);
355
356     # Replace any double trailing slashes from end of mirror
357     $self->{'mirror-url'} =~ s{//+$}{/};
358
359     if ($self->{'module-subset'} eq "all") {
360         $self->{'module-subset'} = "";
361     } else {
362         $self->{'module-subset'} = {
363             map { $_ => 1 } split(qr{,}, $self->{'module-subset'})
364         };
365     }
366
367     return;
368 }
369
370 sub check_if_already_initialized
371 {
372     my ($self) = @_;
373
374     # We consider the repo as `initialized' if submodule.qtbase.url is set
375     if (qx(git config --get submodule.qtbase.url)) {
376         if ($self->{force}) {
377             my @configresult = qx(git config -l);
378             foreach (@configresult) {
379                 # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
380                 if (/(submodule\.[^.=]+)\.url=.*/) {
381                     $self->exe('git', 'config', '--remove-section', $1);
382                 }
383             }
384         }
385         else {
386             exit 0 if ($self->{quiet});
387             print "Will not reinitialize already initialized repository (use -f to force)!\n";
388             exit 1;
389         }
390     }
391
392     return;
393 }
394
395 sub git_submodule_init
396 {
397     my ($self) = @_;
398
399     my @init_args;
400     if ($self->{quiet}) {
401         push @init_args, '--quiet';
402     }
403     $self->exe('git', 'submodule', 'init', @init_args);
404
405     my $template = getcwd()."/.commit-template";
406     if (-e $template) {
407         $self->exe('git', 'config', 'commit.template', $template);
408     }
409
410     return;
411 }
412
413 sub git_disable_webkit_submodule
414 {
415     my ($self) = @_;
416
417     $self->exe('git', 'config', '--remove', 'submodule.qtwebkit');
418     $self->exe('git', 'config', '--remove', 'submodule.qtwebkit-examples');
419
420     return;
421 }
422
423 sub git_prune_submodules
424 {
425     my ($self) = @_;
426
427     my @configresult = qx(git config -l);
428     foreach my $line (@configresult) {
429         if ($line =~ /submodule\.([^.=]+)\.url=/) {
430             my $module_name = $1;
431             if (!$self->{'module-subset'}{$module_name}) {
432                 $self->exe('git', 'config', '--remove', "submodule.$module_name");
433             }
434         }
435     }
436 }
437
438 sub git_set_submodule_config
439 {
440     my ($self) = @_;
441
442     my @configresult          = qx(git config -l);
443     my $protocol              = $self->{protocol};
444     my $url_base_for_protocol = $PROTOCOLS{$protocol};
445
446     foreach my $line (@configresult) {
447         # Example line: submodule.qtqa.url=git://gitorious.org/qt/qtqa.git
448         next if ($line !~ /submodule\.([^.=]+)\.url=(.*)/);
449
450         my $key   = $1;
451         my $value = $2;
452
453         if ($protocol) {
454                 # rewrite URL to chosen protocol
455                 $value =~ s,^git://gitorious\.org/,$url_base_for_protocol,;
456         }
457
458         $self->exe('git', 'config', "submodule.$key.url", $value);
459
460         if ($self->{'ignore-submodules'}) {
461             $self->exe('git', 'config', "submodule.$key.ignore", 'all');
462         }
463     }
464
465     return;
466 }
467
468 sub git_clone_all_submodules
469 {
470     my ($self) = @_;
471
472     # manually clone each repo here, so we can easily use reference repos, mirrors etc
473     my @configresult = qx(git config -l);
474     foreach my $line (@configresult) {
475         if ($line =~ /submodule\.([^.=]+)\.url=(.*)/) {
476             $self->git_clone_one_submodule($1, $2);
477         }
478     }
479
480     if ($self->{update}) {
481         $self->exe('git', 'submodule', 'update', '--recursive');
482     }
483
484     return;
485 }
486
487 sub git_add_remotes
488 {
489     my ($self, $repo_basename) = @_;
490
491     my $gerrit_repo_basename = $GERRIT_REPOS{$repo_basename};
492     if ($gerrit_repo_basename) {
493         my $gerrit_repo_url;
494
495         # If given a username, make a "verbose" remote.
496         # Otherwise, rely on proper SSH configuration.
497         if ($self->{'codereview-username'}) {
498             $gerrit_repo_url = $GERRIT_SSH_BASE;
499             $gerrit_repo_url =~ s,\@USER\@,$self->{'codereview-username'}\@,;
500             $gerrit_repo_url =~ s,\@PORT\@,:29418,;
501         }
502         else {
503             $gerrit_repo_url = $GERRIT_SSH_BASE;
504             $gerrit_repo_url =~ s,\@[^\@]+\@,,g;
505         }
506
507         $gerrit_repo_url .= $gerrit_repo_basename;
508         $self->exe('git', 'config', 'remote.gerrit.url', $gerrit_repo_url);
509         $self->exe('git', 'config', 'remote.gerrit.fetch', '+refs/heads/*:refs/remotes/gerrit/*', '/heads/');
510     }
511
512     return;
513 }
514
515 sub git_clone_one_submodule
516 {
517     my ($self, $submodule, $url) = @_;
518
519     my $alternates            = $self->{ 'alternates'        };
520     my $mirror_url            = $self->{ 'mirror-url'        };
521     my $protocol              = $self->{ 'protocol'          };
522
523     # `--reference FOO' args for the clone, if any.
524     my @reference_args;
525
526     if ($alternates) {
527         # alternates is a qt5 repo, so the submodule will be under that.
528         if (-d "$alternates/$submodule") {
529             @reference_args = ('--reference', "$alternates/$submodule");
530         }
531         else {
532             print " *** $alternates/$submodule not found, ignoring alternate for this submodule\n";
533         }
534     }
535
536     my $mirror;
537     if ($mirror_url) {
538         $mirror = $mirror_url."qt/$submodule";
539         $mirror .= ".git" unless (-d $mirror); # Support local disk mirror
540     }
541
542     if ($mirror) {
543         # Only use the mirror if it can be reached.
544         eval { $self->exe('git', 'ls-remote', $mirror, 'test/if/mirror/exists') };
545         if ($@) {
546             warn "mirror [$mirror] is not accessible; $url will be used\n";
547             undef $mirror;
548         }
549     }
550
551     my $do_clone = (! -d "$submodule/.git");
552     if ($do_clone) {
553         $self->exe('git', 'clone', @reference_args, ($mirror ? $mirror : $url), $submodule);
554     }
555
556     chdir($submodule) or confess "chdir $submodule: $OS_ERROR";
557
558     $self->exe('git', 'config', 'remote.origin.url', $url);
559     if ($mirror) {
560         $self->exe('git', 'config', 'remote.mirror.url', $mirror);
561         $self->exe('git', 'config', 'remote.mirror.fetch', '+refs/heads/*:refs/remotes/mirror/*');
562     }
563
564     if (!$do_clone) {
565         $self->exe('git', 'fetch', ($mirror ? $mirror : $url));
566     }
567
568     my $template = getcwd()."/../.commit-template";
569     if (-e $template) {
570         $self->exe('git', 'config', 'commit.template', $template);
571     }
572
573     $self->git_add_remotes($submodule);
574
575     if ($self->{'detach-alternates'}) {
576         $self->exe('git', 'repack', '-a');
577
578         my $alternates_path = '.git/objects/info/alternates';
579         if (-e $alternates_path) {
580             unlink($alternates_path) || confess "unlink $alternates_path: $OS_ERROR";
581         }
582     }
583
584     chdir("..") or confess "cd ..: $OS_ERROR";
585
586     return;
587 }
588
589 sub ensure_link
590 {
591     my ($self, $src, $tgt) = @_;
592     return if (!$self->{'force-hooks'} and -f $tgt);
593     unlink($tgt); # In case we have a dead symlink or pre-existing hook
594     print "Aliasing $src\n      as $tgt ...\n" if (!$self->{quiet});
595     return if eval { symlink($src, $tgt) };
596     # Windows doesn't do (proper) symlinks. As the post_commit script needs
597     # them to locate itself, we write a forwarding script instead.
598     open SCRIPT, ">".$tgt or die "Cannot create forwarding script $tgt: $!\n";
599     print SCRIPT "#!/bin/sh\nexec `dirname \$0`/$src \"\$\@\"\n";
600     close SCRIPT;
601 }
602
603 sub git_install_hooks
604 {
605     my ($self) = @_;
606
607     return if (!-d 'qtrepotools/git-hooks');
608
609     chomp(my @modules = `git submodule foreach :`);
610     push @modules, "";
611     for my $module (@modules) {
612         $module =~ s,^Entering \'([^\']+)\'$,$1/,;
613         my $rel = $module;
614         $rel =~ s,[^/]+,..,g;
615         $rel .= "../../qtrepotools/git-hooks/";
616         $self->ensure_link($rel.'gerrit_commit_msg_hook', $module.'.git/hooks/commit-msg');
617         $self->ensure_link($rel.'git_post_commit_hook', $module.'.git/hooks/post-commit');
618     }
619 }
620
621 sub run
622 {
623     my ($self) = @_;
624
625     $self->check_if_already_initialized;
626     $self->git_submodule_init;
627
628     if (!$self->{webkit}) {
629         $self->git_disable_webkit_submodule;
630     }
631
632     if ($self->{'module-subset'}) {
633         $self->git_prune_submodules;
634     }
635
636     $self->git_set_submodule_config;
637
638     $self->git_clone_all_submodules;
639
640     $self->git_add_remotes('qt5');
641
642     $self->git_install_hooks;
643
644     return;
645 }
646
647 #==============================================================================
648
649 Qt::InitRepository->new(@ARGV)->run if (!caller);
650 1;