edaf37b1ab66274323424e8dd56eee5972b50197
[mirror/qt/qt5.git] / qt.pro
1 # Create the super cache so modules will add themselves to it.
2 cache(, super)
3
4 TEMPLATE      = subdirs
5
6 CONFIG += prepare_docs
7
8 module_qtbase.subdir = qtbase
9 module_qtbase.target = module-qtbase
10
11 module_qtsvg.subdir = qtsvg
12 module_qtsvg.target = module-qtsvg
13 module_qtsvg.depends = module_qtbase
14
15 module_qtxmlpatterns.subdir = qtxmlpatterns
16 module_qtxmlpatterns.target = module-qtxmlpatterns
17 module_qtxmlpatterns.depends = module_qtbase
18
19 module_qtscript.subdir = qtscript
20 module_qtscript.target = module-qtscript
21 module_qtscript.depends = module_qtbase
22
23 module_qtjsbackend.subdir = qtjsbackend
24 module_qtjsbackend.target = module-qtjsbackend
25 module_qtjsbackend.depends = module_qtbase
26
27 module_qtdeclarative.subdir = qtdeclarative
28 module_qtdeclarative.target = module-qtdeclarative
29 module_qtdeclarative.depends = module_qtbase module_qtjsbackend
30
31 module_qtwebkit.file = qtwebkit/WebKit.pro
32 module_qtwebkit.depends = module_qtbase module_qtdeclarative
33 module_qtwebkit.target = module-qtwebkit
34
35 module_qtwebkit_examples_and_demos.subdir = qtwebkit-examples-and-demos
36 module_qtwebkit_examples_and_demos.target = module-qtwebkit-examples-and-demos
37 module_qtwebkit_examples_and_demos.depends = module_qtwebkit module_qttools
38
39 module_qttools.subdir = qttools
40 module_qttools.target = module-qttools
41 module_qttools.depends = module_qtbase
42
43 module_qttranslations.subdir = qttranslations
44 module_qttranslations.target = module-qttranslations
45 module_qttranslations.depends = module_qttools
46
47 module_qtdoc.subdir = qtdoc
48 module_qtdoc.target = module-qtdoc
49 module_qtdoc.depends = module_qtbase module_qtdeclarative
50
51 module_qtactiveqt.subdir = qtactiveqt
52 module_qtactiveqt.target = module-qtactiveqt
53 module_qtactiveqt.depends = module_qtbase
54
55 module_qlalr.subdir = qlalr
56 module_qlalr.target = module-qlalr
57 module_qlalr.depends = module_qtbase
58
59 module_qtqa.subdir = qtqa
60 module_qtqa.target = module-qtqa
61 module_qtqa.depends = module_qtbase
62
63 module_qtlocation.subdir = qtlocation
64 module_qtlocation.target = module-qtlocation
65 module_qtlocation.depends = module_qtbase
66
67 module_qtsensors.subdir = qtsensors
68 module_qtsensors.target = module-qtsensors
69 module_qtsensors.depends = module_qtbase
70
71 module_qtsystems.subdir = qtsystems
72 module_qtsystems.target = module-qtsystems
73 module_qtsystems.depends = module_qtbase
74
75 module_qtmultimedia.subdir = qtmultimedia
76 module_qtmultimedia.target = module-qtmultimedia
77 module_qtmultimedia.depends = module_qtbase
78
79 module_qtfeedback.subdir = qtfeedback
80 module_qtfeedback.target = module-qtfeedback
81 module_qtfeedback.depends = module_qtbase module_qtdeclarative
82
83 module_qt3d.subdir = qt3d
84 module_qt3d.target = module-qt3d
85 module_qt3d.depends = module_qtbase module_qtdeclarative
86
87 module_qtpim.subdir = qtpim
88 module_qtpim.target = module-qtpim
89 module_qtpim.depends = module_qtdeclarative
90
91 module_qtconnectivity.subdir = qtconnectivity
92 module_qtconnectivity.target = module-qtconnectivity
93 module_qtconnectivity.depends = module_qtsystems
94
95 module_qtwayland.subdir = qtwayland
96 module_qtwayland.target = module-qtwayland
97 module_qtwayland.depends = module_qtbase
98 # not yet enabled by default
99 module_qtwayland.CONFIG = no_default_target no_default_install
100
101 module_qtimageformats.subdir = qtimageformats
102 module_qtimageformats.target = module-qtimageformats
103 module_qtimageformats.depends = module_qtbase
104
105 module_qtquick1.subdir = qtquick1
106 module_qtquick1.target = module-qtquick1
107 module_qtquick1.depends = module_qtbase module_qtscript
108
109 module_qtgraphicaleffects.subdir = qtgraphicaleffects
110 module_qtgraphicaleffects.target = module-qtgraphicaleffects
111 module_qtgraphicaleffects.depends = module_qtbase module_qtdeclarative
112
113 # only qtbase is required to exist. The others may not - but it is the
114 # users responsibility to ensure that all needed dependencies exist, or
115 # it may not build.
116
117 SUBDIRS = module_qtbase
118
119 exists(qtsvg/qtsvg.pro) {
120     SUBDIRS += module_qtsvg
121     # These modules do not require qtsvg, but can use it if it is available
122     module_qtdeclarative.depends += module_qtsvg
123     module_qtquick1.depends += module_qtsvg
124 }
125 exists(qtxmlpatterns/qtxmlpatterns.pro) {
126     SUBDIRS += module_qtxmlpatterns
127     # These modules do not require qtxmlpatterns, but can use it if it is available
128     module_qtdeclarative.depends += module_qtxmlpatterns
129     module_qtquick1.depends += module_qtxmlpatterns
130 }
131
132 exists(qtjsbackend/qtjsbackend.pro): SUBDIRS += module_qtjsbackend
133 exists(qtdeclarative/qtdeclarative.pro) {
134     SUBDIRS += module_qtdeclarative
135     # These modules do not require qtdeclarative, but can use it if it is available
136     module_qttools.depends += module_qtdeclarative
137     module_qtsensors.depends += module_qtdeclarative
138     module_qtsystems.depends += module_qtdeclarative
139     module_qtmultimedia.depends += module_qtdeclarative
140     module_qtwayland.depends += module_qtdeclarative
141 }
142 exists(qt3d/qt3d.pro) {
143     SUBDIRS += module_qt3d
144     # These modules do not require qt3d, but can use it if it is available
145     module_qtlocation.depends += module_qtdeclarative module_qt3d
146 }
147 exists(qtscript/qtscript.pro): SUBDIRS += module_qtscript
148 exists(qtlocation/qtlocation.pro) {
149     SUBDIRS += module_qtlocation
150     # These modules do not require qtlocation, but can use it if it is available
151     module_qtwebkit.depends += module_qtlocation
152 }
153 exists(qtsensors/qtsensors.pro) {
154     SUBDIRS += module_qtsensors
155     # These modules do not require qtsensors, but can use it if it is available
156     module_qtwebkit.depends += module_qtsensors
157 }
158 exists(qtsystems/qtsystems.pro) {
159     SUBDIRS += module_qtsystems
160     # These modules do not require qtsystems, but can use it if it is available
161     module_qtlocation.depends += module_qtsystems
162 }
163 exists(qtmultimedia/qtmultimedia.pro) {
164     SUBDIRS += module_qtmultimedia
165     # These modules do not require qtmultimedia, but can use it if it is available
166     module_qtfeedback.depends += module_qtmultimedia
167     module_qtlocation.depends += module_qtmultimedia
168 }
169 exists(qtfeedback/qtfeedback.pro): SUBDIRS += module_qtfeedback
170 exists(qtpim/qtpim.pro): SUBDIRS += module_qtpim
171 exists(qtconnectivity/qtconnectivity.pro): SUBDIRS += module_qtconnectivity
172 exists(qtactiveqt/qtactiveqt.pro) {
173     SUBDIRS += module_qtactiveqt
174     module_qttools.depends += module_qtactiveqt
175 }
176 exists(qtwebkit/WebKit.pro) {
177     mac|contains(QT_CONFIG, icu) {
178         SUBDIRS += module_qtwebkit
179         module_qttools.depends += module_qtwebkit
180         module_qtquick1.depends += module_qtwebkit
181         exists(qtwebkit-examples-and-demos/qtwebkit-examples-and-demos.pro) {
182             SUBDIRS += module_qtwebkit_examples_and_demos
183         }
184     } else {
185         message("WebKit: Qt was built without ICU support, WebKit disabled.")
186     }
187 }
188 exists(qttools/qttools.pro) {
189     SUBDIRS += module_qttools
190     module_qtquick1.depends += module_qttools
191 }
192 exists(qtquick1/qtquick1.pro): SUBDIRS += module_qtquick1
193 !win32:!mac:exists(qtwayland/qtwayland.pro): SUBDIRS += module_qtwayland
194 exists(qtimageformats/qtimageformats.pro): SUBDIRS += module_qtimageformats
195 exists(qtgraphicaleffects/qtgraphicaleffects.pro): SUBDIRS += module_qtgraphicaleffects
196 exists(qttranslations/qttranslations.pro): SUBDIRS += module_qttranslations
197 exists(qtdoc/qtdoc.pro): SUBDIRS += module_qtdoc
198 exists(qtqa/qtqa.pro): SUBDIRS += module_qtqa
199 exists(qlalr/qlalr.pro): SUBDIRS += module_qlalr