Add the QtMultimediaKit module. Currently not built.
[mirror/qt/qt5.git] / qtwebkit.pri
1 # Wrapper profile for QtWebkit.
2 #
3 # This is needed because webkit builds via a script.
4 # Technically this script is a .pro file, but we name it .pri to avoid clashing
5 # with qt.pro.
6
7 isEmpty(vcproj) {
8     QMAKE_LINK = @: IGNORE THIS LINE
9     OBJECTS_DIR =
10     win32:CONFIG -= embed_manifest_exe
11 } else {
12     CONFIG += console
13     PHONY_DEPS = .
14     phony_src.input = PHONY_DEPS
15     phony_src.output = phony.c
16     phony_src.variable_out = GENERATED_SOURCES
17     phony_src.commands = echo int main() { return 0; } > phony.c
18     phony_src.name = CREATE phony.c
19     phony_src.CONFIG += combine
20     QMAKE_EXTRA_COMPILERS += phony_src
21 }
22
23 DS = $$QMAKE_DIR_SEP
24 contains(DS, /) {
25     env_export = export
26     OPTI=+
27     SBC=$$quote($$QMAKE_CHK_DIR_EXISTS qtwebkit || mkdir qtwebkit &&)
28 } else {
29     env_export = set
30     GNUTOOLS = $$quote("set \"PATH=$$PWD/gnuwin32/bin;%PATH%\" &&")
31 }
32
33 exists($$PWD/qtwebkit/WebKitTools):qtwebkit_tools_dir = WebKitTools
34 else:qtwebkit_tools_dir = Tools
35
36 QTWEBKIT_BUILD_CONFIG =
37 contains(CONFIG, release):!contains(CONFIG, debug_and_release): {QTWEBKIT_BUILD_CONFIG = --release}
38
39 # The '+' is to make parallel "make" work across the script boundary.
40 module_qtwebkit.commands = $${OPTI}$${SBC}cd qtwebkit && \
41                            $$env_export \"WEBKITOUTPUTDIR=$$OUT_PWD/qtwebkit/WebKitBuild\" && $$GNUTOOLS \
42                            perl $$PWD$${DS}qtwebkit$${DS}$${qtwebkit_tools_dir}$${DS}Scripts$${DS}build-webkit \
43                                --qt \
44                                --qmake=$(QMAKE) \
45                                --install-libs=$$[QT_INSTALL_LIBS] \
46                                $$QTWEBKIT_BUILD_CONFIG
47 #                               "--makeargs=\"-$(MAKEFLAGS)\""
48 # Trick to force dependency on this rule.
49 #module_qtwebkit.commands += $$escape_expand(\\n)make_default: module-qtwebkit
50 module_qtwebkit.target = module-qtwebkit
51
52 # The '+' is to make parallel "make" work across the script boundary.
53 module_qtwebkit_clean.commands = $${OPTI}$${SBC}cd qtwebkit && \
54                                  $$env_export \"WEBKITOUTPUTDIR=$$OUT_PWD/qtwebkit/WebKitBuild\" && $$GNUTOOLS \
55                                  perl $$PWD$${DS}qtwebkit$${DS}$${qtwebkit_tools_dir}$${DS}Scripts$${DS}build-webkit \
56                                      --qt \
57                                      --qmake=$(QMAKE) \
58                                      --install-libs=$$[QT_INSTALL_LIBS] \
59                                      $$QTWEBKIT_BUILD_CONFIG \
60                                      "--makeargs=\"$(MAKEFLAGS)\"" \
61                                      --clean
62 # Trick to force dependency on this rule.
63 module_qtwebkit_clean.commands += $$escape_expand(\\n)clean: module-qtwebkit-clean
64 module_qtwebkit_clean.target = module-qtwebkit-clean
65
66 module_qtwebkit_install.commands = $${OPTI}$${SBC}cd qtwebkit && \
67                            $$env_export \"WEBKITOUTPUTDIR=$$OUT_PWD/qtwebkit/WebKitBuild\" && $$GNUTOOLS \
68                            perl $$PWD$${DS}qtwebkit$${DS}$${qtwebkit_tools_dir}$${DS}Scripts$${DS}build-webkit \
69                                --qt \
70                                --qmake=$(QMAKE) \
71                                --install-libs=$$[QT_INSTALL_LIBS] \
72                                "--makeargs=\"install\""
73 # Trick to force dependency on this rule.
74 module_qtwebkit_install.commands+= $$escape_expand(\\n)install: module-qtwebkit-install
75 module_qtwebkit_install.target = module-qtwebkit-install
76
77 module_qtwebkit_uninstall.commands = $${OPTI}$${SBC}cd qtwebkit && \
78                            $$env_export \"WEBKITOUTPUTDIR=$$OUT_PWD/qtwebkit/WebKitBuild\" && $$GNUTOOLS \
79                            perl $$PWD$${DS}qtwebkit$${DS}$${qtwebkit_tools_dir}$${DS}Scripts$${DS}build-webkit \
80                                --qt \
81                                --qmake=$(QMAKE) \
82                                --install-libs=$$[QT_INSTALL_LIBS] \
83                                "--makeargs=\"uninstall\""
84 # Trick to force dependency on this rule.
85 module_qtwebkit_uninstall.commands+= $$escape_expand(\\n)uninstall: module-qtwebkit-uninstall
86 module_qtwebkit_uninstall.target = module-qtwebkit-uninstall
87
88 # WebKit needs a nonstandard target because the build has to be initiated by the bundled script.
89 QMAKE_EXTRA_TARGETS += module_qtwebkit module_qtwebkit_clean module_qtwebkit_install module_qtwebkit_uninstall
90 PRE_TARGETDEPS += module-qtwebkit