Updated WebKit import
[mirror/qt/qt5.git] / qt.pro
1 TEMPLATE      = subdirs
2
3 module_qtbase.subdir = $$IN_PWD/qtbase
4 module_qtbase.target = module-qtbase
5
6 module_qtsvg.subdir = $$IN_PWD/qtsvg
7 module_qtsvg.target = module-qtsvg
8 module_qtsvg.depends = module_qtbase
9
10 module_qtphonon.subdir = $$IN_PWD/qtphonon
11 module_qtphonon.target = module-qtphonon
12 module_qtphonon.depends = module_qtbase
13
14 module_qtxmlpatterns.subdir = $$IN_PWD/qtxmlpatterns
15 module_qtxmlpatterns.target = module-qtxmlpatterns
16 module_qtxmlpatterns.depends = module_qtbase
17
18 module_qtscript.subdir = $$IN_PWD/qtscript
19 module_qtscript.target = module-qtscript
20 module_qtscript.depends = module_qtbase
21
22 module_qtdeclarative.subdir = $$IN_PWD/qtdeclarative
23 module_qtdeclarative.target = module-qtdeclarative
24 module_qtdeclarative.depends = module_qtbase module_qtxmlpatterns
25
26 module_qtwebkit.file = qtwebkit.pri
27 module_qtwebkit.makefile = Makefile.qtwebkit
28 module_qtwebkit.depends = module_qtbase module_qtscript module_qtdeclarative
29 # The qtwebkit subdir does not follow the "module-*" scheme, so make our own target that does.
30 module_qtwebkit_target.target = module-qtwebkit
31 module_qtwebkit_target.commands =
32 module_qtwebkit_target.depends = sub-qtwebkit-pri
33 QMAKE_EXTRA_TARGETS += module_qtwebkit_target
34
35 module_qtwebkit_examples_and_demos.subdir = $$IN_PWD/qtwebkit-examples-and-demos
36 module_qtwebkit_examples_and_demos.target = module-qtwebkit-examples-and-demos
37 module_qtwebkit_examples_and_demos.depends = module_qtwebkit
38
39 module_qttools.subdir = $$IN_PWD/qttools
40 module_qttools.target = module-qttools
41 module_qttools.depends = module_qtbase module_qtscript module_qtdeclarative
42 win32:module_qttools.depends += module_qtactiveqt
43
44 module_qttranslations.subdir = $$IN_PWD/qttranslations
45 module_qttranslations.target = module-qttranslations
46 module_qttranslations.depends = module_qttools
47
48 module_qtdoc.subdir = $$IN_PWD/qtdoc
49 module_qtdoc.target = module-qtdoc
50 module_qtdoc.depends = module_qtbase module_qtdeclarative
51
52 module_qtactiveqt.subdir = $$IN_PWD/qtactiveqt
53 module_qtactiveqt.target = module-qtactiveqt
54 module_qtactiveqt.depends = module_qtbase
55
56 module_qlalr.subdir = $$IN_PWD/qlalr
57 module_qlalr.target = module-qlalr
58 module_qlalr.depends = module_qtbase
59
60 module_qtqa.subdir = $$IN_PWD/qtqa
61 module_qtqa.target = module-qtqa
62 module_qtqa.depends = module_qtbase
63
64 module_qtlocation.subdir = $$IN_PWD/qtlocation
65 module_qtlocation.target = module-qtlocation
66 module_qtlocation.depends = module_qtbase module_qtdeclarative module_qtquick3d
67
68 module_qtsensors.subdir = $$IN_PWD/qtsensors
69 module_qtsensors.target = module-qtsensors
70 module_qtsensors.depends = module_qtbase module_qtdeclarative
71
72 module_qtsystems.subdir = $$IN_PWD/qtsystems
73 module_qtsystems.target = module-qtsystems
74 module_qtsystems.depends = module_qtbase module_qtdeclarative
75
76 module_qtmultimedia.subdir = $$IN_PWD/qtmultimedia
77 module_qtmultimedia.target = module-qtmultimedia
78 module_qtmultimedia.depends = module_qtbase module_qtdeclarative
79
80 module_qtfeedback.subdir = $$IN_PWD/qtfeedback
81 module_qtfeedback.target = module-qtfeedback
82 module_qtfeedback.depends = module_qtbase module_qtmultimedia module_qtdeclarative
83
84 module_qt3d.subdir = $$IN_PWD/qt3d
85 module_qt3d.target = module-qt3d
86 module_qt3d.depends = module_qtbase module_qtdeclarative
87 # not yet enabled by default (enable it when removing qtquick3d)
88 module_qt3d.CONFIG = no_default_target no_default_install
89
90 module_qtquick3d.subdir = $$IN_PWD/qtquick3d
91 module_qtquick3d.target = module-qtquick3d
92 module_qtquick3d.depends = $${module_qt3d.depends}
93
94 module_qtdocgallery.subdir = $$IN_PWD/qtdocgallery
95 module_qtdocgallery.target = module-qtdocgallery
96 module_qtdocgallery.depends = module_qtbase module_qtscript module_qtdeclarative
97
98 module_qtpim.subdir = $$IN_PWD/qtpim
99 module_qtpim.target = module-qtpim
100 module_qtpim.depends = module_qtdeclarative
101
102 module_qtconnectivity.subdir = $$IN_PWD/qtconnectivity
103 module_qtconnectivity.target = module-qtconnectivity
104 module_qtconnectivity.depends = module_qtsystems
105
106 module_qtwayland.subdir = $$IN_PWD/qtwayland
107 module_qtwayland.target = module-qtwayland
108 module_qtwayland.depends = module_qtbase
109 # not yet enabled by default
110 module_qtwayland.CONFIG = no_default_target no_default_install
111
112 module_qtjsondb.subdir = $$IN_PWD/qtjsondb
113 module_qtjsondb.target = module-qtjsondb
114 module_qtjsondb.depends = module_qtbase module_qtdeclarative module_qtxmlpatterns
115 # not yet enabled by default
116 module_qtjsondb.CONFIG = no_default_target no_default_install
117
118 # only qtbase is required to exist. The others may not - but it is the
119 # users responsibility to ensure that all needed dependencies exist, or
120 # it may not build.
121
122 SUBDIRS = module_qtbase
123
124 exists(qtsvg/qtsvg.pro): SUBDIRS += module_qtsvg
125 exists(qtphonon/qtphonon.pro): SUBDIRS += module_qtphonon
126 exists(qtxmlpatterns/qtxmlpatterns.pro): SUBDIRS += module_qtxmlpatterns
127 exists(qtscript/qtscript.pro): SUBDIRS += module_qtscript
128 exists(qtdeclarative/qtdeclarative.pro): SUBDIRS += module_qtdeclarative
129 exists(qttools/qttools.pro): SUBDIRS += module_qttools
130 exists(qttranslations/qttranslations.pro): SUBDIRS += module_qttranslations
131 exists(qtdoc/qtdoc.pro): SUBDIRS += module_qtdoc
132 exists(qlalr/qlalr.pro): SUBDIRS += module_qlalr
133 exists(qtqa/qtqa.pro): SUBDIRS += module_qtqa
134 exists(qtlocation/qtlocation.pro): SUBDIRS += module_qtlocation
135 exists(qtactiveqt/qtactiveqt.pro): SUBDIRS += module_qtactiveqt
136 exists(qtsensors/qtsensors.pro): SUBDIRS += module_qtsensors
137 exists(qtsystems/qtsystems.pro): SUBDIRS += module_qtsystems
138 exists(qtmultimedia/qtmultimedia.pro): SUBDIRS += module_qtmultimedia
139 exists(qtfeedback/qtfeedback.pro): SUBDIRS += module_qtfeedback
140 exists(qtquick3d/qtquick3d.pro): SUBDIRS += module_qtquick3d
141 exists(qt3d/qt3d.pro): SUBDIRS += module_qt3d
142 exists(qtdocgallery/qtdocgallery.pro): SUBDIRS += module_qtdocgallery
143 exists(qtpim/qtpim.pro): SUBDIRS += module_qtpim
144 exists(qtconnectivity/qtconnectivity.pro): SUBDIRS += module_qtconnectivity
145 exists(qtwayland/qtwayland.pro): SUBDIRS += module_qtwayland
146 exists(qtjsondb/qtjsondb.pro): SUBDIRS += module_qtjsondb
147
148 exists(qtwebkit/Tools/Scripts/build-webkit) {
149     SUBDIRS +=  module_qtwebkit \
150                 module_qtwebkit_examples_and_demos
151     module_qttools.depends += module_qtwebkit
152 }