ca65d2ebd09079eac536bd0fc9e35991e96c9d6d
[mirror/qt/qt5.git] / qt.pro
1 TEMPLATE      = subdirs
2
3 module_qtbase.subdir = $$IN_PWD/qtbase
4 module_qtbase.target = module-qtbase
5
6 module_qtsvg.subdir = $$IN_PWD/qtsvg
7 module_qtsvg.target = module-qtsvg
8 module_qtsvg.depends = module_qtbase
9
10 module_qtphonon.subdir = $$IN_PWD/qtphonon
11 module_qtphonon.target = module-qtphonon
12 module_qtphonon.depends = module_qtbase
13
14 module_qtmultimedia.subdir = $$IN_PWD/qtmultimedia
15 module_qtmultimedia.target = module-qtmultimedia
16 module_qtmultimedia.depends = module_qtbase
17
18 module_qtxmlpatterns.subdir = $$IN_PWD/qtxmlpatterns
19 module_qtxmlpatterns.target = module-qtxmlpatterns
20 module_qtxmlpatterns.depends = module_qtbase
21
22 module_qtscript.subdir = $$IN_PWD/qtscript
23 module_qtscript.target = module-qtscript
24 module_qtscript.depends = module_qtbase
25
26 module_qtdeclarative.subdir = $$IN_PWD/qtdeclarative
27 module_qtdeclarative.target = module-qtdeclarative
28 module_qtdeclarative.depends = module_qtbase module_qtscript module_qtsvg module_qtxmlpatterns
29
30 module_qt3support.subdir = $$IN_PWD/qt3support
31 module_qt3support.target = module-qt3support
32 module_qt3support.depends = module_qtbase
33
34 module_qtwebkit.file = qtwebkit.pri
35 module_qtwebkit.makefile = Makefile.qtwebkit
36 module_qtwebkit.depends = module_qtbase module_qtscript module_qtdeclarative module_phonon
37 # The qtwebkit subdir does not follow the "module-*" scheme, so make our own target that does.
38 module_qtwebkit_target.target = module-qtwebkit
39 module_qtwebkit_target.commands =
40 module_qtwebkit_target.depends = sub-qtwebkit-pri
41 QMAKE_EXTRA_TARGETS += module_qtwebkit_target
42
43 module_qtwebkit_examples_and_demos.subdir = $$IN_PWD/qtwebkit-examples-and-demos
44 module_qtwebkit_examples_and_demos.target = module-qtwebkit-examples-and-demos
45 module_qtwebkit_examples_and_demos.depends = module_qtwebkit
46
47 module_qttools.subdir = $$IN_PWD/qttools
48 module_qttools.target = module-qttools
49 module_qttools.depends = module_qtbase module_qtscript module_qtdeclarative module_qt3support
50 win32:module_qttools.depends += module_activeqt
51
52 module_qttranslations.subdir = $$IN_PWD/qttranslations
53 module_qttranslations.target = module-qttranslations
54 module_qttranslations.depends = module_qttools
55
56 module_qtdoc.subdir = $$IN_PWD/qtdoc
57 module_qtdoc.target = module-qtdoc
58 module_qtdoc.depends = module_qtdeclarative module_qttools #for the demos and QtHelp
59
60 module_qtactiveqt.subdir = $$IN_PWD/qtactiveqt
61 module_qtactiveqt.target = module-qtactiveqt
62 module_qtactiveqt.depends = module_qtbase
63
64 module_qlalr.subdir = $$IN_PWD/qlalr
65 module_qlalr.target = module-qlalr
66 module_qlalr.depends = module-qtbase
67
68 module_qtqa.subdir = $$IN_PWD/qtqa
69 module_qtqa.target = module-qtqa
70 module_qtqa.depends = module-qtbase
71
72 SUBDIRS       = \
73                 module_qtbase \
74                 module_qtsvg \
75                 module_qtphonon \
76                 module_qtxmlpatterns \
77                 module_qtscript \
78                 module_qtdeclarative \
79                 module_qt3support \
80                 module_qtmultimedia \
81                 module_qttools \
82                 module_qttranslations \
83                 module_qtdoc \
84                 module_qlalr \
85                 module_qtqa \
86
87 exists(qtwebkit/Tools/Scripts/build-webkit) {
88     SUBDIRS +=  module_qtwebkit \
89                 module_qtwebkit_examples_and_demos
90     module_qttools.depends += module_qtwebkit
91 }
92 win32:SUBDIRS += module_qtactiveqt