Tweak name of Makefile for QtWebKit to just 'Makefile', not 'Makefile.WebKit'
[mirror/qt/qt5.git] / qt.pro
1 # Create the super cache so modules will add themselves to it.
2 cache(, super)
3
4 TEMPLATE      = subdirs
5
6 module_qtbase.subdir = qtbase
7 module_qtbase.target = module-qtbase
8
9 module_qtsvg.subdir = qtsvg
10 module_qtsvg.target = module-qtsvg
11 module_qtsvg.depends = module_qtbase
12
13 module_qtxmlpatterns.subdir = qtxmlpatterns
14 module_qtxmlpatterns.target = module-qtxmlpatterns
15 module_qtxmlpatterns.depends = module_qtbase
16
17 module_qtscript.subdir = qtscript
18 module_qtscript.target = module-qtscript
19 module_qtscript.depends = module_qtbase
20
21 module_qtjsbackend.subdir = qtjsbackend
22 module_qtjsbackend.target = module-qtjsbackend
23 module_qtjsbackend.depends = module_qtbase
24
25 module_qtdeclarative.subdir = qtdeclarative
26 module_qtdeclarative.target = module-qtdeclarative
27 module_qtdeclarative.depends = module_qtbase module_qtjsbackend
28
29 module_qtwebkit.file = qtwebkit/WebKit.pro
30 module_qtwebkit.makefile = Makefile
31 module_qtwebkit.depends = module_qtbase module_qtdeclarative
32 module_qtwebkit.target = module-qtwebkit
33
34 module_qtwebkit_examples_and_demos.subdir = qtwebkit-examples-and-demos
35 module_qtwebkit_examples_and_demos.target = module-qtwebkit-examples-and-demos
36 module_qtwebkit_examples_and_demos.depends = module_qtwebkit module_qttools
37
38 module_qttools.subdir = qttools
39 module_qttools.target = module-qttools
40 module_qttools.depends = module_qtbase
41
42 module_qttranslations.subdir = qttranslations
43 module_qttranslations.target = module-qttranslations
44 module_qttranslations.depends = module_qttools
45
46 module_qtdoc.subdir = qtdoc
47 module_qtdoc.target = module-qtdoc
48 module_qtdoc.depends = module_qtbase module_qtdeclarative
49
50 module_qtactiveqt.subdir = qtactiveqt
51 module_qtactiveqt.target = module-qtactiveqt
52 module_qtactiveqt.depends = module_qtbase
53
54 module_qlalr.subdir = qlalr
55 module_qlalr.target = module-qlalr
56 module_qlalr.depends = module_qtbase
57
58 module_qtqa.subdir = qtqa
59 module_qtqa.target = module-qtqa
60 module_qtqa.depends = module_qtbase
61
62 module_qtlocation.subdir = qtlocation
63 module_qtlocation.target = module-qtlocation
64 module_qtlocation.depends = module_qtbase
65
66 module_qtsensors.subdir = qtsensors
67 module_qtsensors.target = module-qtsensors
68 module_qtsensors.depends = module_qtbase
69
70 module_qtsystems.subdir = qtsystems
71 module_qtsystems.target = module-qtsystems
72 module_qtsystems.depends = module_qtbase
73
74 module_qtmultimedia.subdir = qtmultimedia
75 module_qtmultimedia.target = module-qtmultimedia
76 module_qtmultimedia.depends = module_qtbase
77
78 module_qtfeedback.subdir = qtfeedback
79 module_qtfeedback.target = module-qtfeedback
80 module_qtfeedback.depends = module_qtbase module_qtdeclarative
81
82 module_qt3d.subdir = qt3d
83 module_qt3d.target = module-qt3d
84 module_qt3d.depends = module_qtbase module_qtdeclarative
85
86 module_qtpim.subdir = qtpim
87 module_qtpim.target = module-qtpim
88 module_qtpim.depends = module_qtdeclarative
89
90 module_qtconnectivity.subdir = qtconnectivity
91 module_qtconnectivity.target = module-qtconnectivity
92 module_qtconnectivity.depends = module_qtsystems
93
94 module_qtwayland.subdir = qtwayland
95 module_qtwayland.target = module-qtwayland
96 module_qtwayland.depends = module_qtbase
97 # not yet enabled by default
98 module_qtwayland.CONFIG = no_default_target no_default_install
99
100 module_qtimageformats.subdir = qtimageformats
101 module_qtimageformats.target = module-qtimageformats
102 module_qtimageformats.depends = module_qtbase
103
104 module_qtquick1.subdir = qtquick1
105 module_qtquick1.target = module-qtquick1
106 module_qtquick1.depends = module_qtbase module_qtscript
107
108 module_qtgraphicaleffects.subdir = qtgraphicaleffects
109 module_qtgraphicaleffects.target = module-qtgraphicaleffects
110 module_qtgraphicaleffects.depends = module_qtbase module_qtdeclarative
111
112 # only qtbase is required to exist. The others may not - but it is the
113 # users responsibility to ensure that all needed dependencies exist, or
114 # it may not build.
115
116 SUBDIRS = module_qtbase
117
118 exists(qtsvg/qtsvg.pro) {
119     SUBDIRS += module_qtsvg
120     # These modules do not require qtsvg, but can use it if it is available
121     module_qtdeclarative.depends += module_qtsvg
122     module_qtquick1.depends += module_qtsvg
123 }
124 exists(qtxmlpatterns/qtxmlpatterns.pro) {
125     SUBDIRS += module_qtxmlpatterns
126     # These modules do not require qtxmlpatterns, but can use it if it is available
127     module_qtdeclarative.depends += module_qtxmlpatterns
128     module_qtquick1.depends += module_qtxmlpatterns
129 }
130
131 exists(qtjsbackend/qtjsbackend.pro): SUBDIRS += module_qtjsbackend
132 exists(qtdeclarative/qtdeclarative.pro) {
133     SUBDIRS += module_qtdeclarative
134     # These modules do not require qtdeclarative, but can use it if it is available
135     module_qttools.depends += module_qtdeclarative
136     module_qtsensors.depends += module_qtdeclarative
137     module_qtsystems.depends += module_qtdeclarative
138     module_qtmultimedia.depends += module_qtdeclarative
139     module_qtwayland.depends += module_qtdeclarative
140 }
141 exists(qt3d/qt3d.pro) {
142     SUBDIRS += module_qt3d
143     # These modules do not require qt3d, but can use it if it is available
144     module_qtlocation.depends += module_qtdeclarative module_qt3d
145 }
146 exists(qtscript/qtscript.pro): SUBDIRS += module_qtscript
147 exists(qtlocation/qtlocation.pro) {
148     SUBDIRS += module_qtlocation
149     # These modules do not require qtlocation, but can use it if it is available
150     module_qtwebkit.depends += module_qtlocation
151 }
152 exists(qtsensors/qtsensors.pro) {
153     SUBDIRS += module_qtsensors
154     # These modules do not require qtsensors, but can use it if it is available
155     module_qtwebkit.depends += module_qtsensors
156 }
157 exists(qtsystems/qtsystems.pro) {
158     SUBDIRS += module_qtsystems
159     # These modules do not require qtsystems, but can use it if it is available
160     module_qtlocation.depends += module_qtsystems
161 }
162 exists(qtmultimedia/qtmultimedia.pro) {
163     SUBDIRS += module_qtmultimedia
164     # These modules do not require qtmultimedia, but can use it if it is available
165     module_qtfeedback.depends += module_qtmultimedia
166     module_qtlocation.depends += module_qtmultimedia
167 }
168 exists(qtfeedback/qtfeedback.pro): SUBDIRS += module_qtfeedback
169 exists(qtpim/qtpim.pro): SUBDIRS += module_qtpim
170 exists(qtconnectivity/qtconnectivity.pro): SUBDIRS += module_qtconnectivity
171 exists(qtactiveqt/qtactiveqt.pro) {
172     SUBDIRS += module_qtactiveqt
173     module_qttools.depends += module_qtactiveqt
174 }
175 exists(qtwebkit/WebKit.pro) {
176     mac|contains(QT_CONFIG, icu) {
177         SUBDIRS += module_qtwebkit
178         module_qttools.depends += module_qtwebkit
179         module_qtquick1.depends += module_qtwebkit
180         exists(qtwebkit-examples-and-demos/qtwebkit-examples-and-demos.pro) {
181             SUBDIRS += module_qtwebkit_examples_and_demos
182         }
183     } else {
184         message("WebKit: Qt was built without ICU support, WebKit disabled.")
185     }
186 }
187 exists(qttools/qttools.pro) {
188     SUBDIRS += module_qttools
189     module_qtquick1.depends += module_qttools
190 }
191 exists(qtquick1/qtquick1.pro): SUBDIRS += module_qtquick1
192 !win32:!mac:exists(qtwayland/qtwayland.pro): SUBDIRS += module_qtwayland
193 exists(qtimageformats/qtimageformats.pro): SUBDIRS += module_qtimageformats
194 exists(qtgraphicaleffects/qtgraphicaleffects.pro): SUBDIRS += module_qtgraphicaleffects
195 exists(qttranslations/qttranslations.pro): SUBDIRS += module_qttranslations
196 exists(qtdoc/qtdoc.pro): SUBDIRS += module_qtdoc
197 exists(qtqa/qtqa.pro): SUBDIRS += module_qtqa
198 exists(qlalr/qlalr.pro): SUBDIRS += module_qlalr