Introduce dependency: QtQuick1 needs QtWebKit
[mirror/qt/qt5.git] / qt.pro
1 # Create the super cache so modules will add themselves to it.
2 cache(, super)
3
4 TEMPLATE      = subdirs
5
6 module_qtbase.subdir = qtbase
7 module_qtbase.target = module-qtbase
8
9 module_qtsvg.subdir = qtsvg
10 module_qtsvg.target = module-qtsvg
11 module_qtsvg.depends = module_qtbase
12
13 module_qtxmlpatterns.subdir = qtxmlpatterns
14 module_qtxmlpatterns.target = module-qtxmlpatterns
15 module_qtxmlpatterns.depends = module_qtbase
16
17 module_qtscript.subdir = qtscript
18 module_qtscript.target = module-qtscript
19 module_qtscript.depends = module_qtbase
20
21 module_qtjsbackend.subdir = qtjsbackend
22 module_qtjsbackend.target = module-qtjsbackend
23 module_qtjsbackend.depends = module_qtbase
24
25 module_qtdeclarative.subdir = qtdeclarative
26 module_qtdeclarative.target = module-qtdeclarative
27 module_qtdeclarative.depends = module_qtbase module_qtjsbackend
28
29 module_qtwebkit.file = qtwebkit/WebKit.pro
30 module_qtwebkit.depends = module_qtbase module_qtdeclarative
31 module_qtwebkit.target = module-qtwebkit
32
33 module_qtwebkit_examples_and_demos.subdir = qtwebkit-examples-and-demos
34 module_qtwebkit_examples_and_demos.target = module-qtwebkit-examples-and-demos
35 module_qtwebkit_examples_and_demos.depends = module_qtwebkit module_qttools
36
37 module_qttools.subdir = qttools
38 module_qttools.target = module-qttools
39 module_qttools.depends = module_qtbase
40
41 module_qttranslations.subdir = qttranslations
42 module_qttranslations.target = module-qttranslations
43 module_qttranslations.depends = module_qttools
44
45 module_qtdoc.subdir = qtdoc
46 module_qtdoc.target = module-qtdoc
47 module_qtdoc.depends = module_qtbase module_qtdeclarative
48
49 module_qtactiveqt.subdir = qtactiveqt
50 module_qtactiveqt.target = module-qtactiveqt
51 module_qtactiveqt.depends = module_qtbase
52
53 module_qlalr.subdir = qlalr
54 module_qlalr.target = module-qlalr
55 module_qlalr.depends = module_qtbase
56
57 module_qtqa.subdir = qtqa
58 module_qtqa.target = module-qtqa
59 module_qtqa.depends = module_qtbase
60
61 module_qtlocation.subdir = qtlocation
62 module_qtlocation.target = module-qtlocation
63 module_qtlocation.depends = module_qtbase
64
65 module_qtsensors.subdir = qtsensors
66 module_qtsensors.target = module-qtsensors
67 module_qtsensors.depends = module_qtbase
68
69 module_qtsystems.subdir = qtsystems
70 module_qtsystems.target = module-qtsystems
71 module_qtsystems.depends = module_qtbase
72
73 module_qtmultimedia.subdir = qtmultimedia
74 module_qtmultimedia.target = module-qtmultimedia
75 module_qtmultimedia.depends = module_qtbase
76
77 module_qtfeedback.subdir = qtfeedback
78 module_qtfeedback.target = module-qtfeedback
79 module_qtfeedback.depends = module_qtbase module_qtdeclarative
80
81 module_qt3d.subdir = qt3d
82 module_qt3d.target = module-qt3d
83 module_qt3d.depends = module_qtbase module_qtdeclarative
84
85 module_qtpim.subdir = qtpim
86 module_qtpim.target = module-qtpim
87 module_qtpim.depends = module_qtdeclarative
88
89 module_qtconnectivity.subdir = qtconnectivity
90 module_qtconnectivity.target = module-qtconnectivity
91 module_qtconnectivity.depends = module_qtsystems
92
93 module_qtwayland.subdir = qtwayland
94 module_qtwayland.target = module-qtwayland
95 module_qtwayland.depends = module_qtbase
96 # not yet enabled by default
97 module_qtwayland.CONFIG = no_default_target no_default_install
98
99 module_qtimageformats.subdir = qtimageformats
100 module_qtimageformats.target = module-qtimageformats
101 module_qtimageformats.depends = module_qtbase
102
103 module_qtquick1.subdir = qtquick1
104 module_qtquick1.target = module-qtquick1
105 module_qtquick1.depends = module_qtbase module_qtscript
106
107 module_qtgraphicaleffects.subdir = qtgraphicaleffects
108 module_qtgraphicaleffects.target = module-qtgraphicaleffects
109 module_qtgraphicaleffects.depends = module_qtbase module_qtdeclarative
110
111 # only qtbase is required to exist. The others may not - but it is the
112 # users responsibility to ensure that all needed dependencies exist, or
113 # it may not build.
114
115 SUBDIRS = module_qtbase
116
117 exists(qtsvg/qtsvg.pro) {
118     SUBDIRS += module_qtsvg
119     # These modules do not require qtsvg, but can use it if it is available
120     module_qtdeclarative.depends += module_qtsvg
121     module_qtquick1.depends += module_qtsvg
122 }
123 exists(qtxmlpatterns/qtxmlpatterns.pro) {
124     SUBDIRS += module_qtxmlpatterns
125     # These modules do not require qtxmlpatterns, but can use it if it is available
126     module_qtdeclarative.depends += module_qtxmlpatterns
127     module_qtquick1.depends += module_qtxmlpatterns
128 }
129
130 exists(qtjsbackend/qtjsbackend.pro): SUBDIRS += module_qtjsbackend
131 exists(qtdeclarative/qtdeclarative.pro) {
132     SUBDIRS += module_qtdeclarative
133     # These modules do not require qtdeclarative, but can use it if it is available
134     module_qttools.depends += module_qtdeclarative
135     module_qtsensors.depends += module_qtdeclarative
136     module_qtsystems.depends += module_qtdeclarative
137     module_qtmultimedia.depends += module_qtdeclarative
138     module_qtwayland.depends += module_qtdeclarative
139 }
140 exists(qt3d/qt3d.pro) {
141     SUBDIRS += module_qt3d
142     # These modules do not require qt3d, but can use it if it is available
143     module_qtlocation.depends += module_qtdeclarative module_qt3d
144 }
145 exists(qtscript/qtscript.pro): SUBDIRS += module_qtscript
146 exists(qtlocation/qtlocation.pro) {
147     SUBDIRS += module_qtlocation
148     # These modules do not require qtlocation, but can use it if it is available
149     module_qtwebkit.depends += module_qtlocation
150 }
151 exists(qtsensors/qtsensors.pro) {
152     SUBDIRS += module_qtsensors
153     # These modules do not require qtsensors, but can use it if it is available
154     module_qtwebkit.depends += module_qtsensors
155 }
156 exists(qtsystems/qtsystems.pro) {
157     SUBDIRS += module_qtsystems
158     # These modules do not require qtsystems, but can use it if it is available
159     module_qtlocation.depends += module_qtsystems
160 }
161 exists(qtmultimedia/qtmultimedia.pro) {
162     SUBDIRS += module_qtmultimedia
163     # These modules do not require qtmultimedia, but can use it if it is available
164     module_qtfeedback.depends += module_qtmultimedia
165     module_qtlocation.depends += module_qtmultimedia
166 }
167 exists(qtfeedback/qtfeedback.pro): SUBDIRS += module_qtfeedback
168 exists(qtpim/qtpim.pro): SUBDIRS += module_qtpim
169 exists(qtconnectivity/qtconnectivity.pro): SUBDIRS += module_qtconnectivity
170 exists(qtactiveqt/qtactiveqt.pro) {
171     SUBDIRS += module_qtactiveqt
172     module_qttools.depends += module_qtactiveqt
173 }
174 exists(qtwebkit/WebKit.pro) {
175     mac|contains(QT_CONFIG, icu) {
176         SUBDIRS += module_qtwebkit
177         module_qttools.depends += module_qtwebkit
178         module_qtquick1.depends += module_qtwebkit
179         exists(qtwebkit-examples-and-demos/qtwebkit-examples-and-demos.pro) {
180             SUBDIRS += module_qtwebkit_examples_and_demos
181         }
182     } else {
183         message("WebKit: Qt was built without ICU support, WebKit disabled.")
184     }
185 }
186 exists(qttools/qttools.pro) {
187     SUBDIRS += module_qttools
188     module_qtquick1.depends += module_qttools
189 }
190 exists(qtquick1/qtquick1.pro): SUBDIRS += module_qtquick1
191 !win32:!mac:exists(qtwayland/qtwayland.pro): SUBDIRS += module_qtwayland
192 exists(qtimageformats/qtimageformats.pro): SUBDIRS += module_qtimageformats
193 exists(qtgraphicaleffects/qtgraphicaleffects.pro): SUBDIRS += module_qtgraphicaleffects
194 exists(qttranslations/qttranslations.pro): SUBDIRS += module_qttranslations
195 exists(qtdoc/qtdoc.pro): SUBDIRS += module_qtdoc
196 exists(qtqa/qtqa.pro): SUBDIRS += module_qtqa
197 exists(qlalr/qlalr.pro): SUBDIRS += module_qlalr