Remove qtjsbackend as dependency for qtdeclarative
[mirror/qt/qt5.git] / qt.pro
1 # Create the super cache so modules will add themselves to it.
2 cache(, super)
3
4 CONFIG += build_pass   # hack to disable the .qmake.super auto-add
5 load(qt_build_config)
6
7 TEMPLATE      = subdirs
8
9 defineReplace(moduleName) {
10     return(module_$$replace(1, -, _))
11 }
12
13 # Arguments: module name, [mandatory deps], [optional deps], [project file]
14 defineTest(addModule) {
15     contains(QT_SKIP_MODULES, $$1): return(false)
16     mod = $$moduleName($$1)
17
18     isEmpty(4) {
19         !exists($$1/$${1}.pro): return(false)
20         $${mod}.subdir = $$1
21         export($${mod}.subdir)
22     } else {
23         !exists($$1/$${4}): return(false)
24         $${mod}.file = $$1/$$4
25         $${mod}.makefile = Makefile
26         export($${mod}.file)
27         export($${mod}.makefile)
28     }
29
30     for(d, 2) {
31         dn = $$moduleName($$d)
32         !contains(SUBDIRS, $$dn): \
33             return(false)
34         $${mod}.depends += $$dn
35     }
36     for(d, 3) {
37         dn = $$moduleName($$d)
38         contains(SUBDIRS, $$dn): \
39             $${mod}.depends += $$dn
40     }
41     !isEmpty($${mod}.depends): \
42         export($${mod}.depends)
43
44     $${mod}.target = module-$$1
45     export($${mod}.target)
46
47     SUBDIRS += $$mod
48     export(SUBDIRS)
49     return(true)
50 }
51
52 # only qtbase is required to exist. The others may not - but it is the
53 # users responsibility to ensure that all needed dependencies exist, or
54 # it may not build.
55
56 addModule(qtbase)
57 addModule(qtmacextras, qtbase)
58 addModule(qtwinextras, qtbase)
59 addModule(qtx11extras, qtbase)
60 addModule(qlalr, qtbase)
61 addModule(qtsvg, qtbase)
62 addModule(qtxmlpatterns, qtbase)
63 addModule(qtjsbackend, qtbase)
64 addModule(qtdeclarative, qtbase, qtsvg qtxmlpatterns)
65 addModule(qtquickcontrols, qtdeclarative)
66 addModule(qtmultimedia, qtdeclarative)
67 addModule(qtactiveqt, qtbase)
68 addModule(qt3d, qtdeclarative)
69 addModule(qtjsondb, qtdeclarative)
70 addModule(qtsystems, qtbase, qtdeclarative)
71 addModule(qtlocation, qtbase, qt3d qtsystems qtmultimedia)
72 addModule(qtsensors, qtbase, qtdeclarative)
73 addModule(qtconnectivity, qtsystems)
74 addModule(qtfeedback, qtdeclarative, qtmultimedia)
75 addModule(qtpim, qtdeclarative, qtjsondb)
76 addModule(qtwebkit, qtdeclarative, qtlocation qtsensors, WebKit.pro)
77 addModule(qttools, qtbase, qtdeclarative qtactiveqt qtwebkit)
78 addModule(qtwebkit-examples, qtwebkit qttools)
79 addModule(qtimageformats, qtbase)
80 addModule(qtgraphicaleffects, qtdeclarative)
81 addModule(qtscript, qtbase)
82 addModule(qtquick1, qtscript, qtsvg qtxmlpatterns qtwebkit qttools)
83 addModule(qtdocgallery, qtdeclarative, qtjsondb)
84 !win32:!mac:addModule(qtwayland, qtbase, qtdeclarative)
85 addModule(qtserialport, qtbase)
86 addModule(qttranslations, qttools)
87 addModule(qtdoc, qtdeclarative)
88 addModule(qtqa, qtbase)