make qtandroidextras a regular optional dependency of qtconnectivity
[mirror/qt/qt5.git] / qt.pro
1 # Create the super cache so modules will add themselves to it.
2 cache(, super)
3
4 CONFIG += build_pass   # hack to disable the .qmake.super auto-add
5 load(qt_build_config)
6 CONFIG -= build_pass   # unhack, as it confuses Qt Creator
7
8 TEMPLATE      = subdirs
9
10 defineReplace(moduleName) {
11     return(module_$$replace(1, -, _))
12 }
13
14 # Arguments: module name, [mandatory deps], [optional deps], [project file]
15 defineTest(addModule) {
16     for(d, $$list($$2 $$3)): \
17         !contains(MODULES, $$d): \
18             error("'$$1' depends on not (yet) declared '$$d'.")
19     MODULES += $$1
20     export(MODULES)
21
22     contains(QT_SKIP_MODULES, $$1): return(false)
23     !isEmpty(QT_BUILD_MODULES):!contains(QT_BUILD_MODULES, $$1): return(false)
24     mod = $$moduleName($$1)
25
26     isEmpty(4) {
27         !exists($$1/$${1}.pro): return(false)
28         $${mod}.subdir = $$1
29         export($${mod}.subdir)
30     } else {
31         !exists($$1/$${4}): return(false)
32         $${mod}.file = $$1/$$4
33         $${mod}.makefile = Makefile
34         export($${mod}.file)
35         export($${mod}.makefile)
36     }
37
38     for(d, 2) {
39         dn = $$moduleName($$d)
40         !contains(SUBDIRS, $$dn): \
41             return(false)
42         $${mod}.depends += $$dn
43     }
44     for(d, 3) {
45         dn = $$moduleName($$d)
46         contains(SUBDIRS, $$dn): \
47             $${mod}.depends += $$dn
48     }
49     !isEmpty($${mod}.depends): \
50         export($${mod}.depends)
51
52     $${mod}.target = module-$$1
53     export($${mod}.target)
54
55     SUBDIRS += $$mod
56     export(SUBDIRS)
57     return(true)
58 }
59
60 # only qtbase is required to exist. The others may not - but it is the
61 # users responsibility to ensure that all needed dependencies exist, or
62 # it may not build.
63
64 addModule(qtbase)
65 addModule(qtandroidextras, qtbase)
66 addModule(qtmacextras, qtbase)
67 addModule(qtx11extras, qtbase)
68 addModule(qtsvg, qtbase)
69 addModule(qtxmlpatterns, qtbase)
70 addModule(qtdeclarative, qtbase, qtsvg qtxmlpatterns)
71 addModule(qtgraphicaleffects, qtdeclarative)
72 addModule(qtquickcontrols, qtdeclarative, qtgraphicaleffects)
73 addModule(qtquickcontrols2, qtquickcontrols)
74 addModule(qtmultimedia, qtbase, qtdeclarative)
75 addModule(qtwinextras, qtbase, qtdeclarative qtmultimedia)
76 addModule(qtactiveqt, qtbase)
77 addModule(qtsystems, qtbase, qtdeclarative)
78 addModule(qtsensors, qtbase, qtdeclarative)
79 addModule(qtconnectivity, qtbase, qtdeclarative qtandroidextras)
80 addModule(qtfeedback, qtdeclarative, qtmultimedia)
81 addModule(qtpim, qtdeclarative)
82 addModule(qtwebsockets, qtbase, qtdeclarative)
83 addModule(qtwebchannel, qtbase, qtdeclarative qtwebsockets)
84 addModule(qtserialport, qtbase)
85 addModule(qtlocation, qtbase, qtdeclarative qtquickcontrols qtserialport qtsystems)
86 addModule(qtwebkit, qtbase, qtdeclarative qtlocation qtmultimedia qtsensors qtwebchannel qtxmlpatterns, WebKit.pro)
87 addModule(qttools, qtbase, qtdeclarative qtactiveqt qtwebkit)
88 addModule(qtwebkit-examples, qtwebkit qttools)
89 addModule(qtimageformats, qtbase)
90 addModule(qt3d, qtdeclarative qtimageformats)
91 addModule(qtcanvas3d, qtdeclarative)
92 addModule(qtscript, qtbase, qttools)
93 addModule(qtquick1, qtscript, qtsvg qtxmlpatterns)
94 addModule(qtdocgallery, qtdeclarative)
95 addModule(qtwayland, qtbase, qtdeclarative)
96 addModule(qtserialbus, qtserialport)
97 addModule(qtenginio, qtdeclarative)
98 addModule(qtwebengine, qtquickcontrols qtwebchannel, qtlocation)
99 addModule(qtwebview, qtdeclarative, qtwebengine)
100 addModule(qtpurchasing, qtbase, qtdeclarative)
101 addModule(qttranslations, qttools)
102 addModule(qtdoc, qtdeclarative)
103 addModule(qtqa, qtbase)