Add missing emission of activated(QString)
[mirror/qt/qtbase.git] / src / corelib / global / global.pri
1 # Qt kernel library base module
2
3 HEADERS +=  \
4         global/qglobal.h \
5         global/qsystemdetection.h \
6         global/qcompilerdetection.h \
7         global/qprocessordetection.h \
8         global/qnamespace.h \
9         global/qendian.h \
10         global/qnumeric_p.h \
11         global/qnumeric.h \
12         global/qglobalstatic.h \
13         global/qlibraryinfo.h \
14         global/qlogging.h \
15         global/qtypeinfo.h \
16         global/qsysinfo.h \
17         global/qisenum.h \
18         global/qtypetraits.h \
19         global/qflags.h \
20         global/qhooks_p.h
21
22 SOURCES += \
23         global/archdetect.cpp \
24         global/qglobal.cpp \
25         global/qglobalstatic.cpp \
26         global/qlibraryinfo.cpp \
27         global/qmalloc.cpp \
28         global/qnumeric.cpp \
29         global/qlogging.cpp \
30         global/qhooks.cpp
31
32 # qlibraryinfo.cpp includes qconfig.cpp
33 INCLUDEPATH += $$QT_BUILD_TREE/src/corelib/global
34
35 # Only used on platforms with CONFIG += precompile_header
36 PRECOMPILED_HEADER = global/qt_pch.h
37
38 # qlogging.cpp uses backtrace(3), which is in a separate library on the BSDs.
39 LIBS_PRIVATE += $$QMAKE_LIBS_EXECINFO
40
41 if(linux*|hurd*):!cross_compile:!static:!*-armcc* {
42    QMAKE_LFLAGS += -Wl,-e,qt_core_boilerplate
43    prog=$$quote(if (/program interpreter: (.*)]/) { print $1; })
44    DEFINES += ELF_INTERPRETER=\\\"$$system(readelf -l /bin/ls | perl -n -e \'$$prog\')\\\"
45 }
46
47 slog2 {
48     LIBS_PRIVATE += -lslog2
49     DEFINES += QT_USE_SLOG2
50 }
51
52 journald {
53     CONFIG += link_pkgconfig
54     PKGCONFIG_PRIVATE += libsystemd-journal
55     DEFINES += QT_USE_JOURNALD
56 }