(re-)add top-level 'check' target
[mirror/qt/qt5.git] / qt.pro
1 # Create the super cache so modules will add themselves to it.
2 cache(, super)
3
4 TEMPLATE      = subdirs
5
6 CONFIG += prepare_docs qt_docs_targets testcase_targets
7
8 module_qtbase.subdir = qtbase
9 module_qtbase.target = module-qtbase
10
11 module_qtsvg.subdir = qtsvg
12 module_qtsvg.target = module-qtsvg
13 module_qtsvg.depends = module_qtbase
14
15 module_qtxmlpatterns.subdir = qtxmlpatterns
16 module_qtxmlpatterns.target = module-qtxmlpatterns
17 module_qtxmlpatterns.depends = module_qtbase
18
19 module_qtscript.subdir = qtscript
20 module_qtscript.target = module-qtscript
21 module_qtscript.depends = module_qtbase
22
23 module_qtjsbackend.subdir = qtjsbackend
24 module_qtjsbackend.target = module-qtjsbackend
25 module_qtjsbackend.depends = module_qtbase
26
27 module_qtdeclarative.subdir = qtdeclarative
28 module_qtdeclarative.target = module-qtdeclarative
29 module_qtdeclarative.depends = module_qtbase module_qtjsbackend
30
31 module_qtwebkit.file = qtwebkit/WebKit.pro
32 module_qtwebkit.makefile = Makefile
33 module_qtwebkit.depends = module_qtbase module_qtdeclarative
34 module_qtwebkit.target = module-qtwebkit
35
36 module_qtwebkit_examples_and_demos.subdir = qtwebkit-examples-and-demos
37 module_qtwebkit_examples_and_demos.target = module-qtwebkit-examples-and-demos
38 module_qtwebkit_examples_and_demos.depends = module_qtwebkit module_qttools
39
40 module_qttools.subdir = qttools
41 module_qttools.target = module-qttools
42 module_qttools.depends = module_qtbase
43
44 module_qttranslations.subdir = qttranslations
45 module_qttranslations.target = module-qttranslations
46 module_qttranslations.depends = module_qttools
47
48 module_qtdoc.subdir = qtdoc
49 module_qtdoc.target = module-qtdoc
50 module_qtdoc.depends = module_qtbase module_qtdeclarative
51
52 module_qtactiveqt.subdir = qtactiveqt
53 module_qtactiveqt.target = module-qtactiveqt
54 module_qtactiveqt.depends = module_qtbase
55
56 module_qtqa.subdir = qtqa
57 module_qtqa.target = module-qtqa
58 module_qtqa.depends = module_qtbase
59
60 module_qtmultimedia.subdir = qtmultimedia
61 module_qtmultimedia.target = module-qtmultimedia
62 module_qtmultimedia.depends = module_qtbase
63
64 module_qtimageformats.subdir = qtimageformats
65 module_qtimageformats.target = module-qtimageformats
66 module_qtimageformats.depends = module_qtbase
67
68 module_qtquick1.subdir = qtquick1
69 module_qtquick1.target = module-qtquick1
70 module_qtquick1.depends = module_qtbase module_qtscript
71
72 module_qtgraphicaleffects.subdir = qtgraphicaleffects
73 module_qtgraphicaleffects.target = module-qtgraphicaleffects
74 module_qtgraphicaleffects.depends = module_qtbase module_qtdeclarative
75
76 # only qtbase is required to exist. The others may not - but it is the
77 # users responsibility to ensure that all needed dependencies exist, or
78 # it may not build.
79
80 SUBDIRS = module_qtbase
81
82 exists(qtsvg/qtsvg.pro) {
83     SUBDIRS += module_qtsvg
84     # These modules do not require qtsvg, but can use it if it is available
85     module_qtdeclarative.depends += module_qtsvg
86     module_qtquick1.depends += module_qtsvg
87 }
88 exists(qtxmlpatterns/qtxmlpatterns.pro) {
89     SUBDIRS += module_qtxmlpatterns
90     # These modules do not require qtxmlpatterns, but can use it if it is available
91     module_qtdeclarative.depends += module_qtxmlpatterns
92     module_qtquick1.depends += module_qtxmlpatterns
93 }
94
95 exists(qtjsbackend/qtjsbackend.pro): SUBDIRS += module_qtjsbackend
96 exists(qtdeclarative/qtdeclarative.pro) {
97     SUBDIRS += module_qtdeclarative
98     # These modules do not require qtdeclarative, but can use it if it is available
99     module_qttools.depends += module_qtdeclarative
100     module_qtmultimedia.depends += module_qtdeclarative
101 }
102 exists(qtscript/qtscript.pro): SUBDIRS += module_qtscript
103 exists(qtmultimedia/qtmultimedia.pro): SUBDIRS += module_qtmultimedia
104 exists(qtactiveqt/qtactiveqt.pro) {
105     SUBDIRS += module_qtactiveqt
106     module_qttools.depends += module_qtactiveqt
107 }
108 exists(qtwebkit/WebKit.pro) {
109     mac|contains(QT_CONFIG, icu) {
110         SUBDIRS += module_qtwebkit
111         module_qttools.depends += module_qtwebkit
112         module_qtquick1.depends += module_qtwebkit
113         exists(qtwebkit-examples-and-demos/qtwebkit-examples-and-demos.pro) {
114             SUBDIRS += module_qtwebkit_examples_and_demos
115         }
116     } else {
117         message("WebKit: Qt was built without ICU support, WebKit disabled.")
118     }
119 }
120 exists(qttools/qttools.pro) {
121     SUBDIRS += module_qttools
122     module_qtquick1.depends += module_qttools
123 }
124 exists(qtquick1/qtquick1.pro): SUBDIRS += module_qtquick1
125 exists(qtimageformats/qtimageformats.pro): SUBDIRS += module_qtimageformats
126 exists(qtgraphicaleffects/qtgraphicaleffects.pro): SUBDIRS += module_qtgraphicaleffects
127 exists(qttranslations/qttranslations.pro): SUBDIRS += module_qttranslations
128 exists(qtdoc/qtdoc.pro): SUBDIRS += module_qtdoc
129 exists(qtqa/qtqa.pro): SUBDIRS += module_qtqa