Remove submodules which are not part of Qt 5.0.
[mirror/qt/qt5.git] / qt.pro
1 # Create the super cache so modules will add themselves to it.
2 cache(, super)
3
4 TEMPLATE      = subdirs
5
6 module_qtbase.subdir = qtbase
7 module_qtbase.target = module-qtbase
8
9 module_qtsvg.subdir = qtsvg
10 module_qtsvg.target = module-qtsvg
11 module_qtsvg.depends = module_qtbase
12
13 module_qtxmlpatterns.subdir = qtxmlpatterns
14 module_qtxmlpatterns.target = module-qtxmlpatterns
15 module_qtxmlpatterns.depends = module_qtbase
16
17 module_qtscript.subdir = qtscript
18 module_qtscript.target = module-qtscript
19 module_qtscript.depends = module_qtbase
20
21 module_qtjsbackend.subdir = qtjsbackend
22 module_qtjsbackend.target = module-qtjsbackend
23 module_qtjsbackend.depends = module_qtbase
24
25 module_qtdeclarative.subdir = qtdeclarative
26 module_qtdeclarative.target = module-qtdeclarative
27 module_qtdeclarative.depends = module_qtbase module_qtjsbackend
28
29 module_qtwebkit.file = qtwebkit/WebKit.pro
30 module_qtwebkit.makefile = Makefile
31 module_qtwebkit.depends = module_qtbase module_qtdeclarative
32 module_qtwebkit.target = module-qtwebkit
33
34 module_qtwebkit_examples_and_demos.subdir = qtwebkit-examples-and-demos
35 module_qtwebkit_examples_and_demos.target = module-qtwebkit-examples-and-demos
36 module_qtwebkit_examples_and_demos.depends = module_qtwebkit module_qttools
37
38 module_qttools.subdir = qttools
39 module_qttools.target = module-qttools
40 module_qttools.depends = module_qtbase
41
42 module_qttranslations.subdir = qttranslations
43 module_qttranslations.target = module-qttranslations
44 module_qttranslations.depends = module_qttools
45
46 module_qtdoc.subdir = qtdoc
47 module_qtdoc.target = module-qtdoc
48 module_qtdoc.depends = module_qtbase module_qtdeclarative
49
50 module_qtactiveqt.subdir = qtactiveqt
51 module_qtactiveqt.target = module-qtactiveqt
52 module_qtactiveqt.depends = module_qtbase
53
54 module_qtqa.subdir = qtqa
55 module_qtqa.target = module-qtqa
56 module_qtqa.depends = module_qtbase
57
58 module_qtmultimedia.subdir = qtmultimedia
59 module_qtmultimedia.target = module-qtmultimedia
60 module_qtmultimedia.depends = module_qtbase
61
62 module_qtimageformats.subdir = qtimageformats
63 module_qtimageformats.target = module-qtimageformats
64 module_qtimageformats.depends = module_qtbase
65
66 module_qtquick1.subdir = qtquick1
67 module_qtquick1.target = module-qtquick1
68 module_qtquick1.depends = module_qtbase module_qtscript
69
70 module_qtgraphicaleffects.subdir = qtgraphicaleffects
71 module_qtgraphicaleffects.target = module-qtgraphicaleffects
72 module_qtgraphicaleffects.depends = module_qtbase module_qtdeclarative
73
74 # only qtbase is required to exist. The others may not - but it is the
75 # users responsibility to ensure that all needed dependencies exist, or
76 # it may not build.
77
78 SUBDIRS = module_qtbase
79
80 exists(qtsvg/qtsvg.pro) {
81     SUBDIRS += module_qtsvg
82     # These modules do not require qtsvg, but can use it if it is available
83     module_qtdeclarative.depends += module_qtsvg
84     module_qtquick1.depends += module_qtsvg
85 }
86 exists(qtxmlpatterns/qtxmlpatterns.pro) {
87     SUBDIRS += module_qtxmlpatterns
88     # These modules do not require qtxmlpatterns, but can use it if it is available
89     module_qtdeclarative.depends += module_qtxmlpatterns
90     module_qtquick1.depends += module_qtxmlpatterns
91 }
92
93 exists(qtjsbackend/qtjsbackend.pro): SUBDIRS += module_qtjsbackend
94 exists(qtdeclarative/qtdeclarative.pro) {
95     SUBDIRS += module_qtdeclarative
96     # These modules do not require qtdeclarative, but can use it if it is available
97     module_qttools.depends += module_qtdeclarative
98     module_qtmultimedia.depends += module_qtdeclarative
99 }
100 exists(qtscript/qtscript.pro): SUBDIRS += module_qtscript
101 exists(qtmultimedia/qtmultimedia.pro): SUBDIRS += module_qtmultimedia
102 exists(qtactiveqt/qtactiveqt.pro) {
103     SUBDIRS += module_qtactiveqt
104     module_qttools.depends += module_qtactiveqt
105 }
106 exists(qtwebkit/WebKit.pro) {
107     mac|contains(QT_CONFIG, icu) {
108         SUBDIRS += module_qtwebkit
109         module_qttools.depends += module_qtwebkit
110         module_qtquick1.depends += module_qtwebkit
111         exists(qtwebkit-examples-and-demos/qtwebkit-examples-and-demos.pro) {
112             SUBDIRS += module_qtwebkit_examples_and_demos
113         }
114     } else {
115         message("WebKit: Qt was built without ICU support, WebKit disabled.")
116     }
117 }
118 exists(qttools/qttools.pro) {
119     SUBDIRS += module_qttools
120     module_qtquick1.depends += module_qttools
121 }
122 exists(qtquick1/qtquick1.pro): SUBDIRS += module_qtquick1
123 exists(qtimageformats/qtimageformats.pro): SUBDIRS += module_qtimageformats
124 exists(qtgraphicaleffects/qtgraphicaleffects.pro): SUBDIRS += module_qtgraphicaleffects
125 exists(qttranslations/qttranslations.pro): SUBDIRS += module_qttranslations
126 exists(qtdoc/qtdoc.pro): SUBDIRS += module_qtdoc
127 exists(qtqa/qtqa.pro): SUBDIRS += module_qtqa